Form to flash

[nanfa]

Hi Guys,

Please does anyone know how I can make a small form flash on the screen? I need my program to pop up little announcements once in a while.

Thanks

Nanfa

[Hack]

Const FLASHW_STOP = 0 'Stop flashing. The system restores the window to its original state.
Const FLASHW_CAPTION = &H1 'Flash the window caption.
Const FLASHW_TRAY = &H2 'Flash the taskbar button.
Const FLASHW_ALL = (FLASHW_CAPTION Or FLASHW_TRAY) 'Flash both the window caption and taskbar button. This is equivalent to setting the FLASHW_CAPTION Or FLASHW_TRAY flags.
Const FLASHW_TIMER = &H4 'Flash continuously, until the FLASHW_STOP flag is set.
Const FLASHW_TIMERNOFG = &HC 'Flash continuously until the window comes to the foreground.
Private Type FLASHWINFO
    cbSize As Long
    hwnd As Long
    dwFlags As Long
    uCount As Long
    dwTimeout As Long
End Type
Private Declare Function FlashWindowEx Lib "user32" (pfwi As FLASHWINFO) As Boolean
Private Sub Form_Load()
    'KPD-Team 1999
    'URL: [url]http://www.allapi.net/[/url]
    'E-Mail: [email][email protected][/email]
    Dim FlashInfo As FLASHWINFO
    'Specifies the size of the structure.
    FlashInfo.cbSize = Len(FlashInfo)
    'Specifies the flash status
    FlashInfo.dwFlags = FLASHW_ALL Or FLASHW_TIMER
    'Specifies the rate, in milliseconds, at which the window will be flashed. If dwTimeout is zero, the function uses the default cursor blink rate.
    FlashInfo.dwTimeout = 0
    'Handle to the window to be flashed. The window can be either opened or minimized.
    FlashInfo.hwnd = Me.hwnd
    'Specifies the number of times to flash the window.
    FlashInfo.uCount = 0
    FlashWindowEx FlashInfo
End Sub
Private Sub Form_Paint()
    Me.CurrentX = 0
    Me.CurrentY = 0
    Me.Print "Click me !"
End Sub

[Megatron]

That makes the title bar flash, not the Form. To make the actual Form flash, use the following code (requires a timer)

Private Sub Timer1_Timer()

    Me.Visible = Not Me.Visible
    
End Sub

[Hack]

Originally posted by Megatron
That makes the title bar flash, not the Form [my post]

True, but if the whole form flashes would'nt it be hard to read what was on it?

nanfa: Are you looking to flash the entire form or just its title bar?

[Megatron]

Well he has both solutions now.