Very Hard Question (RESOLVED)

[packetVB]

Im creating custom controls and I need to use my own windows procedure.
I know I can replace the winproc using something like

SetWindowLong(m_hwnd, GWL_WNDPROC, AddressOf CtrlHandler)
But I can only get it to work with the Ctrlhandler function in a module.
How can I get this to work so I can have my message handler in the class?? Is it possible?

[packetVB]

NeverMind,

After much thought and trial and error, I figured it out.

[Bombdrop]

Could you please show the board how you resolved this, as i'm sure this will help others.

[packetVB]

Sure,

Ill go with an example textbox window

'vbTextBox custom class
Private m_parentHwnd As Long
Private m_hwnd As Long
Private m_ControlID As Long
Private OldWndProc As Long
Public ObjectPtr As Long
 
Private Sub Class_Initialize()
    m_hwnd = 0
    'copy this class object to ObjectPtr, will use it later
    CopyMemory ObjectPtr, Me, 4
End Sub
 
'Message Handling for this class window
Public Function MessageHandler(ByVal hWnd As Long, ByVal uMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
 
    If uMsg = WM_LBUTTONDOWN Then
        Debug.Print "ButtonDown"
    End If
    MessageHandler = CallWindowProc(OldWndProc, hWnd, uMsg, wParam, lParam)
End Function
 
Public Function CreateTextBox(pLeft As Long, pTop As Long, pWidth As Long, pHeight As Long, pHwnd As Long, pText As String, CtrlID As Long, ExtraStyle As Long) As Long
    m_parentHwnd =pHwnd
    ReturnValue = CreateWindowEx(ExStyle, "EDIT", pText, WS_VISIBLE Or WS_CHILD Or ES_LEFT Or WS_TABSTOP Or ExtraStyle, pLeft, pTop, pWidth, pHeight, pHwnd, CtrlID, App.hInstance, ByVal 0)
 
    if Returnvalue=0 then exit function
    m_hwnd = ReturnValue
    'now that we created the window put the ObjectPtr (which is pointer to this class object)
        'into the GWL_USERDATA of the window
        SetWindowLong m_hwnd, GWL_USERDATA, ObjectPtr
 
        'the CtrlHandler is responsible for sending message to correct
        'class object
        OldWndProc = SetWindowLong(m_hwnd, GWL_WNDPROC, AddressOf CtrlHandler)
        'ShowWindow m_hwnd, SW_SHOWNORMAL
        CreateTextBox = m_hwnd
 
End Function

Now we just created a window and replaced the windows procedure with one called CtrlHandler, that will be public in a module like so.

'Public Functions module
Public OO as Object
 
Public Function CtrlHandler(ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Dim ObjectPointer As Long
    'get the pointer that we put into Userdata when we create the window in the class    
    ObjectPointer = GetWindowLong(hWnd, GWL_USERDATA)
    'if its not 0
    If ObjectPointer <> 0 Then
        'copy memory to the tmp object OO
        'the tmp object must be PUBLIC declared in the module
        CopyMemory OO, ObjectPointer, 4
        'Call the Class function
        CtrlHandler = OO.MessageHandler(hWnd, Msg, wParam, lParam)
    Else
        'do the default (for forms)
        CtrlHandler = DefWindowProc(hWnd, Msg, wParam, lParam)
    End If
End Function

Not sure how well this will work, seems to be working pretty good for now.

Of course GetWindowLong,CopyMemory,DefWindowProc are API's, check all APINET for how to declare and for the Const.

Cheers,
packetvb

[packetVB]

yo admins

Can you move this to the code bank.
Dont want to double post.


packetvb

[Wokawidget]

You could always use this subclassing module that does it all nice an neatly for you and handles multiple instances of subclassed controls.

Woka