[RESOLVED] treeview expand a particular node by code. Possible?

[Adebiyi24]

Hello VbForums
I can open the first node by this code.

TreeView1.Nodes(1).Expanded = True

But I want to open the 4th node.

TreeView1.Nodes(4).Expanded = True

this code doesn't open the 4 th node.
thank you

[Arnoutdv]

Does Nodes(4) have any children?

Sample using a TreeView control and a CommandButton

Option Explicit

Private Sub Form_Load()
  With TreeView1
    .Nodes.Clear
    .Nodes.Add , , "root", "Node 1"
    .Nodes.Add "root", tvwChild, "node1.1", "Node 1.1"
    .Nodes.Add "root", tvwChild, "node1.2", "Node 1.2"
    .Nodes.Add "root", tvwChild, "node1.3", "Node 1.3"
    .Nodes.Add "node1.3", tvwChild, "node1.3.1", "Node 1.3.1"
    .Nodes.Add "node1.3", tvwChild, "node1.3.2", "Node 1.3.2"
    .Nodes.Item(1).Expanded = True
  End With
End Sub

Private Sub Command1_Click()
  TreeView1.Nodes.Item("node1.3").Expanded = True
End Sub

Clicking the command button will open "Node 1.3.2", but only if the parents are also open.
If you remove " .Nodes.Item(1).Expanded = True" line then clicking the command button doesn't do anything

[Adebiyi24]

Thank you sir for the interest and help

Does Nodes(4) have any children?

yes

If you remove " .Nodes.Item(1).Expanded = True, then ....

But I do not want to open node 1
I'm feeding the treevew from database that why I could not replicate your code.
thank you

[Arnoutdv]

Important is that a node can only be shown expanded if it's parent nodes are also expanded.
You can't expand a node if it's parents is collapsed

[Adebiyi24]

I want to produce something like this:
Attachment 182297

[Adebiyi24]

Do you think this is not possible by code?

[gilman]

Do you think this is not possible by code?

Yes it is possible:

Option Explicit

Public Sub ExpandNode(ByVal oNode As MSComctlLib.Node)

    If Not oNode.Parent Is Nothing Then
        'If the parent node is not expanded, then expand the parent node
        If Not oNode.Parent.Expanded Then
            ExpandNode oNode.Parent
        End If
    End If
    oNode.Expanded = True
End Sub

Private Sub Command1_Click()
    ExpandNode TreeView1.Nodes.Item("node1.3")
End Sub
Private Sub Form_Load()
  With TreeView1
    .Nodes.Clear
    .Nodes.Add , , "root", "Node 1"
    .Nodes.Add "root", tvwChild, "node1.1", "Node 1.1"
    .Nodes.Add "root", tvwChild, "node1.2", "Node 1.2"
    .Nodes.Add "root", tvwChild, "node1.3", "Node 1.3"
    .Nodes.Add "node1.3", tvwChild, "node1.3.1", "Node 1.3.1"
    .Nodes.Add "node1.3", tvwChild, "node1.3.2", "Node 1.3.2"
    'do not expand root node
'    .Nodes.Item(1).Expanded = True
  End With
End Sub

[Adebiyi24]

gilman
Thank you very much
I got it
thank you

[Adebiyi24]

I got it
thank you

[gilman]

There's a problem with the original code, if a node in the path is spanded but the root is colapsed, the procedure fails, and not show the expanded node, try
This works fine.

Option Explicit

Public Sub ExpandNode(ByVal oNode As MSComctlLib.Node)

    If Not oNode.Parent Is Nothing Then
        'don't stop if the parent is expanded
'        If Not oNode.Parent.Expanded Then
        ExpandNode oNode.Parent
'        End If
    End If
    oNode.Expanded = True
End Sub

Private Sub Command1_Click()
    ExpandNode TreeView1.Nodes("node1.3.2")
End Sub
Private Sub Form_Load()
  With TreeView1
    .Nodes.Clear
    .Nodes.Add , , "root", "Node 1"
    .Nodes.Add "root", tvwChild, "node1.1", "Node 1.1"
    .Nodes.Add "root", tvwChild, "node1.2", "Node 1.2"
    .Nodes.Add "root", tvwChild, "node1.3", "Node 1.3"
    .Nodes("node1.3").Expanded = True
    .Nodes.Add "node1.3", tvwChild, "node1.3.1", "Node 1.3.1"
    .Nodes.Add "node1.3", tvwChild, "node1.3.2", "Node 1.3.2"
   .Nodes.Add "node1.3.2", tvwChild, "node1.3.2.1", "Node 1.3.2.1"
    'do not expand root node
'    .Nodes.Item(1).Expanded = True
  End With
End Sub

if you uncoment the comented if block in ExpandNode the button don't work