enumerating task manager apps

[pulSSSar]

um ... one other thing

can you enumerate all the applications showing in the applications tab of task manager for NT/2K

i know how to enumerate all the processes running, or all the services... but i want the full titles of each app showing in the applications tab... mainly so i can check the internet explorer titles of the pages that users are viewing

[chrisjk]

In a module

Private Declare Function EnumWindows Lib "user32" (ByVal lpEnumFunc As Long, ByVal lParam As Long) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function IsWindowVisible Lib "user32" (ByVal hwnd As Long) As Long
 
Private Const WM_GETTEXT = &HD
 
Private aCaptions() As String
Private lCount As Long
 
Public Function GetAllCaptions() As Variant
    lCount = 0
    Call EnumWindows(AddressOf EnumWindowsProc, 0&)
    If lCount Then ReDim Preserve aCaptions(lCount - 1)
    GetAllCaptions = IIf(lCount, aCaptions, Array())
End Function
 
Private Function EnumWindowsProc(ByVal hwnd As Long, ByVal lParam As Long) As Long
    Dim sBuffer As String * 260
    If IsWindowVisible(hwnd) Then
        ReDim Preserve aCaptions(lCount)
        aCaptions(lCount) = Left(sBuffer, SendMessage(hwnd, WM_GETTEXT, 260, ByVal sBuffer))
        If Len(Trim(aCaptions(lCount))) Then lCount = lCount + 1
    End If
    EnumWindowsProc = hwnd
End Function

In a form (with listbox - List1)

Private Sub Command1_Click()
 
    Dim vCaps As Variant
    Dim lIndex As Long
    
    vCaps = GetAllCaptions()
    List1.Clear
    For lIndex = 0 To UBound(vCaps)
        List1.AddItem vCaps(lIndex)
    Next
 
End Sub

[pulSSSar]

j33z m8

ur a bl00dy L3g3nD

seriously ... thanks man

j00 da m4s73r