Program In Taskbar [RESOLVED]

[Aaron Smith]

Hi Everyone

What i am wanting to do is have a program which is not shown in the taskbar so all i would do for that would be make the property for this false

I then need to have an icon in the system tray (beside the clock) when the program is minimized and then when the icon is double clicked it will open the program which has been minimized.

Hopefully this is possible.

Thanks

[HanneSThEGreaT]

Have a look at this example
Hopefully it helps!

[Aaron Smith]

thanks for your help but sadly my internet serivce cannot download as shared network

If you could post code that would be helpful.

Thanks

[HanneSThEGreaT]

Here's the code, you just need to add some controls to the form, in order for it to work..

Option Explicit
 
      'Declare a user-defined variable to pass to the Shell_NotifyIcon
      'function.
      Private Type NOTIFYICONDATA
         cbSize As Long
         hWnd As Long
         uId As Long
         uFlags As Long
         uCallBackMessage As Long
         hIcon As Long
         szTip As String * 64
      End Type
 
      'Declare the constants for the API function. These constants can be
      'found in the header file Shellapi.h.
 
      'The following constants are the messages sent to the
      'Shell_NotifyIcon function to add, modify, or delete an icon from the
      'taskbar status area.
      Private Const NIM_ADD = &H0
      Private Const NIM_MODIFY = &H1
      Private Const NIM_DELETE = &H2
 
      'The following constant is the message sent when a mouse event occurs
      'within the rectangular boundaries of the icon in the taskbar status
      'area.
      Private Const WM_MOUSEMOVE = &H200
 
      'The following constants are the flags that indicate the valid
      'members of the NOTIFYICONDATA data type.
      Private Const NIF_MESSAGE = &H1
      Private Const NIF_ICON = &H2
      Private Const NIF_TIP = &H4
 
      'The following constants are used to determine the mouse input on the
      'the icon in the taskbar status area.
 
      'Left-click constants.
      Private Const WM_LBUTTONDBLCLK = &H203   'Double-click
      Private Const WM_LBUTTONDOWN = &H201     'Button down
      Private Const WM_LBUTTONUP = &H202       'Button up
 
      'Right-click constants.
      Private Const WM_RBUTTONDBLCLK = &H206   'Double-click
      Private Const WM_RBUTTONDOWN = &H204     'Button down
      Private Const WM_RBUTTONUP = &H205       'Button up
 
      'Declare the API function call.
      Private Declare Function Shell_NotifyIcon Lib "shell32" _
         Alias "Shell_NotifyIconA" _
         (ByVal dwMessage As Long, pnid As NOTIFYICONDATA) As Boolean
 
      'Dimension a variable as the user-defined data type.
      Dim nid As NOTIFYICONDATA
 
      Private Sub cmdAdd_Click()
         'Click this button to add an icon to the taskbar status area.
 
         'Set the individual values of the NOTIFYICONDATA data type.
         nid.cbSize = Len(nid)
         nid.hWnd = frmTaskIcon.hWnd
         nid.uId = vbNull
         nid.uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
         nid.uCallBackMessage = WM_MOUSEMOVE
         nid.hIcon = frmTaskIcon.Icon
         nid.szTip = "Taskbar Status Area Sample Program" & vbNullChar
 
         'Call the Shell_NotifyIcon function to add the icon to the taskbar
         'status area.
         Shell_NotifyIcon NIM_ADD, nid
      End Sub
 
      Private Sub cmdDelete_Click()
         'Click this button to delete the added icon from the taskbar
         'status area by calling the Shell_NotifyIcon function.
         Shell_NotifyIcon NIM_DELETE, nid
      End Sub
 
      Private Sub Form_Load()
         'Set the captions of the command button when the form loads.
         cmdAdd.Caption = "Add an Icon"
         cmdDelete.Caption = "Delete Icon"
         
         'note once icon is visible, double click it,
         'to choose own icon.  Or right click to
         'specify tooltips
         
      End Sub
 
      Private Sub Form_Terminate()
         'Delete the added icon from the taskbar status area when the
         'program ends.
         Shell_NotifyIcon NIM_DELETE, nid
      End Sub
 
      Private Sub Form_MouseMove _
         (Button As Integer, _
          Shift As Integer, _
          X As Single, _
          Y As Single)
          'Event occurs when the mouse pointer is within the rectangular
          'boundaries of the icon in the taskbar status area.
          Dim msg As Long
          Dim sFilter As String
          msg = X / Screen.TwipsPerPixelX
          Select Case msg
             Case WM_LBUTTONDOWN
             Case WM_LBUTTONUP
             Case WM_LBUTTONDBLCLK
             cdTask.DialogTitle = "Select an Icon"
             sFilter = "Icon Files (*.ico)|*.ico"
             sFilter = sFilter & "|All Files (*.*)|*.*"
             cdTask.Filter = sFilter
             cdTask.ShowOpen
             If cdTask.FileName <> "" Then
                frmTaskIcon.Icon = LoadPicture(cdTask.FileName)
                nid.hIcon = frmTaskIcon.Icon
                Shell_NotifyIcon NIM_MODIFY, nid
             End If
             Case WM_RBUTTONDOWN
                Dim ToolTipString As String
                ToolTipString = InputBox("Enter the new ToolTip:", _
                                  "Change ToolTip")
                If ToolTipString <> "" Then
                   nid.szTip = ToolTipString & vbNullChar
                   Shell_NotifyIcon NIM_MODIFY, nid
                End If
             Case WM_RBUTTONUP
             Case WM_RBUTTONDBLCLK
          End Select
      End Sub

[Wokawidget]

If you click on the link in my sig, SysTray, then you can download my code.
The code basically does what HanneSThEGreaT posted, but it's a little more structures, elegant and a few more features (like adding menus at runtime so when you right click on the icon...blah blah). It also allows you to annimate the systray icon.
Full demo and source is included. The demo included the functionality you want, hiding the form to the systray when minimised.

If you have any questions then give me a shout.

Woka

[Aaron Smith]

thank you both for you help

If you have any questions then give me a shout.

I have not had a change to try this out but when i do if i have any difficulties then i will let you know