SQL Servers

[vbgladiator]

I use the following code to display all the SQL servers on the network:

Option Explicit
 
Private Declare Function lstrlenW Lib "kernel32" (ByVal lpString As Long) As Long
 
Private Declare Function NetServerEnum Lib "netapi32" ( _
       strServername As Any, _
       ByVal level As Long, _
       bufptr As Long, _
       ByVal prefmaxlen As Long, _
       entriesread As Long, _
       totalentries As Long, _
       ByVal servertype As Long, _
       strDomain As Any, _
       resumehandle As Long) As Long
 
 
Private Declare Function NetApiBufferFree Lib "Netapi32.dll" _
(ByVal lpBuffer As Long) As Long
 
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
(Destination As Any, Source As Any, ByVal Length As Long)
 
Private Const SV_TYPE_SERVER As Long = &H2
Private Const SV_TYPE_SQLSERVER As Long = &H4
 
Private Type SV_100
 platform As Long
 Name As Long
End Type
 
 
Public DEBUGMODE As Boolean
 
 
Public Function GetSQLServers(DomainName As String) As String()
   Dim l As Long
   Dim entriesread As Long
   Dim totalentries As Long
   Dim hREsume As Long
   Dim bufptr As Long
   Dim level As Long
   Dim prefmaxlen As Long
   Dim lType As Long
   Dim Domain() As Byte
   Dim i As Long
   Dim sv100 As SV_100
   Dim Servers() As String
 
   level = 100
   prefmaxlen = -1
 
   lType = SV_TYPE_SQLSERVER
   Domain = DomainName & vbNullChar
   l = NetServerEnum(ByVal 0&, _
           level, _
           bufptr, _
           prefmaxlen, _
           entriesread, _
           totalentries, _
           lType, _
           Domain(0), _
           hREsume)
 
   If l = 0 Or l = 234& Then
       ReDim Servers(entriesread - 1)
       For i = 0 To entriesread - 1
           CopyMemory sv100, ByVal bufptr, Len(sv100)
           Servers(i) = Pointer2stringw(sv100.Name)
           bufptr = bufptr + Len(sv100)
       Next i
   Else
       ReDim Servers(0)
       Servers(0) = "N/A"
   End If
   NetApiBufferFree bufptr
   GetSQLServers = Servers
End Function
 
Private Function Pointer2stringw(ByVal l As Long) As String
   Dim buffer() As Byte
   Dim nLen As Long
   '
   nLen = lstrlenW(l) * 2
   If nLen Then
       ReDim buffer(0 To (nLen - 1)) As Byte
       CopyMemory buffer(0), ByVal l, nLen
       Pointer2stringw = buffer
   End If
End Function

However, if I stop running the server on my machine and then resume it again, it won't show up again. Any ideas why?

[vbgladiator]

Nervermind,

It seems that it needs few minutes before finding it again. Weird.

[spoiledkid]

I'd use SQLDMO instead.

http://www.vbforums.com/showthread.p...ghlight=SQLDMO