[RESOLVED] How to bold selected words in RichTextBox?

[sayisker]

Hi, I'm new in RichTextBox. I want to select a word that wrapped between my special symbol I self invented (#B#) to be bold and deleted the symbol after bold, how to do that?

RichTextBox1.Text = "There is a #B#Little#B# cat."
RichTextBox1.Font.Size = 12
RichTextBox1.Font.Name = "Courier New"

Expected results:
There is a Little cat

[Arnoutdv]

Use the .SelStart, .SelLength, .SelText and .SelBold properties

[Zvoni]

In a loop:
Search for the (first/next) occurence of "#B#".
if it's the opening Tag, Add 3 to the result, and save it. i'd use a dynamic 2D-Array, with the "start" saved in the first dimension
From this "new" starting point search for the next occurence of "#B#". Save the result in the second dimension of the Array.
Now (!) add 3 to that result for your next starting point.
To signify a found "#B#'" as an opening Tag i'd use a boolean Variable i toggle with each new occurence and use that boolean to know when to add 3 to the result (before/after saving the value)
Loop end
In a new loop LBound(Array) to UBound(Array)
Set Font to Bold using the Start and End-Values in the Array using the Properties Arnout mentioned above
Loop End
Finally: Replace all "#B#" with ""/vbNullString

EDIT: And no, i'm not going to step into the minefield of discussions like
"Why not use html-tags", or "this is so slow" or any other reason.
This above is the most simple algorithm to skin that cat, which i would expect even a rookie in any programming language to come up with

[SamOscarBrown]

If I were you I would un-invent #B# and instead, invent a start location of #B# and and end location of #/B". HTML and other 'languages' tend to use the slash "/" to indicate the END of formatted text. Will make your search in your RTB much easier.

Sammi

EDIT: Or like Z said....use existing practices.

[sayisker]

First of all, thanks for Zvoni's explanation, but I think a code sample would help me understand better because I'm still new in vb too.

[Eduardo-]

RichTextBox1.SelText = "There is a "
RichTextBox1.SelBold = True
RichTextBox1.SelText = "little"
RichTextBox1.SelBold = False
RichTextBox1.SelText = " cat"

[dilettante]

Something like:

    Dim LPos As Long
    Dim RPos As Long

    With RichTextBox1
'        .Text = "There is a #B#Little#B# cat.  #B#Meow.#B#  I can hear it!"
'                        /- empty                            /- adjacent      /- dangling
        .Text = "There#B##B# is a #B#Little#B# cat.  #B#Me#B##B#ow.#B#  I can #B#hear it!"
        Do
            LPos = .Find("#B#", LPos, , rtfMatchCase Or rtfNoHighlight)
            If LPos >= 0 Then
                .SelStart = LPos
                .SelLength = Len("#B#")
                .SelText = vbNullString
                RPos = .Find("#B#", LPos, , rtfMatchCase Or rtfNoHighlight)
                If RPos >= 0 Then
                    .SelStart = RPos
                    .SelLength = Len("#B#")
                    .SelText = vbNullString
                Else
                    RPos = &H7FFFFFFF 'No right tag, so through the end of all text.
                End If
                If RPos - LPos > 0 Then
                    .SelStart = LPos
                    .SelLength = RPos - LPos
                    .SelBold = True
                End If
                LPos = RPos
            End If
        Loop While LPos >= 0
        .SelStart = 0
    End With

[Eduardo-]

Instead of using your custom tagging why don't you write the RTF codes directly?

RichTextBox1.TextRTF = "{\rtf1\fs" & RichTextBox1.Font.Size * 2 & " " & "There is a \b little\b0  cat" & "}"

[dilettante]

I suspect the idea is to let users manually enter the desired markup and then convert it.

[sayisker]

Something like:

    Dim LPos As Long
    Dim RPos As Long

    With RichTextBox1
'        .Text = "There is a #B#Little#B# cat.  #B#Meow.#B#  I can hear it!"
'                        /- empty                            /- adjacent      /- dangling
        .Text = "There#B##B# is a #B#Little#B# cat.  #B#Me#B##B#ow.#B#  I can #B#hear it!"
        Do
            LPos = .Find("#B#", LPos, , rtfMatchCase Or rtfNoHighlight)
            If LPos >= 0 Then
                .SelStart = LPos
                .SelLength = Len("#B#")
                .SelText = vbNullString
                RPos = .Find("#B#", LPos, , rtfMatchCase Or rtfNoHighlight)
                If RPos >= 0 Then
                    .SelStart = RPos
                    .SelLength = Len("#B#")
                    .SelText = vbNullString
                Else
                    RPos = &H7FFFFFFF 'No right tag, so through the end of all text.
                End If
                If RPos - LPos > 0 Then
                    .SelStart = LPos
                    .SelLength = RPos - LPos
                    .SelBold = True
                End If
                LPos = RPos
            End If
        Loop While LPos >= 0
        .SelStart = 0
    End With

Well done, dilettante, is working so well. Thank you very much for your effort.