[SOLVED] Getting bit from Byte

[Mer08_]

I am trying to assign a bit of a Byte to a control in my form. I have tried to search on internet but I couldn't find anything. I expect my code to be like this:

Public Class Form1
     Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
          Dim bytes As Byte() = {&B00, &B01, &B10, &B11}
          Dim bit As Boolean = MagicalFunctionThatGetsBitFromByte(bytes(0), 0) REM MagicalFunctionThatGetsBitFromByte(a As Byte, b As Integer) As Boolean | Where A is the byte and B is the bit (0 - 7)
          Button2.Enable = bit
     End Sub
End Class

Visual Basic .NET Framework 4.8

[TysonLPrice]

That's over my head but I see something out there called a bit array that looks like you can do that:

https://docs.microsoft.com/en-us/dot...N&view=net-6.0

[jmcilhinney]

Two options come to mind immediately: a BitArray and bit-masking, e.g.

Module Module1
 
    Sub Main()
        Dim b As Byte = &B10110101
 
        For i = 0 To 7
            Console.WriteLine(GetBit1(b, i))
        Next
 
        Console.WriteLine()
 
        For i = 0 To 7
            Console.WriteLine(GetBit2(b, i))
        Next
 
        Console.ReadLine()
    End Sub
 
    Private Function GetBit1(value As Byte, index As Integer) As Boolean
        Dim bits = New BitArray({value})
 
        Return bits(index)
    End Function
 
    Private Function GetBit2(value As Byte, index As Integer) As Boolean
        Dim mask As Byte = 2 ^ index
 
        Return (value And mask) <> 0
    End Function
 
End Module

Whichever option you choose, you might write it as an extension method, e.g.

Imports System.Runtime.CompilerServices
 
Public Module ByteExtensions
 
    <Extension>
    Public Function GetBit(source As Byte, index As Integer) As Boolean
        Dim mask As Byte = 2 ^ index
 
        Return (source And mask) <> 0
    End Function
 
End Module

and then you can call it on the value itself, e.g.

Module Module1
 
    Sub Main()
        Dim b As Byte = &B10110101
 
        For i = 0 To 7
            Console.WriteLine(b.GetBit(i))
        Next
 
        Console.ReadLine()
    End Sub
 
End Module

The BitArray would come into its own if you wanted to create it once and then use it multiple times.

[Niya]

    Private Function GetBit2(value As Byte, index As Integer) As Boolean
        Dim mask As Byte = 2 ^ index

        Return (value And mask) <> 0
    End Function

I'd go with this:-

    Public Function GetBit(value As Byte, index As Integer) As Boolean
        Return CBool((value And (1 << index)))
    End Function

The JIT produces cleaner, and by appearance, much faster assembly for this. I've observed that the JIT creates a lot of excessive x87 FPU instructions for exponent operations when this could be done using simple integer instructions which are faster.