Ping Network Computer

[vbchJack]

Very simple setup. Local network with 2 computers, a printer and Internet access. The server often needs to know the status of the 2nd computer. I am using the following code which seems a common solution:

If My.Computer.Network.Ping("Jack-Laptop") Then
    MsgBox("Pinged successfully.")
Else
    MsgBox("Pinged computer is off-line")
End If

When "Jack-Laptop" is on-line, all is well ... MsgBox prints correctly.
When "Jack-Laptop" is 0ff-line there is an error and MsgBox is not printed.

The error msg is a rather ambiguous 'unhandled exception.'

What am I missing here?

Having seen my 83rd birthday come and go, I am thinking this will be my last project. Over the years you guys have been great ... there is VB Forum input in almost all of my projects. Thanks for that!

[dday9]

According to the documentation (here), the two exception types you can expect are:

1. InvalidOperationException - No network connection is available.
2. PingException - URL was not valid.

My first suggestion would be to wrap your statement in a Try/Catch statement so that you can get the exception details:

Try
    If My.Computer.Network.Ping("Jack-Laptop") Then
        MessageBox.Show("Pinged successfully.")
    Else
        MessageBox.Show("Pinged computer is off-line")
    End If
Catch ex As Exception
    MessageBox.Show(ex.Message)
End Try

Setup a breakpoint in exception handler portion of the Try/Catch and relay the details here.

[vbchJack]

Thanks dday9. I should have mentioned that I did the Try...Catch with the same result. I also placed an 'On Error GoTo' (not with the Try...Catch) in the sub. Again the same response. In all cases I get: "An exception occurred during a Ping request." Execution stops at the first line i.e. "If My.Computer.Network.Ping("Jack-Laptop")"

[dday9]

What was the Exception type?

[dbasnett]

What was the Exception type?

If I had to guess it would be that it is PingException and the resolving mechanism did NOT resolve "Jack-Laptop".

[vbchJack]

I did not get anything more than the error msg ... no number.
If it is PingException, how do I fix that? This is my first network project.

[PlausiblyDamp]

I did not get anything more than the error msg ... no number.
If it is PingException, how do I fix that? This is my first network project.

When it says "Unhandled Exception" it should at the very least give you the Type of exception, a number isn't normally used in this context.

If you are unsure then just copy and paste the error message here.

[dday9]

Yeah, I'm not usually one for screenshots, but I think this might be a case where a screenshot of the error message may provide me with the details that I'm looking for.

[dbasnett]

I did not get anything more than the error msg ... no number.
If it is PingException, how do I fix that? This is my first network project.

Have you tried using the IP addresses of the machines, instead of names, you are pinging? Based on your earlier description you could assign IP addresses to the devices.

[sapator]

May I propose the networkinformation ping with PingReply?
I use it async but I suppose you can use it non async.
It will give you more information but I suppose it will exception out in certain cases:

https://docs.microsoft.com/en-us/dot...d?view=net-5.0
https://docs.microsoft.com/en-us/dot...s?view=net-5.0

Something like:

 Dim pinger As New Ping()

        Try
            Dim pr As PingReply = pinger.Send("Jack-Laptop", 3000)
            If pr.Status = IPStatus.Success Then
               MsgBox("Pinged successfully.")
            Else
               MsgBox("Status",pr.Status.tostring) ' not sure if you just get the status here or you have to convert from the above link, haven't checked.
            End If
' and an exception catch  if it fails
        Catch ex As Exception
            MessageBox.Show("IP Error", ex.message)       
            Exit Sub
        End Try

[vbchJack]

Attachment 181775

This from the Immediate window:
at System.Net.NetworkInformation.Ping.Send(String hostNameOrAddress, Int32 timeout, Byte[] buffer, PingOptions options)</ExceptionString><NativeErrorCode>2AF9</NativeErrorCode></InnerException></Exception></TraceRecord>

[dday9]

Based on your image, you're getting a PingException (displayed in the dialog title of the exception).

I would suggest what dbasnett suggested in post #9 and try to ping just the IP address of the computer first. If that works, then what is likely happening is that either:

1. There is a typo in the computer name
2. There is a specific format you need to follow for pinging networked machines

[dbasnett]

Try it like this

First a method,

    Private Function PingIt(HostOrIP As String) As Boolean
        Dim rv As Boolean = False
        Try
            Dim _ip As Net.IPAddress
            Dim he As Net.IPHostEntry
            Dim pr As Net.NetworkInformation.PingReply
            Dim _ping As New Net.NetworkInformation.Ping
            If Not Net.IPAddress.TryParse(HostOrIP, _ip) Then
                he = Net.Dns.GetHostEntry(HostOrIP)
                If he IsNot Nothing AndAlso he.HostName <> "" Then
                    pr = _ping.Send(he.HostName)
                    If pr.Status = Net.NetworkInformation.IPStatus.Success Then
                        rv = True
                    End If
                End If
                he = Nothing
            Else
                pr = _ping.Send(_ip)
                If pr.Status = Net.NetworkInformation.IPStatus.Success Then
                    rv = True
                End If
            End If
        Catch ex As Exception
        End Try
        Return rv
    End Function

Then use the method like this,

        Dim foo As Boolean = PingIt("Jack-Laptop")
        If foo Then
            'success
        Else
            'fail
        End If

[vbchJack]

Thanks dbasnett.
Your solution is above my paygrade but it works.
And thanks to all you other responders for your time and help.