Print to printer without dialog and print preview

[BSWhipp]

I have a program I created to print labels where is has a print preview form and an rdlc for interaction so users can see what they print before they print it. Now new desire is to have it auto print from an external source. I have created arguments to get the data, printer, copies, and what layouts I need to make the selection automatically, The issue I I don't know how to have the program use the existing code and have it print directly to the printer without print preview. Existing code is attached

With PrintPreview114.ReportViewer114
                .PrinterSettings.PrinterName = "\\GVL02\114 Label Printer (Assembly)" 'Intermec Printer PM4i
                temstr = .PrinterSettings.PrinterName
                goodprinter = TestPrinter(temstr)
                If goodprinter = "" Then
                    ' MessageBox.Show("Printed is not installed. Contact your Administrator.", "Information", MessageBoxButtons.OK, MessageBoxIcon.Information)
                    Exit Sub
                Else
                    If temstr <> goodprinter Then
                        .PrinterSettings.PrinterName = goodprinter
                    End If
                End If
                .ProcessingMode = ProcessingMode.Local
                .PrinterSettings.Copies = lcnumoflabels
                .LocalReport.DataSources.Clear()
                .LocalReport.DataSources.Add(RDS)
                .SetDisplayMode(DisplayMode.PrintLayout)
                'Set the paper
                Try
                    .PrinterSettings.DefaultPageSettings.PaperSize = .PrinterSettings.PaperSizes(2)
                Catch
                    MessageBox.Show("Printer needs to be setup. Check Paper sizes.", "Information", MessageBoxButtons.OK, MessageBoxIcon.Information)
                End Try
                .LocalReport.SetParameters(param1)
                .LocalReport.SetParameters(param2)
                .LocalReport.SetParameters(param3)
                .LocalReport.SetParameters(param4)
                .LocalReport.Refresh()
            End With

[.paul.]

You need to show the code that opens the PrintPreviewDialog. It’s probably a simple fix…

[.paul.]

With PrintPreview114??? Ok I get it now. What other properties does Your reportviewer have?

[BSWhipp]

after the End With in the normal program I have
PrintPreview114.Show()
There is only Me.ReportViewer114.RefreshReport() in the PrintPreview114_load.

Thanks for helping.

[.paul.]

So there is no Print command instead of PrintPreview114.Show?

[BSWhipp]

apparently, I am a novice to VB so I could have overlooked it. What would be the syntax? Because there is no syntax for the PrintPreview114 or Reportviewer114 for print?

[BSWhipp]

.paul., what do I need to do to get this working? Your help is greatly appreciated.

[.paul.]

Try this...

With PrintPreview114.ReportViewer114
    .PrinterSettings.PrinterName = "\\GVL02\114 Label Printer (Assembly)" 'Intermec Printer PM4i
    temstr = .PrinterSettings.PrinterName
    goodprinter = TestPrinter(temstr)
    If goodprinter = "" Then
        ' MessageBox.Show("Printed is not installed. Contact your Administrator.", "Information", MessageBoxButtons.OK, MessageBoxIcon.Information)
        Exit Sub
    Else
        If temstr <> goodprinter Then
            .PrinterSettings.PrinterName = goodprinter
        End If
    End If
    .ProcessingMode = ProcessingMode.Local
    .PrinterSettings.Copies = lcnumoflabels
    .LocalReport.DataSources.Clear()
    .LocalReport.DataSources.Add(RDS)
    .SetDisplayMode(DisplayMode.PrintLayout)
    'Set the paper
    Try
        .PrinterSettings.DefaultPageSettings.PaperSize = .PrinterSettings.PaperSizes(2)
    Catch
        MessageBox.Show("Printer needs to be setup. Check Paper sizes.", "Information", MessageBoxButtons.OK, MessageBoxIcon.Information)
    End Try
    .LocalReport.SetParameters(param1)
    .LocalReport.SetParameters(param2)
    .LocalReport.SetParameters(param3)
    .LocalReport.SetParameters(param4)
    .LocalReport.Refresh()
    .LocalReport.PrintToPrinter()
End With

[BSWhipp]

I get 'PrintToPrinter' is not a member of Microsoft.Reportin.Winforms.LocalReport?

[.paul.]

Ok. This page from Microsoft explains how…

https://docs.microsoft.com/en-us/pre...ectedfrom=MSDN

[BSWhipp]

Yea, I saw that. I was trying to avoid it if possible. Guess not. Thanks

[BSWhipp]

OK, I have that implemented but it only prints 1 copy. When I add printdoc.PrinterSettings.Copies = 2 it still prints 1 copy. Wam I missing something?

[.paul.]

Can you show me your PrintPage code? You need to implement a loop to print your number of copies... You'd set PrinterSettings.Copies = 2, then run PrintPage twice.

Edit: or any number in PrinterSettings.Copies

[.paul.]

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
    PrintDocument1.PrinterSettings.Copies = 2
    PrintDocument1.Print
End Sub

Private Sub PrintDocument1_PrintPage(ByVal sender As Object, ByVal e As System.Drawing.Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage

    ' your page print code

    PrintDocument1.PrinterSettings.Copies -= CShort(1)

    If PrintDocument1.PrinterSettings.Copies > 0 Then
        e.HasMorePages = True
    End If
End Sub

[BSWhipp]

The printpage code looke like this:

 Private Sub PrintPage(ByVal sender As Object, ByVal ev As PrintPageEventArgs)
        Dim pageImage As New Metafile(m_streams(m_currentPageIndex))

        ' Adjust rectangular area with printer margins.
        Dim adjustedRect As New Rectangle(ev.PageBounds.Left - CInt(ev.PageSettings.HardMarginX),
                                          ev.PageBounds.Top - CInt(ev.PageSettings.HardMarginY), _
                                          ev.PageBounds.Width, _
                                          ev.PageBounds.Height)

        ' Draw a white background for the report
        ev.Graphics.FillRectangle(Brushes.White, adjustedRect)

        ' Draw the report content
        ev.Graphics.DrawImage(pageImage, adjustedRect)

        ' Prepare for the next page. Make sure we haven't hit the end.
        m_currentPageIndex += 1
        ev.HasMorePages = (m_currentPageIndex < m_streams.Count)
    End Sub

So I would set the copies then in the sub print Which looks like this

    Private Sub Print()
        If m_streams Is Nothing OrElse m_streams.Count = 0 Then
            Throw New Exception("Error: no stream to print.")
        End If
        AddHandler printdoc.PrintPage, AddressOf PrintPage
        m_currentPageIndex = 0
        printdoc.Print()
    End Sub

Add a loop for the AddHanler line?

Why is this so complicated? Why couldn't Microsoft Create code to send a rdlc direct to a printer? like localreport.print()? Years ago in Foxpro, I think we could do it. BTW, thanks again for all your help.

[.paul.]

No. See my code in post #14
It’s more complicated as your printing spans over more than one page. You can print more copies by setting your page range counter back to 0 and then setting hasmorepages to true, then it’ll print another copy of your complete pages in your range

[BSWhipp]

OK, I set my printdoc.printersettings.copies to 2 then added the

 printdoc.PrinterSettings.Copies -= CShort(1)
 If printdoc.PrinterSettings.Copies > 0 Then
    ev.HasMorePages = True
End If

I see how it is working but when it hits the printpage sub again because hasmorepages is now true, in the Dim pageimage line it errors out unhandled exception of type 'System.ArgumentOutOfRangeException' occurred in mscorlib.dll. BT, it does show a messagebox stating what page it is printing. Is there any way to get rid of that too?

[.paul.]

Private Sub Print()
    If m_streams Is Nothing OrElse m_streams.Count = 0 Then
        Throw New Exception("Error: no stream to print.")
    End If
    AddHandler printdoc.PrintPage, AddressOf PrintPage
    m_currentPageIndex = 0
    printdoc.PrinterSettings.Copies = 2
    printdoc.Print()
End Sub

Private Sub PrintPage(ByVal sender As Object, ByVal ev As PrintPageEventArgs)
    Dim pageImage As New Metafile(m_streams(m_currentPageIndex))

    ' Adjust rectangular area with printer margins.
    Dim adjustedRect As New Rectangle(ev.PageBounds.Left - CInt(ev.PageSettings.HardMarginX),
                                          ev.PageBounds.Top - CInt(ev.PageSettings.HardMarginY), _
                                          ev.PageBounds.Width, _
                                          ev.PageBounds.Height)

    ' Draw a white background for the report
    ev.Graphics.FillRectangle(Brushes.White, adjustedRect)

    ' Draw the report content
    ev.Graphics.DrawImage(pageImage, adjustedRect)

    ' Prepare for the next page. Make sure we haven't hit the end.
    m_currentPageIndex += 1
    if (m_currentPageIndex < m_streams.Count) Then
        ev.HasMorePages = True
    Else
        printdoc.PrinterSettings.Copies -= CShort(1)
        m_currentPageIndex = 0
        If printdoc.PrinterSettings.Copies > 0 Then
            ev.HasMorePages = True
        End If
    End If
End Sub

[BSWhipp]

I stepped away from it for a while and went back to and and go it. Definitely had to do a loop like you stated, but the loop has to be here. Start the loop then do the new code for the Export and Print. Finally. Again, Thanks for all your help.

 For i = 1 To 2
     printdoc = New PrintDocument
     Export(PrintPreview114.ReportViewer114.LocalReport, "114")
     Print()
Next

[.paul.]

Or you could do it without a loop, as I showed you in post #18

[BSWhipp]

For some reason, I got an unhandled exception error on that code when it went to print page 2.

[.paul.]

On which line?

[BSWhipp]

When it sets the ev.hasmorepages to true, at the end of the Sub, it goes back to the beginning of the Sub and errors out on
Dim pageImage As New Metafile(m_streams(m_currentPageIndex)). If I let it print the page (document) and then exit the sub, I can print copy with the loop.

[.paul.]

Try this...

Private Sub PrintPage(ByVal sender As Object, ByVal ev As PrintPageEventArgs)
    Dim pageImage As New Metafile(m_streams(m_currentPageIndex))

    ' Adjust rectangular area with printer margins.
    Dim adjustedRect As New Rectangle(ev.PageBounds.Left - CInt(ev.PageSettings.HardMarginX),
                                          ev.PageBounds.Top - CInt(ev.PageSettings.HardMarginY), _
                                          ev.PageBounds.Width, _
                                          ev.PageBounds.Height)

    ' Draw a white background for the report
    ev.Graphics.FillRectangle(Brushes.White, adjustedRect)

    ' Draw the report content
    ev.Graphics.DrawImage(pageImage, adjustedRect)

    pageImage.Dispose

    ' Prepare for the next page. Make sure we haven't hit the end.
    m_currentPageIndex += 1
    if (m_currentPageIndex < m_streams.Count) Then
        ev.HasMorePages = True
    Else
        printdoc.PrinterSettings.Copies -= CShort(1)
        m_currentPageIndex = 0
        If printdoc.PrinterSettings.Copies > 0 Then
            ev.HasMorePages = True
        End If
    End If
End Sub