How to SOMETIMES pass an array to a function

[IliaPreston]

I need to pass an array to a function.
However, sometimes I don't want that to happen.

In other words, I need to write a function that should look at the input array to see if it exists, do something, and if it doesn't exist, do other things.

Currently, I have written something like this:

Private Sub Command15_Click()
   
   Dim XArray()      As String
   Dim N           As Long
   
   N = proc1_Command15("abc", Null)
   
End Sub

Private Function proc1_Command15(ByRef XVal As String, ByRef XArray() As String) As Long
   
   Dim L       As Long
   Dim s       As String
   
   If IsNull(XArray()) Then
      s = "XArray is null. Nothing added!"
   Else
      L = Array_Length(XArray())
      
      ReDim Preserve XArray(L) As String
      XArray(L) = XVal
      
      s = "XVal added." & vbCrLf & vbCrLf & "Number of records:" & vbTab & (L + 1)
   End If
   
   MsgBox s
   
End Function

But, that doesn't work.
It gives me a compile error (doesn't compile)

I am not sure if the concept of Null that I am using is the right concept to use in this case or not, and if not, then how to do what I am trying to do.

Please help.
Thanks.

[dz32]

try something like this

Private Sub Form_Load()
    
   Dim XArray()    As String
   Dim N           As Long
   
   N = proc1_Command15("abc")
   proc1_Command15 "111", XArray
   proc1_Command15 "222", XArray
   Debug.Print "Xarray contents: " & Join(XArray, ",")
   
End Sub

Private Function proc1_Command15(ByRef XVal As String, Optional ByRef XArray As Variant) As Long
   
   Dim L       As Long
   Dim s       As String
   On Error Resume Next
   
   If IsArray(XArray) Then
      L = UBound(XArray)     'error if empty
      
      If Err.Number = 9 Then 'subscript out of range array empty
         ReDim Preserve XArray(0)
      Else
         ReDim Preserve XArray(L + 1)
      End If
      
      XArray(UBound(XArray)) = XVal
      
      s = "XVal added. records: " & UBound(XArray)
   Else
      s = "XArray not given. Nothing added!"
   End If
   
   Debug.Print s
   
End Function

[techgnome]

Look up how to use the keyword OPTIONAL...You want an optional parameter in this ccase.

-tg

[L'mars]

Hello
Visit the next webs
They uses the param PARAMARRAY on functions for arrays

https://analystcave.com/vba-tip-of-the-day-paramarray/

http://www.vb-helper.com/howto_param_array.htmlhttp://www.vb-helper.com/howto_param_array.html

http://www.tushar-mehta.com/publish_...ramArray.shtml

Bye