My first class

[wild_bill]

Hello all, I would like you to critique my code. In the past I've create modules rather than classes. The class I've created is for our n-tier structure. We are forbidden to call stored procedures directly, and I thought it was goofy to create a new function for each SP that gets called. I'm hoping this will be the only function used to call any stored procedure. What do you think?

Imports System.Data.SqlClient
Public Class DalBx
    Private sSPname As String
    Private sConnString As String
    Private hsParms As New Hashtable
    Private bEncryptedConn As Boolean
 
    Function GetData() As DataSet
        Try
            If bEncryptedConn Then
                Dim commBC As New BCBSMT.CommonBC
                sConnString = commBC.DecryptString(sConnString)
            End If
 
            Dim sqConn As SqlConnection = New SqlConnection(sConnString)
            Dim sqCmd As New SqlCommand
            Dim sqDa As New SqlDataAdapter
            Dim sqCb As SqlCommandBuilder
            Dim sqPrm As SqlParameter
            Dim dsRtn As New DataSet
 
            sqCmd = sqConn.CreateCommand
            sqCmd.CommandText = sSPname
            sqCmd.CommandType = CommandType.StoredProcedure
 
            sqConn.Open()
            sqCb.DeriveParameters(sqCmd)
            sqConn.Close()
 
            For Each sqPrm In sqCmd.Parameters
                If hsParms.Contains(sqPrm.ParameterName) Then
                    sqPrm.Value = hsParms.Item(sqPrm.ParameterName)
                End If
            Next
 
            sqDa.SelectCommand = sqCmd
            sqDa.Fill(dsRtn)
 
            Return dsRtn
        Catch oEx As Exception
            Dim dsError As New DataSet
            Dim dt As New DataTable
            dt.TableName = "ErrorTable"
            dt.Columns.Add("ErrorDescription")
            dt.Rows.Add(dt.NewRow)
            dt.Rows(0).Item(0) = oEx.ToString
            dsError.Tables.Add(dt)
 
            Return dsError
        End Try
    End Function
 
#Region "Properties"
 
    Property SPname() As String
        Get
            Return sSPname
        End Get
        Set(ByVal Value As String)
            sSPname = Value
        End Set
    End Property
    Property ConnString() As String
        Get
            Return sConnString
        End Get
        Set(ByVal Value As String)
            sConnString = Value
        End Set
    End Property
    Property Parameters() As Hashtable
        Get
            Return hsParms
        End Get
        Set(ByVal Value As Hashtable)
            hsParms = Value
        End Set
    End Property
    Property EncryptedConnection() As Boolean
        'Has the connection string been encrypted
        Get
            Return bEncryptedConn
        End Get
        Set(ByVal Value As Boolean)
            bEncryptedConn = Value
        End Set
    End Property
 
#End Region
 
End Class

[-TPM-]

Not bad. You try catch is larger that I'd like, but not a big problem. I'd suggest making properties readonly/writeonly as needed.

[wild_bill]

Thanks I'll look into that.