Imaging - RGB colours need help comparing ....

[illskills]

im running the following code below to replace colours .... the code works fine but i need a way to break down RGB values to calculate if the colour is roughly in the same range as the image .... how can i do this

any help would be great
many thanks
illskills

Dim mycc As New ColorConverter
        pgbProgress.Maximum = 256
        For iColour As Integer = 0 To 255
 
            pgbProgress.Value = iColour
            pgbProgress.Refresh()
            If Not IsNothing(arrColoursToReplace(iColour)) Then
                For i As Integer = 1 To 1000 '# loops throught mosaics
                    If IsNothing(arrCustomMosaics(i, 0, 0)) Then Exit For
                    For x As Integer = 1 To 15
                        For y As Integer = 1 To 15
                            If Not IsNothing(arrCustomMosaics(i, x, y)) Then
                                If mycc.ConvertToString(arrCustomMosaics(i, x, y).ToString) = mycc.ConvertToString(arrColoursToReplace(iColour).ToString) Then
                                    arrColoursToReplace(iColour) = arrCustomMosaics(i, 0, 0)
                                End If
                            End If
                        Next
                    Next
                Next
            End If
        Next
        For i As Integer = 1 To 255
            If Not IsNothing(arrColoursToReplace(i)) Then
                txtmytextbox.Text = txtmytextbox.Text & vbCrLf & arrColoursToReplace(i).tostring
            End If
        Next

[illskills]

... this code looks for an exact match

[moeur]

Here is code that Si da Greek wrote

Private Function ColourLongToWords(ByVal lColour As Long) As String
'Converts an RGB colour number to a string equivalent
'By Si_the_geek, VBForums
 
    'ensure value is within range for colours
  lColour = lColour And &HFFFFFF
 
    'convert to separate RGB values
Dim iRed As Integer, iGreen As Integer, iBlue As Integer
  iRed = lColour And &HFF
  iGreen = (lColour \ &H100) And &HFF
  iBlue = lColour \ &H10000
 
    '"guess" the colour based on these values
Dim sColourName As String
  Select Case iRed
  Case Is > 170     'lots of red
      Select Case iGreen
      Case Is > 170     'lots of green
          Select Case iBlue  'blue:  lots/medium/little
          Case Is > 170:  sColourName = "White"
          Case Is > 85:   sColourName = "Bright Yellow"
          Case Else:      sColourName = "Yellow"
          End Select
      Case Is > 85      'medium green
          Select Case iBlue  'blue:  lots/medium/little
          Case Is > 170:  sColourName = "Pink"
          Case Is > 85:   sColourName = "Magenta"
          Case Else:      sColourName = "Orange"
          End Select
      Case Else         'little green
          Select Case iBlue  'blue:  lots/medium/little
          Case Is > 170:  sColourName = "Purple"
          Case Is > 85:   sColourName = "Dark Pink"
          Case Else:      sColourName = "Red"
          End Select
      End Select
 
  Case Is > 85      'medium red
      Select Case iGreen
      Case Is > 170     'lots of green
          Select Case iBlue  'blue:  lots/medium/little
          Case Is > 170:  sColourName = "Cyan"
          Case Is > 85:   sColourName = "Green"
          Case Else:      sColourName = "Bright Green"
          End Select
      Case Is > 85      'medium green
          Select Case iBlue  'blue:  lots/medium/little
          Case Is > 170:  sColourName = "Dark Blue"
          Case Is > 85:   sColourName = "Dark Grey"
          Case Else:      sColourName = "Dark Green"
          End Select
      Case Else         'little green
          Select Case iBlue  'blue:  lots/medium/little
          Case Is > 170:  sColourName = "Dark Blue"
          Case Is > 85:   sColourName = "Purple"
          Case Else:      sColourName = "Dark Red"
          End Select
      End Select
 
  Case Else         'little red
      Select Case iGreen
      Case Is > 170     'lots of green
          Select Case iBlue  'blue:  lots/medium/little
          Case Is > 170:  sColourName = "Cyan"
          Case Is > 85:   sColourName = "Green"
          Case Else:      sColourName = "Bright Green"
          End Select
      Case Is > 85      'medium green
          Select Case iBlue  'blue:  lots/medium/little
          Case Is > 170:  sColourName = "Blue"
          Case Is > 85:   sColourName = "Dark Cyan"
          Case Else:      sColourName = "Dark Green"
          End Select
      Case Else         'little green
          Select Case iBlue  'blue:  lots/medium/little
          Case Is > 170:  sColourName = "Bright Blue"
          Case Is > 85:   sColourName = "Dark Blue"
          Case Else:      sColourName = "Black"
          End Select
      End Select
   End Select
 
  ColourLongToWords = sColourName
 
End Function

from this thread
http://www.vbforums.com/showthread.php?t=366584

[si_the_geek]

beat me to it!

By the way, there's no R in geek