Questions question....

[winterlight]

I'm trying to make a basic general knowledge program with a set of questions all on one form. A labels caption holds the question and below it there are 4 option buttons with multiple choice answers. All this is housed in a frame, so that each question is separate. The title of each frame is 'Question 1, Question 2, question 3' etc. When you have answered all the questions you then press a button at the bottom of the form which checks whether correct answer has been selected. I want a message box to come up which will say "Well Done! You have got all the answers correct!!!" if you have got all the answers correct. If some have been answered incorrectly I want a messagebox to come up which will say "Sorry, but you got the following answers wrong: ----then it will list each question no. which the user answered incorrectly-----.

As you can see from the following code, I am nowhere near close to finishing it!

Private Sub Command1_Click()
If (Option4.Value) And (Option6.Value) = True Then
MsgBox "Well Done! You have got all the answers correct!!!"
ElseIf Option4.Value = False Then
MsgBox "You Got Question 1 wrong!"
ElseIf Option6.Value = False Then
MsgBox "You got question 2 wrong!"
End If

End Sub


I would be most grateful for your comments and solutions.

[MartinLiss]

Option Explicit
Private Type QA
    Question As String
    Ans1 As String
    Ans2 As String
    Ans3 As String
    Ans4 As String
    CorrectAns As Integer
    Correct As Boolean
End Type
Private QandA(1) As QA
Private mintQuestion As Integer
 
Private Sub Command1_Click()
 
    Label1.Caption = QandA(mintQuestion).Question
    Option1(0).Caption = QandA(mintQuestion).Ans1
    Option1(1).Caption = QandA(mintQuestion).Ans2
    Option1(2).Caption = QandA(mintQuestion).Ans3
    Option1(3).Caption = QandA(mintQuestion).Ans4
    Option1(0).Value = False
    Option1(1).Value = False
    Option1(2).Value = False
    Option1(3).Value = False
End Sub
 
Private Sub Form_Load()
 
    QandA(0).Question = "Who is the world's best programmer?"
    QandA(0).Ans1 = "Joe"
    QandA(0).Ans2 = "MartinLiss"
    QandA(0).Ans3 = "Fred"
    QandA(0).Ans4 = "Sam"
    QandA(0).CorrectAns = 2
    
    Option1(0).Value = False
    Option1(1).Value = False
    Option1(2).Value = False
    Option1(3).Value = False
    
    QandA(1).Question = "How much is 1 + 1?"
    QandA(1).Ans1 = "2"
    QandA(1).Ans2 = "6"
    QandA(1).Ans3 = "All of the above"
    QandA(1).Ans4 = "3"
    QandA(1).CorrectAns = 1
    
End Sub
 
 
Private Sub Option1_Click(Index As Integer)
    
    If Index + 1 = QandA(mintQuestion).CorrectAns Then
        QandA(mintQuestion).Correct = True
    Else
        QandA(mintQuestion).Correct = False
    End If
    mintQuestion = mintQuestion + 1
    
    If mintQuestion > UBound(QandA) Then
        ShowResults
    End If
    
 
End Sub
 
Public Sub ShowResults()
 
    Dim lngIndex As Long
    Dim strErrors As String
    
    For lngIndex = 0 To UBound(QandA)
        If Not QandA(lngIndex).Correct Then
            strErrors = strErrors & lngIndex + 1 & ": " & QandA(lngIndex).Question & vbCrLf
        End If
    Next
    
    If strErrors = "" Then
        MsgBox "Well Done! You have got all the answers correct!!!"
    Else
        MsgBox "Sorry, but you got the following answers wrong:" & vbCrLf & strErrors
    End If
        
 
End Sub