[resoloved]Always on top?

[n00b scripter]

How to make a program always on top with a click on a command button?

[RhinoBull]

Here is a quick sample:

Option Explicit
 
Const HWND_TOPMOST = -1
Const HWND_NOTOPMOST = -2
Const SWP_NOSIZE = &H1
Const SWP_NOMOVE = &H2
Const SWP_NOACTIVATE = &H10
Const SWP_SHOWWINDOW = &H40
 
Private Declare Sub SetWindowPos Lib "User32" _
    (ByVal hWnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, _
    ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long)
 
Private Sub Command1_Click()
    SetWindowPos Me.hWnd, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOACTIVATE Or SWP_SHOWWINDOW _
        Or SWP_NOMOVE Or SWP_NOSIZE
End Sub

[Static]

Private Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
 
Private Const HWND_TOPMOST = -1
Private Const HWND_NOTOPMOST = -2
Private Const SWP_NOMOVE = 2
Private Const SWP_NOSIZE = 1
Private Const FLAGS = SWP_NOMOVE Or SWP_NOSIZE
 
Private Sub Form_Load()
    SetWindowPos Me.hwnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
    'To "turn off" always on top use
    'SetWindowPos Me.Hwnd, HWND_NOTOPMOST, 0, 0, 0, 0, FLAGS
End Sub

[n00b scripter]

ok i try

[n00b scripter]

well how to make it not on top? i want to turn it on and off

[|2eM!x]

use the constants provided:

Private Const HWND_TOPMOST = -1
Private Const HWND_NOTOPMOST = -2
Private Const SWP_NOMOVE = 2
Private Const SWP_NOSIZE = 1
Private Const FLAGS = SWP_NOMOVE Or SWP_NOSIZE

[n00b scripter]

I dont aunderstand how to bind that to a command button?

[RhinoBull]

The same way the other const was used but don't forget to declare it first:

Private Sub Command2_Click()
    SetWindowPos Me.hWnd, HWND_NOTOPMOST, 0, 0, 0, 0, SWP_NOACTIVATE Or SWP_SHOWWINDOW _
        Or SWP_NOMOVE Or SWP_NOSIZE
End Sub

[n00b scripter]

whit this script my whole application disappear

[|2eM!x]

Private Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
 
Private Const HWND_TOPMOST = -1
Private Const HWND_NOTOPMOST = -2
Private Const SWP_NOMOVE = 2
Private Const SWP_NOSIZE = 1
Private Const FLAGS = SWP_NOMOVE Or SWP_NOSIZE
 
Private Sub Form_Load()
    SetWindowPos Me.hwnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
    [B]'To "turn off" always on top use
    'SetWindowPos Me.Hwnd, HWND_NOTOPMOST, 0, 0, 0, 0, FLAGS[/B]
End Sub

did you read this post?

[n00b scripter]

Yeah i did and now the turn on thing works but now it dissapears when i try the switch of button i have made it

Private Sub Command2_Click()
    SetWindowPos Me.hwnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
 
End Sub

[half flung pie]

Because of this right here:

Private Sub Command2_Click()
    SetWindowPos Me.hwnd, [B]HWND_TOPMOST,[/B] 0, 0, 0, 0, FLAGS
 
End Sub

Don't use HWND_TOPMOST again. That's a NoNo

[RhinoBull]

Heck knows what you're doing, though ...
The following sample simply toggles between "regular" and "topmost" modes - all you need is ONE command button so just copy and paste this code:

Option Explicit
 
Const HWND_TOPMOST = -1
Const HWND_NOTOPMOST = -2
Const SWP_NOSIZE = &H1
Const SWP_NOMOVE = &H2
Const SWP_NOACTIVATE = &H10
Const SWP_SHOWWINDOW = &H40
 
Private Declare Sub SetWindowPos Lib "User32" _
    (ByVal hWnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, _
    ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long)
 
Private Sub Command1_Click()
'============================
Static blnTopMost As Boolean
Dim lngPos As Long
 
    blnTopMost = Not blnTopMost
    
    If blnTopMost Then
        lngPos = HWND_TOPMOST
        Command1.Caption = "Make Regular Window"
    Else
        lngPos = HWND_NOTOPMOST
        Command1.Caption = "Make Topmost Window"
    End If
    
    SetWindowPos Me.hWnd, lngPos, 0, 0, 0, 0, _
                 SWP_NOACTIVATE Or SWP_SHOWWINDOW Or _
                 SWP_NOMOVE Or SWP_NOSIZE
 
End Sub
 
Private Sub Form_Load()
    Command1.Caption = "Make Topmost Window"
End Sub

[n00b scripter]

Whata... that script made the application fill out the screen!

[half flung pie]

Whata... that script made the application fill out the screen!

If you're talking about RhinoBull's script, it worked just fine for me ?????

[n00b scripter]

hmm weird

[half flung pie]

Post your project maybe someone can see if there is something besides your code

[n00b scripter]

Ok here it is. I dont think you will understand whats it is for

[n00b scripter]

Can any one help me?

[RhinoBull]

Your "problem" noob is setting form's windowstate to maximized, so simply comment it (as shown below):

Private Sub Command1_Click()
'InitializeRes
'''[b]Me.WindowState = 2[/b]
 
...

[n00b scripter]

Ty so much for helping me and excuse me for my noobness

[RhinoBull]

Not at all, are you kidding ... Enjoy it.