Installerless install?

[Destined Soul]

Hi everyone,

I have quite a problem at the moment. I've been asked to produce a database interface program. No problem there. It uses such controls as the DBGrid, DataEnvironment and DataReport. I can create a installer using the Package and Deployment Wizard (PDW) with no problems, and a test computer worked fine.

However, I've been asked to, essentially, put the exe and related files in a networked folder so that people just have to run it, instead of explicitly installing it. I know this is pretty much impossible, unless people already have the files registered on their machine.

A little note here: using PDW to install, then uninstalling the program still allows my program to be run from the networked folder on the test machine. It didn't work before the install.

Any ideas here? I was thinking, if I have to do it the way I've been asked, I'd make the initial form run a silent install. However, it seems like I'd just be writing my own little installer.

Any help/advice is appreciated. Please and thanx.

Destined

[kleinma]

create the installer package.. but don't include your actual exe... that way they will get the support files they need (dlls, ocxs, VB Runtimes) but they wont get a local copy of your exe... that you put on the shared drive and then everyone should be able to access it and have it work.. this is also good because if you make changes to your app you just have to replace the shared drive one instead of individually on a bunch of PCs...

the reason it worked when you installed and then uninstalled is because the uninstall doesnt remove the ocxs and dlls that get registered on the system during the install

[Destined Soul]

Thanx kleinma, I never did think of that. I guess it could be a "if this did not work, run this install file".

A couple of more questions in general...

1) Is it possible to just put the dependant files into the dir with the exe and have it work, or do they still need to be registered

2) If they need to be registered, can I register a local copy then unregister it even if the file exists (and is registered) on the user's computer?

Thanx.

Destined

[kleinma]

Originally posted by Destined Soul
Thanx kleinma, I never did think of that. I guess it could be a "if this did not work, run this install file".

A couple of more questions in general...

1) Is it possible to just put the dependant files into the dir with the exe and have it work, or do they still need to be registered

2) If they need to be registered, can I register a local copy then unregister it even if the file exists (and is registered) on the user's computer?

Thanx.

Destined

yeah you can get creative in order to make things work for ya..

for example.. i have some applications that sit on a shared drive... when you open up the master application it runs a check to see if the computer has the needed components.. and if it does, then it opens the desired application... if not it copies down and registers the needed files.. then launches the program... it even checks file versions in case i make an update to a DLL.. i can just change the version number of it.. and next time the user runs my app.. they will get the newest dll version and it will remove the old one

[Destined Soul]

Originally posted by kleinma
yeah you can get creative in order to make things work for ya..

for example.. i have some applications that sit on a shared drive... when you open up the master application it runs a check to see if the computer has the needed components.. and if it does, then it opens the desired application... if not it copies down and registers the needed files.. then launches the program... it even checks file versions in case i make an update to a DLL.. i can just change the version number of it.. and next time the user runs my app.. they will get the newest dll version and it will remove the old one

Actually, this is pretty much what I was thinking I'd have to do. I'm assuming there's some nice API to check a DLL's version? (I know there's one to register (and unregister) DLLs..)

Not to bug you, but would you be able to post any of that code to check versions and register the files? (Or a link?)

Thanx.

Destined

PS - That was a pretty fast reply.

[kleinma]

i cant post the project because of company security reasons.. but i can give you some pieces to get you going..

here is code you can put in a module to check file versions

you just pass the file name to the GetFileVersion function

Option Explicit
 
Private Type VS_FIXEDFILEINFO
   dwSignature As Long
   dwStrucVersionl As Integer     '  e.g. = &h0000 = 0
   dwStrucVersionh As Integer     '  e.g. = &h0042 = .42
   dwFileVersionMSl As Integer    '  e.g. = &h0003 = 3
   dwFileVersionMSh As Integer    '  e.g. = &h0075 = .75
   dwFileVersionLSl As Integer    '  e.g. = &h0000 = 0
   dwFileVersionLSh As Integer    '  e.g. = &h0031 = .31
   dwProductVersionMSl As Integer '  e.g. = &h0003 = 3
   dwProductVersionMSh As Integer '  e.g. = &h0010 = .1
   dwProductVersionLSl As Integer '  e.g. = &h0000 = 0
   dwProductVersionLSh As Integer '  e.g. = &h0031 = .31
   dwFileFlagsMask As Long        '  = &h3F for version "0.42"
   dwFileFlags As Long            '  e.g. VFF_DEBUG Or VFF_PRERELEASE
   dwFileOS As Long               '  e.g. VOS_DOS_WINDOWS16
   dwFileType As Long             '  e.g. VFT_DRIVER
   dwFileSubtype As Long          '  e.g. VFT2_DRV_KEYBOARD
   dwFileDateMS As Long           '  e.g. 0
   dwFileDateLS As Long           '  e.g. 0
End Type
Private Declare Function GetFileVersionInfo Lib "Version.dll" Alias "GetFileVersionInfoA" (ByVal lptstrFilename As String, ByVal dwhandle As Long, ByVal dwlen As Long, lpData As Any) As Long
Private Declare Function GetFileVersionInfoSize Lib "Version.dll" Alias "GetFileVersionInfoSizeA" (ByVal lptstrFilename As String, lpdwHandle As Long) As Long
Private Declare Function VerQueryValue Lib "Version.dll" Alias "VerQueryValueA" (pBlock As Any, ByVal lpSubBlock As String, lplpBuffer As Any, puLen As Long) As Long
Private Declare Sub MoveMemory Lib "kernel32" Alias "RtlMoveMemory" (dest As Any, ByVal Source As Long, ByVal length As Long)
 
Dim FileVer As String, ProdVer As String
Public Function GetFileVersion(strFullFileName As String) As String
    Dim rc As Long, lDummy As Long, sBuffer() As Byte
    Dim lBufferLen As Long, lVerPointer As Long, udtVerBuffer As VS_FIXEDFILEINFO
    Dim lVerbufferLen As Long
    
    '*** Get size ****
    lBufferLen = GetFileVersionInfoSize(strFullFileName, lDummy)
    If lBufferLen < 1 Then
       MsgBox "No Version Info available!"
       Exit Function
    End If
    
    '**** Store info to udtVerBuffer struct ****
    ReDim sBuffer(lBufferLen)
    rc = GetFileVersionInfo(strFullFileName, 0&, lBufferLen, sBuffer(0))
    rc = VerQueryValue(sBuffer(0), "\", lVerPointer, lVerbufferLen)
    MoveMemory udtVerBuffer, lVerPointer, Len(udtVerBuffer)
    
    '**** Determine File Version number ****
    FileVer = Format$(udtVerBuffer.dwFileVersionMSh) & "." & Format$(udtVerBuffer.dwFileVersionMSl) & "." & Format$(udtVerBuffer.dwFileVersionLSh) & "." & Format$(udtVerBuffer.dwFileVersionLSl)
    
    '**** Determine Product Version number ****
    ProdVer = Format$(udtVerBuffer.dwProductVersionMSh) & "." & Format$(udtVerBuffer.dwProductVersionMSl) & "." & Format$(udtVerBuffer.dwProductVersionLSh) & "." & Format$(udtVerBuffer.dwProductVersionLSl)
 
    GetFileVersion = FileVer
End Function

[Destined Soul]

Thanx a bunch kleinma.

I'll let you know how it goes once I get the rest of it working.

Destined