validation(resolved)

[vivian2u]

hi,

I want to do a validation on a textbox. it only accept numeric from -20 to 40.
below is part of my coding but i cant do the validation on the length and only accept -20 to 40. Please help.

Public Sub Val_Temp(TextObj As TextBox)

Dim i As Integer, n As Integer
Dim s As String, Char As Byte

i = TextObj.SelStart

For n = 1 To Len(TextObj)
Char = Asc(Mid(TextObj, n, 1))

If ((Char >= 48 And Char <= 57) Or (Char = 45 And n = 1) Then
s = s & Mid(TextObj, n, 1)
Else
i = i - 1
End If
Next n

If i > Len(s) Or i < 0 Then i = Len(s)

TextObj.Text = s
TextObj.SelStart = i
End Sub

[dee-u]

How about this?

If TextObj < -20 Or TextObj > 40 Then
    MsgBox "Invalid"
End If

[vivian2u]

it cant work here because i m using

Private Sub text1_Change()
Val_Temp text1
end sub

[|2eM!x]

how cant it work..?

[dee-u]

If Len(Abs(TextObject)) = 2 Then
    If TextObj < -20 Or TextObj > 40 Then
        MsgBox "Invalid"
    End If
Else
    MsgBox "Invalid"
End If

[vivian2u]

ABs cant accept "-"

if Len(Abs(TextObject)) = 2 Then

[microalps]

ABS accept all numerics, positive and negative, and return the absoloute value (disregards the negative sign). You may have to use Val(text) to convert from string to integer.

[vivian2u]

i got compile error ..variable required - can't assign to this expression when i use Abs

[dglienna]

Not sure if I'd do it this way, but to make it work, you need this:

If Len(Abs(val(TextObject.text))) = 2 Then
    If val(TextObj.text) < -20 Or val(TextObj.text) > 40 Then
        MsgBox "Invalid"
    End If
Else
    MsgBox "Invalid"
End If

[vivian2u]

it cant work.

i want a textbox validation buy using Private Sub text1_Change()

(a) it only accept numeric from -20 to 40.
(b) the "-" only allow in front
(c) if negative numeric , allow the length to 3 and not allow the user to press the 4th digit
(d) if posivive numeric, allow the length to 2 and not allow the user press the 3th digit.

my coding below is only work on (b)
Public Sub Val_Temp(TextObj As TextBox)

Dim i As Integer, n As Integer
Dim s As String, Char As Byte

i = TextObj.SelStart

For n = 1 To Len(TextObj)
Char = Asc(Mid(TextObj, n, 1))

If ((Char >= 48 And Char <= 57) Or (Char = 45 And n = 1) Then
s = s & Mid(TextObj, n, 1)
Else
i = i - 1
End If
Next n

If i > Len(s) Or i < 0 Then i = Len(s)

TextObj.Text = s
TextObj.SelStart = i
End Sub

[dglienna]

My routine won't work in Text_Change(), but it could be in Text_Validate(), or even Text_LostFocus()

[vivian2u]

but i want to have the validation in Text_Change(), any idea??

[dglienna]

You could check

1) for numerics and no decimal points
2) the '-' sign only at position 1
3) no more than 2 characters, unless #2 is true

it will fire each time something is put into or taken out of the textbox

[vivian2u]

can someone give me the coding in :

3) no more than 2 characters, unless #2 is true

[dglienna]

There are too many combinations for the change event. I've tried 3 different approaches, and each one crashed.

Why don't you want to use the keypress event? or the lost_focus event?

It would be much cleaner to code.

The change event fires when you hit backspace, or delete, and the length can be 0, but you can't use 0 in the mid statement. you can't compare the length to the previous instance either.

[vivian2u]

i thinking of the keypress even now... you are right...

hows the coding in keypress even ?

[dglienna]

Here is a start. I wasted too much time on the other mess trying to make it work. I'll look at it again tomorrow if you can't figure it out.

Option Explicit
 
Private Sub Form_Load()
  Text1.Text = ""
End Sub
 
Private Sub Text1_KeyPress(KeyAscii As Integer)
  If KeyAscii < 49 Or KeyAscii > 57 Then
    KeyAscii = 0
  Else
    If KeyAscii = 45 And Text1.Text <> "" Then
      KeyAscii = 0
    End If
  End If
End Sub

[vivian2u]

cant work...its not accept '-', because of

If KeyAscii < 49 Or KeyAscii > 57 Then
KeyAscii = 0

[dglienna]

keyascii = 45 is the '-'
i took that one out.

[pnish]

Give this a go.

Option Explicit
 
Dim IsNegative As Boolean
 
Private Sub Text1_Change()
 
    If Left$(Text1.Text, 1) = "-" Then
        Text1.MaxLength = 3
        IsNegative = True
    Else
        Text1.MaxLength = 2
        IsNegative = False
    End If
    
End Sub
 
Private Sub Text1_KeyPress(KeyAscii As Integer)
 
    Select Case KeyAscii
        Case vbKey0 To vbKey9                   ' These keys are OK
            If Len(Text1.Text) = 1 Then
                If Not IsNegative Then
                    If Val(Text1.Text) >= 4 Then
                        If KeyAscii > vbKey0 Then
                            KeyAscii = 0
                        End If
                    End If
                End If
            Else
                If Abs(Val(Text1.Text)) >= 2 Then
                    If KeyAscii > vbKey0 Then
                        KeyAscii = 0
                    End If
                End If
            End If
        Case 45                                 ' 45 is '-'
            If Len(Text1.Text) > 0 Then
                KeyAscii = 0
            End If
        Case vbKeyBack, vbKeyDelete             ' Allow backspace & delete
        Case Else
            KeyAscii = 0
    End Select
    
End Sub

[vivian2u]

this is exactly what i want but when it is negative it accept '0' for
-30 ,-40, -50, -60, -70, -80 and -90.

how can i correct this errors.
thanks

[pnish]

Did you try and figure out why it wasn't working properly? I've amended the code, this should do what you want.

Option Explicit
 
Dim IsNegative As Boolean
 
Private Sub Text1_Change()
 
    If Left$(Text1.Text, 1) = "-" Then
        Text1.MaxLength = 3
        IsNegative = True
    Else
        Text1.MaxLength = 2
        IsNegative = False
    End If
    
End Sub
 
Private Sub Text1_KeyPress(KeyAscii As Integer)
 
    Select Case KeyAscii
        Case vbKey0 To vbKey9                   ' These keys are OK
            If Len(Text1.Text) = 1 Then
                If Not IsNegative Then
                    If Val(Text1.Text) > 4 Then
                        KeyAscii = 0
                    ElseIf Val(Text1.Text) = 4 Then
                        If KeyAscii > vbKey0 Then
                            KeyAscii = 0
                        End If
                    End If
                End If
            Else
                If Abs(Val(Text1.Text)) > 2 Then
                    KeyAscii = 0
                ElseIf Abs(Val(Text1.Text)) = 2 Then
                    If KeyAscii > vbKey0 Then
                        KeyAscii = 0
                    End If
                End If
            End If
        Case 45                                 ' 45 is '-'
            If Len(Text1.Text) > 0 Then
                KeyAscii = 0
            End If
        Case vbKeyBack, vbKeyDelete             ' Allow backspace & delete
        Case Else
            KeyAscii = 0
    End Select
    
End Sub

I know the code is sorely lacking in comments, so why don't you spend some time stepping through the code to try and understand how it works. You may surprise yourself and come up with a better way to do it.

BTW There is still a subtle logic error in the code. See if you can figure out what it is and then fix it.

[vivian2u]

yes, this is exactly what i want and it works perfectly. Thanks again