[RESOLVED] location of the mouse

[Mojtaba]

Hello friends
I get the location of the mouse
Both inside the form and outside the form
The position is not exact
For example to draw a line
X1 , Y1 I set it equal to the location of the mouse

-------------------
Scale mode on pixel
-------------------

Click on the form to find the position of the mouse

Option Explicit
Private Type POINTAPI
X As Long
Y As Long
End Type
Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Private Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Integer
Private Sub Form_Load()
Timer1.Interval = 100
Timer1.Enabled = True
End Sub
Private Sub Timer1_Timer()
Dim pt As POINTAPI
If GetAsyncKeyState(1) <> 0 Then
GetCursorPos pt
Textx.Text = pt.X * Screen.TwipsPerPixelX
Texty.Text = pt.Y * Screen.TwipsPerPixelY
Line1.X1 = pt.X * Screen.TwipsPerPixelX
Line1.Y1 = pt.Y * Screen.TwipsPerPixelY
End If
End Sub

Download Attachments Mouse Position : Mouse Position.zip

[Eduardo-]

Is this a question?

[Mojtaba]

Yes, the question is about the exact location of the mouse
When drawing a line from the location of the mouse is not accurate

[Eduardo-]

You need ScreenToClient:

Option Explicit

Private Type POINTAPI
    X As Long
    Y As Long
End Type
Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Private Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Integer
Private Declare Function ScreenToClient Lib "user32" (ByVal hWnd As Long, lpPoint As POINTAPI) As Long

Private Sub Form_Load()
    Timer1.Interval = 100
    Timer1.Enabled = True
End Sub
Private Sub Timer1_Timer()
    Dim pt As POINTAPI
    If GetAsyncKeyState(1) <> 0 Then
    GetCursorPos pt
    ScreenToClient hWnd, pt
    Textx.Text = pt.X * Screen.TwipsPerPixelX
    Texty.Text = pt.Y * Screen.TwipsPerPixelY
    Line1.X1 = pt.X * Screen.TwipsPerPixelX
    Line1.Y1 = pt.Y * Screen.TwipsPerPixelY
    End If
End Sub

[baka]

also, he could use:

Private Declare Function WindowFromPoint Lib "user32" (ByVal xpoint As Long, ByVal ypoint As Long) As Long

to know that he is in the right form/picturebox/whatever

[Mojtaba]

Thankful Eduardo
Another problem in mode
Form Scale mode on pixel
There is no problem in Twip mode

[Eduardo-]

Thankful Eduardo
Another problem in mode
Form Scale mode on pixel
There is no problem in Twip mode

If you want to work in pixels, then remove the * Screen.TwipsPerPixelX and * Screen.TwipsPerPixelY from the code.

[Mojtaba]

The problem was solved thanks to Eduardo

[passel]

You didn't mark the thread as resolved.