Menubar/Transparency/Etc..

[tomcatexodus]

I tried checking out the other threads I could find regarding form transparency for VB6.0, but I can't quite find the answer I'm looking for..

How would I go about setting a form's window background to transparency, whereas all other controls and objects remain fully visible enabled and accessable.. In essence doing a cutout of the unneeded part of my form window.

My part of the app in question is a toolbar-ish form that sits at the top of the screen using always-on-top api to hold it in view.. but I need transparency for the rest of it..

Also, a side note.. how could I introduce a label/picturebox on top of the menubar on the far left side?..

Great thanks in advance

[moeur]

There are a couple of ways to make a form transparent, here is just one.
Put a label on a form.

Option Explicit
 
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" ( _
    ByVal hWnd As Long, _
    ByVal nIndex As Long _
) As Long
 
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" ( _
    ByVal hWnd As Long, _
    ByVal nIndex As Long, _
    ByVal dwNewLong As Long _
) As Long
 
Private Declare Sub SetWindowPos Lib "user32" ( _
    ByVal hWnd As Long, _
    ByVal hWndInsertAfter As Long, _
    ByVal x As Long, _
    ByVal y As Long, _
    ByVal cx As Long, _
    ByVal cy As Long, _
    ByVal wFlags As Long _
)
 
Private Declare Function SetLayeredWindowAttributes Lib "user32" ( _
    ByVal hWnd As Long, _
    ByVal crKey As Long, _
    ByVal bAlpha As Long, _
    ByVal dwFlags As Long _
) As Long
 
Private Const GWL_EXSTYLE = (-20)
Private Const WS_EX_LAYERED = &H80000
Private Const LWA_COLORKEY = &H1&
Private Const LWA_ALPHA = &H2&
Private Const LWA_OPAQUE = &HFF&
 
Private Const GWL_STYLE = (-16)
Private Const WS_CAPTION = &HC00000
Private Const WS_THICKFRAME = &H40000
 
Private Const HWND_TOPMOST = -1
Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOACTIVATE = &H10
Private Const SWP_SHOWWINDOW = &H40
Private Const SWP_NOZORDER = &H4
Private Const SWP_FRAMECHANGED = &H20
 
Private m_ColorKey As OLE_COLOR
 
Private Declare Function GetSysColor Lib "user32" ( _
    ByVal nIndex As Long _
) As Long
 
Private Function CheckSysColor(ByVal ColorRef As OLE_COLOR) As Long
   Const HighBit = &H80000000
   If ColorRef And HighBit Then
      CheckSysColor = GetSysColor(ColorRef And Not HighBit)
   Else
      CheckSysColor = ColorRef
   End If
End Function
 
Private Function MakeTransparent(ByVal hWnd As Long) As Boolean
   Dim nStyle As Long
   If hWnd Then
      nStyle = GetWindowLong(hWnd, GWL_EXSTYLE) And Not WS_EX_LAYERED
         If SetWindowLong(hWnd, GWL_EXSTYLE, nStyle) Then
            nStyle = nStyle Or WS_EX_LAYERED
            If SetWindowLong(hWnd, GWL_EXSTYLE, nStyle) Then
                     MakeTransparent = CBool(SetLayeredWindowAttributes( _
                     hWnd, CheckSysColor(m_ColorKey), _
                     0, _
                     LWA_COLORKEY))
            End If
         End If
   End If
End Function
 
Private Function ToggleCaption(ByVal Value As Boolean) As Boolean
   Dim nStyle As Long
      ' Retrieve current style bits.
   nStyle = GetWindowLong(Me.hWnd, GWL_STYLE)
   ' Set WS_SYSMENU On or Off as requested.
   If Value Then
      nStyle = nStyle Or WS_CAPTION Or WS_THICKFRAME
   Else
      nStyle = nStyle And Not WS_CAPTION
      nStyle = nStyle And Not WS_THICKFRAME
   End If
      ' Try to set new style.
   If SetWindowLong(Me.hWnd, GWL_STYLE, nStyle) Then
      If nStyle = GetWindowLong(Me.hWnd, GWL_STYLE) Then
         ToggleCaption = True
      End If
   End If
   ' Redraw window with new style.
   SetWindowPos hWnd, 0, 0, 0, 0, 0, SWP_FRAMECHANGED Or SWP_NOMOVE Or SWP_NOZORDER Or SWP_NOSIZE
End Function
 
Private Sub Form_Load()
'setup label
    Label1.AutoSize = True
    Label1.Caption = "Click Me"
 
'make transparent
     'Toggle titlebar off.
      'Call ToggleCaption(False)
            
      m_ColorKey = vbGreen
      MakeTransparent Me.hWnd
      
      ' Set backgrounds to green so they
      ' become transparent too.
      Me.BackColor = vbGreen
      Label1.BackColor = vbGreen
      
End Sub
 
Private Sub Label1_Click()
Unload Me
End Sub

[Protocol]

This should conatin everything you'll need...

[tomcatexodus]

Thanks, I'll look into that

[mats42]

I am having exactly the same problem and neither of theese axamples works for me.

What I need is a truly transparant form, not a form that is a hole.
It realy should work as a pane of glass, you can see what is below it but you can't touch it, mouseclicks and so on should not affect the underlaying objects

[moeur]

you might want to do something like this
http://www.vbforums.com/showthread.php?t=368322

[mats42]

Yes! thats the type of function I want but now I need a method to get it to update itself without flickering all to much

[moeur]

good luck

[mats42]

I could use it for a full screen.

I have some code that will copy everything displayed on the desktop and put that as my background. It's just one "smaller" problem that it catches my window to...

[Harry's Lad]

This isn’t an attempt to hijack the thread but, as it happens, I’ve been struggling to do much the same thing for a day or two..... Moeur’s code (above) nearly works for me except that label1’s background remains as bilious green instead of transparent. Did I set a property wrong somewhere? If only it could be made to be transparent I’d be happy.

Dave

[moeur]

Dave,

If you want to zip up all the files from the project and upload them I can look at what you did.

[Harry's Lad]

Moeur,

Sorry for the delay in answering (Christmas festivities/multiple lagers getting in the way) but I’ve managed to sort it all out now.

1) I’d set the form properties to ‘no border’ (because that’s what I thought wanted) but the transparency works with all form types except ‘no border’ ….
2) Having set the border property to something else I just un-commented the 'Call ToggleCaption(False)’ line – to make the border transparent - and everything works fine.

A lovely bit of code. Thanks for sharing.

ATB

Dave

[mats42]

I'm making progress!

Currently I'm using a "hole" form and api calls to get thou mouseposition, mousebuttonstate and windowstate.

Currently it will detect a click through my app and reset focus back to my app. It's not truely glass but it will do the jobb. The major problem was to handle mouseclicks when another app wa laying above. Since I use api calls i still got those clicks to but by checking active window that can be handled

[Tegan]

Am I understanding you correctly?

You want the form background to be transparent and you want all clicks to the transparent part to be passed to the form underneath? If this is all you need to do, and you don't need any other fancy options like dragging the transparent form by its controls, the answer is simple. I have a code snippet on my computer right now thats not more than 30 lines long and it produces true transparency. Controls on forms beneath can be clicked and I believe you can even adjust the degree of transparency from 0% to 100%. If this sounds useful to you, I'll post the code. Maybe it'll save you a lot of time because I know it took me a long time to figure out how to do that.

[moeur]

I think he wants the other way.
Controls under transparent part must not be clicked.

[mats42]

exactly

I need a pane of glass in vb. See but not touch whats behind it. And with the option to place controls on this pane of glass to.

One applikation is to overlay a presentation from another system and add functions to certain ponts of that presentation