If EndIf 4 possibilities

[ivansmo]

Hi, this is my code that doesn't work. I see it only takes TextBox5.Text values to check and do not TextBox4.Text

Dim first2Chars = TextBox4.Text.Substring(0, 2)

  If ((Convert.ToInt32(TextBox5.Text)) = 0 And first2Chars.tostring IsNot "ST") Then
            MsgBox("YN")
        ElseIf ((Convert.ToInt32(TextBox5.Text)) = 0 And first2Chars.tostring Is "ST") Then
            MsgBox("YY")
        ElseIf ((Convert.ToInt32(TextBox5.Text)) <> 0 And first2Chars.tostring IsNot "ST") Then
            MsgBox("NN")
        ElseIf ((Convert.ToInt32(TextBox5.Text)) <> 0 And first2Chars.tostring Is "ST") Then
            MsgBox("NY")
  End If

I have 4 possible states, Y=Yes, N=No. How to make this check actually work as I need it to?

[dday9]

IsNot and Is will not work here. You should be using = and <>. Side note: because you're converting the TextBox to an Integer, declare a variable for it to be stored in. And there's no need to call ToString on first2Chars since it is already a String. Finally, use AndAlso instead of And, AndAlso will not bother to evaluate the second condition if the first fails.

Take a look at this example:

Dim first2Chars = TextBox4.Text.Substring(0, 2)
Dim textbox5Conversion As Integer

If (Not Integer.TryParse(TextBox5.Text, textbox5Conversion)) Then
    MessageBox.Show("TextBox5 is not a valid integer.")
    Return
End If

If (textbox5Conversion = 0 AndAlso first2Chars <> "ST") Then
    MessageBox.Show("YN")
ElseIf (textbox5Conversion = 0 AndAlso first2Chars = "ST") Then
    MessageBox.Show("YY")
ElseIf (textbox5Conversion <> 0 AndAlso first2Chars <> "ST") Then
    MessageBox.Show("NN")
ElseIf (textbox5Conversion <> 0 AndAlso first2Chars = "ST") Then
    MessageBox.Show("NY")
End If

Edit - In free-typing this I missed the end quote on every "ST". I've updated the code to fix that. Also, after looking at it some more, the last ElseIf is unnecessary. You could replace it with an Else.

[si_the_geek]

'Is' and 'IsNot' aren't meant for checking values (they are basically for checking if two object-variables have the same pointer).

Use = and <> as you did in the other parts of the code.



Also note that first2Chars is already a String, so doing first2Chars.ToString is wasteful



edit: seems my brief distraction took longer than I thought!

[ivansmo]

It works, I've tried the code ... Thank You

[ivansmo]

'Is' and 'IsNot' aren't meant for checking values (they are basically for checking if two object-variables have the same pointer).

Use = and <> as you did in the other parts of the code.



Also note that first2Chars is already a String, so doing first2Chars.ToString is wasteful



edit: seems my brief distraction took longer than I thought!

Thanks for the answer. I appreciate it

[dbasnett]

Thanks for the answer. I appreciate it

Just an alternative,

        Dim first2Chars As String = TextBox4.Text.Substring(0, 2)
        Dim TB5val As Integer
        If Integer.TryParse(TextBox5.Text, TB5val) Then
            Select Case TB5val
                Case 0
                    If first2Chars <> "ST" Then
                        'YN
                    Else
                        'YY
                    End If
                Case Else
                    If first2Chars <> "ST" Then
                        'NN
                    Else
                        'NY
                    End If
            End Select
        Else
            MessageBox.Show("TextBox5 is not a valid integer.")
        End If

[Shaggy Hiker]

You might also want to use String.StartsWith rather than using .SubString for this. Substring returns a string, which means creating a new object, whereas StartsWith returns a Boolean and is likely somewhat more efficient.

[Niya]

(they are basically for checking if two object-variables have the same pointer).

We have to be very careful with our words in statements like this when talking about the .Net environment. Is and IsNot are used to check for the difference between object references, not pointers. Objects can be moved around in memory during the execution of a .Net application which means their pointers can change while they are still the same objects.

[si_the_geek]

Well yes, my caveat of "basically" wasn't really good enough... I was just trying to avoid confusing the thread starter.