Treeview control

[graham23s]

Hey Guys,

I have a treeview control on my form, i am trying to load an xml into the treeview to show cities/states (example at the bottom of the page)

The xml that treeview is loading from looks like:

<?xml version="1.0" encoding="utf-8" ?>
<Locations>
  <Group name="US States">
    <Group name="Alabama">
      <Location name="Tuscaloosa" url="tsc/{0}" />
      <Location name="Montgomery" url="mgm/{0}" />
      <Location name="Mobile" url="mob/{0}" />
      <Location name="Huntsville" url="hsv/{0}" />
      <Location name="Gadsden-Anniston" url="anb/{0}" />
      <Location name="{Florence|Muscle Shoals}" url="msl/{0}" />
      <Location name="Dothan" url="dhn/{0}" />
      <Location name="Birmingham" url="bhm/{0}" />
      <Location name="Auburn" url="aub/{0}" />
    </Group>
    <Location name="Alaska" url="anc/{0}" />
    <Group name="Arizona">
      <Location name="Yuma" url="yum/{0}" />
      <Location name="Tucson" url="tus/{0}" />
      <Location name="Sierra Vista " url="fhu/{0}" />
      <Location name="Prescott" url="prc/{0}" />
      <Group name="Phoenix">
        <Location name="{Central|South Phoenix|S. Phoenix}" url="phx/{0}/cph"/>
        <Location name="East Valley" url="phx/{0}/evl"/>
        <Location name="Phoenix North" url="phx/{0}/nph"/>
        <Location name="West Valley" url="phx/{0}/wvl"/>
      </Group>
      <Location name="Mohave County" url="mhv/{0}" />
      <Location name="{Flagstaff|Sedona}" url="flg/{0}" />
    </Group>
</locations>

I'v never really used the treeview control before, i can load xml documents ok, i'm unsure how to then load the data into the treeview

any help would be appreciated

thanks guys

Graham

[DerekM]

Why don't you just manually add the nodes?

[weirddemon]

Why don't you just manually add the nodes?

It may be that he wants to update the list without re-coding the program.

Graham23s, I did a quick Google search and found this.

It looks pretty solid.

[graham23s]

Hey Guys,

That was a great example WD, i downloaded and implemented it:

Imports System.Xml
 
Public Class Form1
    Inherits System.Windows.Forms.Form
 
#Region " Windows Form Designer generated code "
 
    Public Sub New()
        MyBase.New()
 
        'This call is required by the Windows Form Designer.
        InitializeComponent()
 
        'Add any initialization after the InitializeComponent() call
 
    End Sub
 
    'Form overrides dispose to clean up the component list.
    Protected Overloads Overrides Sub Dispose(ByVal disposing As Boolean)
        If disposing Then
            If Not (components Is Nothing) Then
                components.Dispose()
            End If
        End If
        MyBase.Dispose(disposing)
    End Sub
 
    'Required by the Windows Form Designer
    Private components As System.ComponentModel.IContainer
 
    'NOTE: The following procedure is required by the Windows Form Designer
    'It can be modified using the Windows Form Designer.  
    'Do not modify it using the code editor.
    Friend WithEvents trvItems As System.Windows.Forms.TreeView
    <System.Diagnostics.DebuggerStepThrough()> Private Sub InitializeComponent()
        Me.trvItems = New System.Windows.Forms.TreeView
        Me.SuspendLayout()
        '
        'trvItems
        '
        Me.trvItems.CheckBoxes = True
        Me.trvItems.Dock = System.Windows.Forms.DockStyle.Fill
        Me.trvItems.Location = New System.Drawing.Point(0, 0)
        Me.trvItems.Name = "trvItems"
        Me.trvItems.Size = New System.Drawing.Size(292, 309)
        Me.trvItems.TabIndex = 0
        '
        'Form1
        '
        Me.AutoScaleBaseSize = New System.Drawing.Size(5, 13)
        Me.ClientSize = New System.Drawing.Size(292, 309)
        Me.Controls.Add(Me.trvItems)
        Me.Name = "Form1"
        Me.Text = "Form1"
        Me.ResumeLayout(False)
 
    End Sub
 
#End Region
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim file_name As String = Application.StartupPath
        file_name = file_name.Substring(0, file_name.LastIndexOf("\")) & "\test.xml"
        LoadTreeViewFromXmlFile(file_name, trvItems)
    End Sub
 
    ' Load a TreeView control from an XML file.
    Private Sub LoadTreeViewFromXmlFile(ByVal file_name As String, ByVal trv As TreeView)
        ' Load the XML document.
        Dim xml_doc As New XmlDocument
        xml_doc.Load(file_name)
 
        ' Add the root node's children to the TreeView.
        trv.Nodes.Clear()
        AddTreeViewChildNodes(trv.Nodes, xml_doc.DocumentElement)
    End Sub
 
    ' Add the children of this XML node 
    ' to this child nodes collection.
    Private Sub AddTreeViewChildNodes(ByVal parent_nodes As TreeNodeCollection, ByVal xml_node As XmlNode)
        For Each child_node As XmlNode In xml_node.ChildNodes
            ' Make the new TreeView node.
            Dim new_node As TreeNode = parent_nodes.Add(child_node.Name)
 
            ' Recursively make this node's descendants.
            AddTreeViewChildNodes(new_node.Nodes, child_node)
 
            ' If this is a leaf node, make sure it's visible.
            If new_node.Nodes.Count = 0 Then new_node.EnsureVisible()
        Next child_node
    End Sub
 
    Private Sub trvItems_AfterSelect(ByVal sender As System.Object, ByVal e As System.Windows.Forms.TreeViewEventArgs) Handles trvItems.AfterSelect
 
    End Sub
End Class

simplest xml:

<?xml version="1.0"?>
<Tree>
    <US>
        <city>Alaska</city>
    </US>
    <UK>
        <city>Aberdeen</city>
    </UK>
</Tree>

Instead of displaying the city, it displays the word "city" in the treeview like:

Is there a way i could display the innertext of the node?

thanks guys

Graham

[Pradeep1210]

' Load a TreeView control from an XML file.
Private Sub LoadTreeViewFromXmlFile(ByVal file_name As String, ByVal trv As TreeView)
    Dim xml_doc As New XmlDocument
    xml_doc.Load(file_name)
    trv.Nodes.Clear()
    AddTreeViewChildNodes(trv.Nodes, xml_doc.DocumentElement)
End Sub
 
' Add the children of this XML node to this child nodes collection.
Private Sub AddTreeViewChildNodes(ByVal parent_nodes As TreeNodeCollection, ByVal xml_node As XmlNode)
    For Each child_node As XmlNode In xml_node.ChildNodes
        Dim new_node As TreeNode = parent_nodes.Add(GetNodeText(child_node))
        AddTreeViewChildNodes(new_node.Nodes, child_node)
        If new_node.Nodes.Count = 0 Then new_node.EnsureVisible()
    Next
End Sub
 
Private Function GetNodeText(ByVal node As XmlNode) As String
    ''Put here whatever you want displayed as treeview text
    If node.Attributes IsNot Nothing Then
        For Each attr As XmlAttribute In node.Attributes
            If attr.Name = "name" Then Return attr.Value
        Next
    End If
    If node.InnerText <> "" Then Return node.InnerText
    Return node.Name
End Function