[RESOLVED] Printing a Picturebox with Controls - improper sizing

[SamOscarBrown]

I have several Controls (textboxes, labels, and an Image Control) placed in a Picturebox. Using the code below, I print the contents (well, actually, the entire PB), but it comes out larger than my printed page (IOW, it needs to be scaled to fit the paper (am using regular 8.5 x 11) when printed). Any suggestions?

Private Declare Function SendMessage Lib "user32.dll" Alias _
   "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, _
   ByVal wParam As Long, ByVal lParam As Long) As Long


Private Const WM_PAINT = &HF
Private Const WM_PRINT = &H317
Private Const PRF_CLIENT = &H4&   
Private Const PRF_CHILDREN = &H10&
Private Const PRF_OWNED = &H20&  

Private Sub Command2_Click()
    PrintPictureBox Picture1, 1000, 1000
End Sub




Public Sub SavePictureBox(Box As PictureBox, _
                        Optional X As Single = 0, _
                        Optional Y As Single = 0)
Dim rv As Long
Dim ar As Boolean
    On Error GoTo Exit_Sub
    With Box
        ar = .AutoRedraw
        .AutoRedraw = True
        rv = SendMessage(.hwnd, WM_PAINT, .hDC, 0)
        rv = SendMessage(.hwnd, WM_PRINT, .hDC, _
        PRF_CHILDREN Or PRF_CLIENT Or PRF_OWNED)
        .Picture = .Image
        Printer.PaintPicture .Picture, X, Y
        Printer.EndDoc
        .AutoRedraw = ar
    End With
Exit_Sub:
    If Err.Number Then MsgBox Err.Description, vbOKOnly, "Printer Error!"
End Sub

[dilettante]

So scale it. Read the docs for PaintPicture. You are letting too many arguments default.

[SamOscarBrown]

Got it...thanks.

[dilettante]

Simple demo printing a loaded image:

Option Explicit

Private Sub Main()
    Dim Picture As StdPicture
    Dim Aspect As Double

    ChoosePrinter.Show vbModal
    If ChoosePrinter.Canceled Then
        Unload ChoosePrinter
        MsgBox "Canceled!"
    Else
        Set Printer = ChoosePrinter.SelectedPrinter
        Unload ChoosePrinter
        Set Picture = LoadPicture("OrgChart.emf")
        
        'Print Picture, scaled to printable width of Printer maintaininng aspect ratio:
        With Picture
            Aspect = CDbl(.Height) / CDbl(.Width)
        End With
        With Printer
            On Error Resume Next 'For printers that raise a dialog, e.g. PDF print drivers.
            .PaintPicture Picture, _
                          0, _
                          0, _
                          .ScaleWidth, _
                          .ScaleY(.ScaleX(.ScaleWidth, .ScaleMode, vbHimetric) * Aspect, _
                                  vbHimetric, _
                                  .ScaleMode)
            If Err Then
                MsgBox "Canceled!"
                Exit Sub
            End If
            On Error GoTo 0
            .NewPage
            .EndDoc
        End With
        MsgBox "Done!"
    End If
End Sub

[dilettante]

You can modify this if you have control over Printer.ScaleWidth, which normally defaults to twips but you can be expliocit:

        With Printer
            .ScaleMode = vbTwips
            On Error Resume Next 'For printers that raise a dialog, e.g. PDF print drivers.
            .PaintPicture Picture, _
                          0, _
                          0, _
                          .ScaleWidth, _
                          .ScaleWidth * Aspect

Any absolute units will do (inches, etc.), just be sure you don't fall into the trap of vbPixels.

[SamOscarBrown]

thx dile....but I had already 'fixed' my issue with simple arguments (as you suggested).

In view of learning, what does your project above add in as far as capability/concept, vice simply using proper arguments (which I had failed to do in the beginning)?

[wqweto]

In view of learning, what does your project above add in as far as capability/concept, vice simply using proper arguments (which I had failed to do in the beginning)?

He cannot possible tell this without your first showing which proper arguments the code is currently using.

cheers,
</wqw>

[SamOscarBrown]

@w....(and dile?)...well, I simply used

Printer.PaintPicture .Picture, X, Y, 10000, 13000

where X and Y are 1000 and 500 respectively (changed from 1000 and 1000 in call above).