Form opens in removed monitor!!?

[JohnPotier]

Q: How do I detect if a connected (?) monitor is still there when my application starts?

Background:
I'm so clever and writes the position and size of a window when application ends. The problem is imminent next time the application starts - if the monitor is not connected anymore, the form opens up off screen.

How can I detect if a coordinate (left and top) is still valid when the application starts? How can I detect that a coordinate is on a visible screen area?

Current workaround:
Startup form has KeyPreview=True and if Ctrl+Alt+x is pressed, the form is moved to 0,0 - which is in the upper left corner of the main window.

[baka]

well do a comparison.

hMonitor = MonitorFromWindow(Main.hwnd, 1&)
GetMonitorInfo hMonitor, tagMONITORINFO

should give u everything u need to know the monitor where the APP is about to show.
compare and see if its OK, otherwise RESET.

[Elroy]

I just set this up for a Form1 test:

Option Explicit
Private Type RECT
    Left   As Long
    Top    As Long
    Right  As Long ' This is +1 (right - left = width)
    Bottom As Long ' This is +1 (bottom - top = height)
End Type
Private Type MONITORINFO
    cbSize As Long
    rcMonitor As RECT
    rcWork As RECT
    dwFlags As Long
End Type
Private Declare Function GetWindowRect Lib "user32" (ByVal hWnd As Long, lpRect As RECT) As Long
Private Declare Function GetMonitorInfo Lib "user32.dll" Alias "GetMonitorInfoA" (ByVal hMonitor As Long, ByRef lpmi As MONITORINFO) As Long
Private Declare Function MonitorFromWindow Lib "user32.dll" (ByVal hWnd As Long, ByVal dwFlags As Long) As Long

Public Function FormIsFullyOnMonitor(frm As Form) As Boolean
    ' This tells us whether or not a form is FULLY visible on its monitor.
    '
    Dim hMonitor As Long
    Dim r1 As RECT
    Dim r2 As RECT
    Dim uMonInfo As MONITORINFO
    '
    hMonitor = hMonitorForForm(frm)
    GetWindowRect frm.hWnd, r1
    uMonInfo.cbSize = LenB(uMonInfo)
    GetMonitorInfo hMonitor, uMonInfo
    r2 = uMonInfo.rcWork
    '
    FormIsFullyOnMonitor = (r1.Top >= r2.Top) And (r1.Left >= r2.Left) And (r1.Bottom <= r2.Bottom) And (r1.Right <= r2.Right)
End Function

Public Function hMonitorForForm(frm As Form) As Long
    ' The monitor that the window is MOSTLY on.
    Const MONITOR_DEFAULTTONULL = &H0
    hMonitorForForm = MonitorFromWindow(frm.hWnd, MONITOR_DEFAULTTONULL)
End Function



Private Sub Form_Load()


    If Not FormIsFullyOnMonitor(Me) Then
        Me.Left = (Screen.Width - Me.Width) / 2
        Me.Top = (Screen.Height - Me.Height) / 2
    End If

End Sub

That should get you going.

I actually have a more sophisticated way of centering a form, but the above is a quick-and-dirty way to get it done (using the Screen object). If/since you're saving your form's last location, the above code will keep you out of trouble.

I have similar code in ALL of my forms that are for production/distribution.

[Elroy]

Also, if this is all running on a network, be sure to save your monitor locations locally (individually for each computer using the application). I typically use the registry for this. SaveSetting/GetSetting works perfectly, and they stay local to the machine.

[JohnPotier]

Thanks baka & Elroy. Elroy's code works in initial test :- ) Let me bake it into some of my other projects and test.

[yereverluvinuncleber]

You know, some major applications continue to operate and open on the removed monitor - they have no such code in them that allows them to run on the currently showing screen, firefox for example. Maybe it is a pointer to the new direction... GUI-less applications.

[Elroy]

Thanks baka & Elroy. Elroy's code works in initial test :- ) Let me bake it into some of my other projects and test.

John, hopefully you know that you can pull those procedure out of that Form1, and put them in some general purpose BAS module somewhere. That's why I left them as "Public" procedures. And the API declarations would have to be moved too.

[dilettante]

This is why we have GetWindowPlacement function and SetWindowPlacement function.

If the information specified in WINDOWPLACEMENT would result in a window that is completely off the screen, the system will automatically adjust the coordinates so that the window is visible, taking into account changes in screen resolution and multiple monitor configuration.

Using anything else is a mistake.

[baka]

of all API I have tried so far the best one is the 2 I posted.
can handle everything u need. both to check the monitor your app runs from and all needed data to center it, maximize, fullscreen as it also read the taskbar.
I have also "restore" specific functions but I only store the size and if maxi or full, not left/top position, that I dont care. works everytime.

[xiaoyao]

I have developed a VB plug-in for multi-display management before, CTRL+1, CTRL+2 can switch to different displays

Before I developed a multi-display management VB plug-in,CTRL+1,CTRL+2 can switch to different monitors, and then the mouse can only move within the scope of the monitor.