Results 1 to 20 of 20

Thread: [RESOLVED] Password Generator Validation (Visual Studio 2010)

  1. #1

    Thread Starter
    New Member
    Join Date
    May 2018
    Posts
    5

    Resolved [RESOLVED] Password Generator Validation (Visual Studio 2010)

    Hi Guys,

    Need a little help with an application I'm creating. Its just a simple password generator. I have the application generating the password with no issues but I need to add a step in that checks for: 1 uppercase letter, 1 lowercase letter, 1 number and 1 special character before displaying the password. If the password doesn't contain these values the password should then generate again.

    I would like to keep the code I have, i just want to add a step in at the end.

    Thanks a lot in advance.

    ps. I'm sorry if this is in the wrong place, this is my first post.

    Here is my code:

    Code:
    Public Class Form1
    
        Dim AllCharacters As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789?!£$%^&*()_+[];'#,./?><~@:}{\|"
        Dim r As New Random
        Dim charIndex As Integer
        Dim finalpassword As String
        Dim passwordChars1() As Char = New Char(9) {}
    
     
    
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
    
    
    
            For i As Integer = 0 To 9 - 1
                charIndex = r.Next(AllCharacters.Length)
                passwordChars1(i) = AllCharacters(charIndex)
    
           
            Next
            finalpassword = passwordChars1
    
            passwordbox.Text = finalpassword
    
    
         
    
        End Sub

  2. #2
    PowerPoster
    Join Date
    Feb 2012
    Location
    West Virginia
    Posts
    13,627

    Re: Password Generator Validation (Visual Studio 2010)

    One method would be to create 4 boolean variables. Then in your loop check the index to see which group of characters it falls into.
    i.e if it falls within the first 26 then cUpperCase=True if the next 26 then cLowerCase=True, the next 10 for digits and the rest for special.

    Set one of the booleans to true based on that result. When they loop is done then all four should be true if you have the characters you want.


    BTW You have posted in the VB6 section but you are using a much later version and should be moved to the VB.Net section as all VB versions after 1998 are VB.Net

  3. #3

    Thread Starter
    New Member
    Join Date
    May 2018
    Posts
    5

    Re: Password Generator Validation (Visual Studio 2010)

    Thanks a lot for this, would you happen to know what the code for this would be ?


    My apologies, I'll make sure this goes in the right place next time.

  4. #4
    Powered By Medtronic dbasnett's Avatar
    Join Date
    Dec 2007
    Location
    Pointless Forest 38.517,-92.023
    Posts
    9,388

    Re: Password Generator Validation (Visual Studio 2010)

    Another approach is to ensure that you have one of each. Because this might be homework there are no comments... Step through in the debugger and you will see what is going on.

    Code:
        Private Shared prng As New Random
        Private ReadOnly Upper As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
        Private ReadOnly Lower As String = "abcdefghijklmnopqrstuvwxyz"
        Private ReadOnly Numeric As String = "0123456789"
        Private ReadOnly Special As String = "?!£$%^&*()_+[];'#,./?><~@:}{\|"
        Const PasswordLength As Integer = 9
        Private Password As String
    
        Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
            Dim passWD As New System.Text.StringBuilder
    
            passWD.Append(Upper(prng.Next(Upper.Length)))
            passWD.Append(Lower(prng.Next(Lower.Length)))
            passWD.Append(Numeric(prng.Next(Numeric.Length)))
            passWD.Append(Special(prng.Next(Special.Length)))
    
            Do While passWD.Length <= PasswordLength
                Select Case prng.Next(1, 5)
                    Case 1
                        passWD.Append(Upper(prng.Next(Upper.Length)))
                    Case 2
                        passWD.Append(Lower(prng.Next(Lower.Length)))
                    Case 3
                        passWD.Append(Numeric(prng.Next(Numeric.Length)))
                    Case 4
                        passWD.Append(Special(prng.Next(Special.Length)))
                End Select
            Loop
    
            'the password
            Password = (From c In passWD.ToString Select c Order By prng.Next).ToArray
    My First Computer -- Documentation Link (RT?M) -- Using the Debugger -- Prime Number Sieve
    Counting Bits -- Subnet Calculator -- UI Guidelines -- >> SerialPort Answer <<

    "Those who use Application.DoEvents have no idea what it does and those who know what it does never use it." John Wein

  5. #5
    You don't want to know.
    Join Date
    Aug 2010
    Posts
    4,578

    Re: Password Generator Validation (Visual Studio 2010)

    Well, if it's always one of each, here's what I would do.

    Start by generating a string with 1 random uppercase letter. Add 1 random lowercase letter. Add 1 random number. Add 1 random special character. Now fill in the rest of the length with random characters. When you're done, shuffle the order of this string. Voila. Let's get super fancy and write it functionally.

    Code:
    Imports System
    
    Module Program
    
        Private _rng As New Random()
    
        Private _uppercase As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
        Private _lowercase As String = "abcdefghijklmnopqrstuvwxyz"
        Private _numbers As String = "0123456789"
        Private _special As String = "!@#$%^&*()."
    
        Sub Main(args As String())
            Dim desiredLength = 12
    
            For i As Integer = 0 To 10
                Dim charStream = RequiredChars().Concat(RandomAnything().Take(desiredLength - 4))
                Dim password = Shuffle(charStream)
                Console.WriteLine("   {0}", password)
            Next
        End Sub
    
        Private Function Shuffle(ByVal input As IEnumerable(Of Char)) As String
            Dim buffer() As Char = input.ToArray()
            For i As Integer = buffer.Length - 1 To 1 Step -1
                Dim swapIndex = _rng.Next(i + 1)
                Dim temp = buffer(swapIndex)
                buffer(swapIndex) = buffer(i)
                buffer(i) = temp
            Next
    
            Return New String(buffer)
        End Function
    
        Private Iterator Function RequiredChars() As IEnumerable(Of Char)
            Yield RandomLowercases().First()
            Yield RandomUppercases().First()
            Yield RandomNumbers().First()
            Yield RandomSpecials().First()
        End Function
    
        Private Function RandomLowercases() As IEnumerable(Of Char)
            Return RandomItems(_lowercase)
        End Function
    
        Private Function RandomUppercases() As IEnumerable(Of Char)
            Return RandomItems(_uppercase)
        End Function
    
        Private Function RandomNumbers() As IEnumerable(Of Char)
            Return RandomItems(_numbers)
        End Function
    
        Private Function RandomSpecials() As IEnumerable(Of Char)
            Return RandomItems(_special)
        End Function
    
        Private Iterator Function RandomAnything() As IEnumerable(Of Char)
            Dim collections() = {_uppercase, _lowercase, _numbers, _special}
            While True
                Dim thisCollection = collections(_rng.Next(collections.Length))
                Yield thisCollection(_rng.Next(thisCollection.Length))
            End While
        End Function
    
        Private Iterator Function RandomItems(ByVal input As String) As IEnumerable(Of Char)
            While True
                Yield input(_rng.Next(input.Length))
            End While
        End Function
    
    End Module
    This is more or less what dbasnett just did, but I find the "use LINQ to shuffle" approach to be a smell.
    This answer is wrong. You should be using TableAdapter and Dictionaries instead.

  6. #6
    Super Moderator Shaggy Hiker's Avatar
    Join Date
    Aug 2002
    Location
    Idaho
    Posts
    36,280

    Re: Password Generator Validation (Visual Studio 2010)

    I guess I'd ask whether or not this IS homework. We don't have an issue with helping with homework, but it would certainly restrict what solutions you'd be allowed to use.
    My usual boring signature: Nothing

  7. #7
    Super Moderator dday9's Avatar
    Join Date
    Mar 2011
    Location
    South Louisiana
    Posts
    10,331

    Re: Password Generator Validation (Visual Studio 2010)

    To prevent you from generating multiple passwords that do not meet your criteria, what I would do is:
    1. Get n amount of uppercase letters
    2. Get n amount of lowercase letters
    3. Get n amount of digits
    4. Get n amount of special characters
    5. Combine all of collections from steps 1-4
    6. Order the combination randomly


    Here is an example:
    Code:
    Private r As New Random
    Private Function RandomPassword(ByVal lowercase_count As Integer, ByVal uppercase_count As Integer, ByVal number_count As Integer, ByVal special_count As Integer) As String
        Dim lowercase() As Char = "abcdefghijklmnopqrstuvwxyz".ToCharArray()
        Dim uppercase() As Char = "ABCDEFGHIJKLMNOPQRSTUVWXYZ".ToCharArray()
        Dim numbers() As Char = "0123456789".ToCharArray()
        Dim special() As Char = "~`!@#$%^&*()_-+={[}]|\:;'<,>.?/".ToCharArray()
    
        Dim combination As New List(Of Char)
        combination.AddRange(Enumerable.Range(1, lowercase_count).Select(Function(c) lowercase(r.Next(0, lowercase_count - 1))))
        combination.AddRange(Enumerable.Range(1, uppercase_count).Select(Function(c) uppercase(r.Next(0, uppercase_count - 1))))
        combination.AddRange(Enumerable.Range(1, number_count).Select(Function(c) Convert.ToChar(numbers(r.Next(0, number_count - 1)))))
        combination.AddRange(Enumerable.Range(1, special_count).Select(Function(c) special(r.Next(0, special_count - 1))))
    
        Return New String(combination.OrderBy(Function(c) r.Next()).ToArray())
    End Function
    Fiddle: Live Demo
    "Code is like humor. When you have to explain it, itís bad." - Cory House
    VbLessons | Code Tags | Sword of Fury - Jameram

  8. #8
    PowerPoster Jenner's Avatar
    Join Date
    Jan 2008
    Location
    Mentor, OH
    Posts
    3,712

    Re: Password Generator Validation (Visual Studio 2010)

    I think I wrote something a while back similar to @dday9's solution. The only difference was I used ASCII character ranges and offsets rather than pre-typed strings getting loaded into character arrays.
    But the math I used was I went through my four categories and randomly picked the minimum needed characters for each (typically 1), and however many other characters I needed for the password, I'd randomly pick one of the categories and randomly pick a character from it - then at the end, random shuffle everything.
    My CodeBank Submissions: TETRIS using VB.NET2010 and XNA4.0, Strong Encryption Class, Hardware ID Information Class, Generic .NET Data Provider Class, Lambda Function Example, Lat/Long to UTM Conversion Class, Audio Class using BASS.DLL

    Remember to RATE the people who helped you and mark your forum RESOLVED when you're done!

    "Two things are infinite: the universe and human stupidity; and I'm not sure about the universe. "
    - Albert Einstein

  9. #9

    Thread Starter
    New Member
    Join Date
    May 2018
    Posts
    5

    Re: Password Generator Validation (Visual Studio 2010)

    Quote Originally Posted by Shaggy Hiker View Post
    I guess I'd ask whether or not this IS homework. We don't have an issue with helping with homework, but it would certainly restrict what solutions you'd be allowed to use.
    I'm afraid this isn't homework, I'm just a complete beginner haha! Its actually for a helpdesk at work, we were audited and i have to sort this out for the guys before next week.

  10. #10
    Frenzied Member jdc2000's Avatar
    Join Date
    Oct 2001
    Location
    Idaho Falls, Idaho USA
    Posts
    1,871

    Re: Password Generator Validation (Visual Studio 2010)

    Actually, if you are really looking for security, random character passwords that no one can remember are actually less secure than reasonable length pass phrases that cannot be guessed or easily brute forced but that users can remember. Passwords that you can't remember tend to get written down on post-it notes, so unless you are also using something like KeePass, this might be an issue.

  11. #11
    Bad man! ident's Avatar
    Join Date
    Mar 2009
    Location
    Cambridge
    Posts
    5,394

    Re: Password Generator Validation (Visual Studio 2010)

    Code:
    Public Class Form1
        Private Function Match(value As String) As Boolean
            Return System.Text.RegularExpressions.Regex.IsMatch(value, "^(?=.*[a-z])(?=.*[A-Z])(?=.*\d)(?=.*(_|[^\w])).+$")
        End Function
    End Class

  12. #12
    Powered By Medtronic dbasnett's Avatar
    Join Date
    Dec 2007
    Location
    Pointless Forest 38.517,-92.023
    Posts
    9,388

    Re: Password Generator Validation (Visual Studio 2010)

    Quote Originally Posted by ITdaz View Post
    I'm afraid this isn't homework, I'm just a complete beginner haha! Its actually for a helpdesk at work, we were audited and i have to sort this out for the guys before next week.
    Here is a password generator class, take some time to understand what is going on with it. It gives you some options, see the constructor.

    Code:
        Public Class PasswordGenerator
            Private Shared prng As New Random
            Private Shared ReadOnly Upper As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
            Private Shared ReadOnly Lower As String = "abcdefghijklmnopqrstuvwxyz"
            Private Shared ReadOnly Numeric As String = "0123456789"
            Private Shared ReadOnly Special As String = "?!£$%^&*()_+[];'#,./?><~@:}{\|"
            Private Shared AllChs As New System.Text.StringBuilder
            Private Shared ReadOnly AllChsLen As Integer = Upper.Length + Lower.Length + Numeric.Length + Special.Length
            Private _PasswordLength As Integer
            Public Password As String
            Private _MustHave As PasswordMustHave
            Private _dupCharsAllowed As Boolean = True
    
            <FlagsAttribute> _
            Public Enum PasswordMustHave
                none = 0
                upper = 1 << 0
                lower = 1 << 1
                number = 1 << 2
                special = 1 << 3
                all = PasswordMustHave.upper Or PasswordMustHave.lower Or PasswordMustHave.number Or PasswordMustHave.special
            End Enum
    
            Public Sub New(Optional Length As Integer = 8, Optional MustHave As PasswordMustHave = PasswordMustHave.all, Optional DupCharsAllowed As Boolean = True)
                If Length > 0 AndAlso Length < AllChsLen Then
                    Me._PasswordLength = Length
                Else
                    Me._PasswordLength = 8
                End If
                Me._MustHave = MustHave
                Me._dupCharsAllowed = DupCharsAllowed
                Me.Generate() 'generate a password on creation
            End Sub
    
            Public Function Generate() As String
    
                Dim passWD As New System.Text.StringBuilder
                Dim ie As IEnumerable(Of Char)
                Dim idx As Integer
                'contruct all if needed
                If AllChs.Length <> AllChsLen Then
                    AllChs.Length = 0
                    AllChs.Append(Upper)
                    AllChs.Append(Lower)
                    AllChs.Append(Numeric)
                    AllChs.Append(Special)
                End If
    
                passWD.Append(Me.MustHaveThese) 'add must have chars
    
                If Not Me._dupCharsAllowed Then 'allow dups
                    'strip nulls added by Me.MustHaveThese
                    For idx = AllChs.Length - 1 To 0 Step -1
                        If AllChs(idx) = ControlChars.NullChar Then
                            AllChs.Remove(idx, 1)
                        End If
                    Next
                End If
    
                Do While passWD.Length < Me._PasswordLength 'add random chars
                    idx = prng.Next(AllChs.Length)
                    passWD.Append(AllChs(idx))
                    If Not Me._dupCharsAllowed Then
                        'no dups
                        AllChs.Remove(idx, 1)
                    End If
                Loop
    
                ie = From c In passWD.ToString Select c
    
                ' idx = ie.Count
    
                'shuffle and create password
                Me.Password = (From ch In ie Select ch Order By prng.Next Take Me._PasswordLength).ToArray
                Return Me.Password
            End Function
    
            Private Function MustHaveThese() As String
                Dim rv As New System.Text.StringBuilder
                If (Me._MustHave And PasswordMustHave.upper) = PasswordMustHave.upper Then
                    rv.Append(Me.AddFrom(Upper))
                End If
    
                If (Me._MustHave And PasswordMustHave.lower) = PasswordMustHave.lower Then
                    rv.Append(Me.AddFrom(Lower))
                End If
    
                If (Me._MustHave And PasswordMustHave.number) = PasswordMustHave.number Then
                    rv.Append(Me.AddFrom(Numeric))
                End If
    
                If (Me._MustHave And PasswordMustHave.special) = PasswordMustHave.special Then
                    rv.Append(Me.AddFrom(Special))
                End If
    
                Return rv.ToString
            End Function
    
            Private Function AddFrom(item As String) As Char
                Dim rv As Char = item(prng.Next(item.Length))
                If Not Me._dupCharsAllowed Then
                    AllChs.Replace(rv, ControlChars.NullChar)
                End If
                Return rv
            End Function
        End Class
    Here it is being used to construct 10 passwords

    Code:
            Dim passwdGen As New PasswordGenerator()
            Dim lisPasswd As New List(Of String)
    
            For x As Integer = 1 To 10
                lisPasswd.Add(passwdGen.Password)
                passwdGen.Generate()
            Next
    My First Computer -- Documentation Link (RT?M) -- Using the Debugger -- Prime Number Sieve
    Counting Bits -- Subnet Calculator -- UI Guidelines -- >> SerialPort Answer <<

    "Those who use Application.DoEvents have no idea what it does and those who know what it does never use it." John Wein

  13. #13

    Thread Starter
    New Member
    Join Date
    May 2018
    Posts
    5

    Re: Password Generator Validation (Visual Studio 2010)

    Thanks a lot for all the replies, I eventually went with the Private Shuffle function. I really appreciate all the help.

  14. #14

    Thread Starter
    New Member
    Join Date
    May 2018
    Posts
    5

    Re: Password Generator Validation (Visual Studio 2010)

    Quote Originally Posted by dbasnett View Post
    Here is a password generator class, take some time to understand what is going on with it. It gives you some options, see the constructor.

    Code:
        Public Class PasswordGenerator
            Private Shared prng As New Random
            Private Shared ReadOnly Upper As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
            Private Shared ReadOnly Lower As String = "abcdefghijklmnopqrstuvwxyz"
            Private Shared ReadOnly Numeric As String = "0123456789"
            Private Shared ReadOnly Special As String = "?!£$%^&*()_+[];'#,./?><~@:}{\|"
            Private Shared AllChs As New System.Text.StringBuilder
            Private Shared ReadOnly AllChsLen As Integer = Upper.Length + Lower.Length + Numeric.Length + Special.Length
            Private _PasswordLength As Integer
            Public Password As String
            Private _MustHave As PasswordMustHave
            Private _dupCharsAllowed As Boolean = True
    
            <FlagsAttribute> _
            Public Enum PasswordMustHave
                none = 0
                upper = 1 << 0
                lower = 1 << 1
                number = 1 << 2
                special = 1 << 3
                all = PasswordMustHave.upper Or PasswordMustHave.lower Or PasswordMustHave.number Or PasswordMustHave.special
            End Enum
    
            Public Sub New(Optional Length As Integer = 8, Optional MustHave As PasswordMustHave = PasswordMustHave.all, Optional DupCharsAllowed As Boolean = True)
                If Length > 0 AndAlso Length < AllChsLen Then
                    Me._PasswordLength = Length
                Else
                    Me._PasswordLength = 8
                End If
                Me._MustHave = MustHave
                Me._dupCharsAllowed = DupCharsAllowed
                Me.Generate() 'generate a password on creation
            End Sub
    
            Public Function Generate() As String
    
                Dim passWD As New System.Text.StringBuilder
                Dim ie As IEnumerable(Of Char)
                Dim idx As Integer
                'contruct all if needed
                If AllChs.Length <> AllChsLen Then
                    AllChs.Length = 0
                    AllChs.Append(Upper)
                    AllChs.Append(Lower)
                    AllChs.Append(Numeric)
                    AllChs.Append(Special)
                End If
    
                passWD.Append(Me.MustHaveThese) 'add must have chars
    
                If Not Me._dupCharsAllowed Then 'allow dups
                    'strip nulls added by Me.MustHaveThese
                    For idx = AllChs.Length - 1 To 0 Step -1
                        If AllChs(idx) = ControlChars.NullChar Then
                            AllChs.Remove(idx, 1)
                        End If
                    Next
                End If
    
                Do While passWD.Length < Me._PasswordLength 'add random chars
                    idx = prng.Next(AllChs.Length)
                    passWD.Append(AllChs(idx))
                    If Not Me._dupCharsAllowed Then
                        'no dups
                        AllChs.Remove(idx, 1)
                    End If
                Loop
    
                ie = From c In passWD.ToString Select c
    
                ' idx = ie.Count
    
                'shuffle and create password
                Me.Password = (From ch In ie Select ch Order By prng.Next Take Me._PasswordLength).ToArray
                Return Me.Password
            End Function
    
            Private Function MustHaveThese() As String
                Dim rv As New System.Text.StringBuilder
                If (Me._MustHave And PasswordMustHave.upper) = PasswordMustHave.upper Then
                    rv.Append(Me.AddFrom(Upper))
                End If
    
                If (Me._MustHave And PasswordMustHave.lower) = PasswordMustHave.lower Then
                    rv.Append(Me.AddFrom(Lower))
                End If
    
                If (Me._MustHave And PasswordMustHave.number) = PasswordMustHave.number Then
                    rv.Append(Me.AddFrom(Numeric))
                End If
    
                If (Me._MustHave And PasswordMustHave.special) = PasswordMustHave.special Then
                    rv.Append(Me.AddFrom(Special))
                End If
    
                Return rv.ToString
            End Function
    
            Private Function AddFrom(item As String) As Char
                Dim rv As Char = item(prng.Next(item.Length))
                If Not Me._dupCharsAllowed Then
                    AllChs.Replace(rv, ControlChars.NullChar)
                End If
                Return rv
            End Function
        End Class
    Here it is being used to construct 10 passwords

    Code:
            Dim passwdGen As New PasswordGenerator()
            Dim lisPasswd As New List(Of String)
    
            For x As Integer = 1 To 10
                lisPasswd.Add(passwdGen.Password)
                passwdGen.Generate()
            Next
    This Is brilliant!

  15. #15
    Bad man! ident's Avatar
    Join Date
    Mar 2009
    Location
    Cambridge
    Posts
    5,394

    Re: Password Generator Validation (Visual Studio 2010)

    vb Code:
    1. Public Class form1
    2.     Private Sub GeneratePassword(allowed)
    3.         Dim password = String.Empty
    4.         Dim valid = Function(n)
    5.                         Return System.Text.RegularExpressions.Regex.IsMatch(n, "^(?=.*[a-z])(?=.*[A-Z])(?=.*\d)(?=.*(_|[^\w])).+$")
    6.                     End Function
    7.  
    8.         Do
    9.             password = New String((allowed.OrderBy(Function(c) Guid.NewGuid).Take(10)).ToArray())
    10.         Loop While Not valid(password)
    11.  
    12.  
    13.         MessageBox.Show(password)
    14.     End Sub
    15. End Class

  16. #16
    Bad man! ident's Avatar
    Join Date
    Mar 2009
    Location
    Cambridge
    Posts
    5,394

    Re: Password Generator Validation (Visual Studio 2010)

    Quote Originally Posted by jdc2000 View Post
    Actually, if you are really looking for security, random character passwords that no one can remember are actually less secure than reasonable length pass phrases that cannot be guessed or easily brute forced but that users can remember. Passwords that you can't remember tend to get written down on post-it notes, so unless you are also using something like KeePass, this might be an issue.

    so a 10 digit password i dont know is less secure than a 10 digit One i do?

  17. #17
    Frenzied Member jdc2000's Avatar
    Join Date
    Oct 2001
    Location
    Idaho Falls, Idaho USA
    Posts
    1,871

    Re: [RESOLVED] Password Generator Validation (Visual Studio 2010)

    so a 10 digit password i dont know is less secure than a 10 digit One i do?
    Not sure what you are meaning by this. However, a password you don't know is always more secure, since if you don't know it chances are no one else does either.

    My point is that a 128 character password that you have to write down is less secure than a 16 character password that you can remember. No one can read your mind (yet), but there is the potential that they might see or steal your password from a post-it note. Even electronic password "vaults" have potential issues if they get hacked, and some have been.

  18. #18
    Bad man! ident's Avatar
    Join Date
    Mar 2009
    Location
    Cambridge
    Posts
    5,394

    Re: [RESOLVED] Password Generator Validation (Visual Studio 2010)

    Quote Originally Posted by jdc2000 View Post
    Not sure what you are meaning by this. However, a password you don't know is always more secure, since if you don't know it chances are no one else does either.

    My point is that a 128 character password that you have to write down is less secure than a 16 character password that you can remember. No one can read your mind (yet), but there is the potential that they might see or steal your password from a post-it note. Even electronic password "vaults" have potential issues if they get hacked, and some have been.

    I was actually thinking you was suggesting a random password is less secure. How ever. .....

    You can't suggest a known password is less secure because it's written down is secure over a random One because that's adding an unfair condition.

    My last pass master password is 52 chars long. I know it off by heart. There is no pattern it's random. It's never been written down so how is that less secure than One i don't know? It is not. But this is not for this thread as off topic.

  19. #19
    You don't want to know.
    Join Date
    Aug 2010
    Posts
    4,578

    Re: [RESOLVED] Password Generator Validation (Visual Studio 2010)

    The last few posts, expressed in comic form:

    Name:  password_strength.jpg
Views: 98
Size:  71.0 KB
    This answer is wrong. You should be using TableAdapter and Dictionaries instead.

  20. #20
    Bad man! ident's Avatar
    Join Date
    Mar 2009
    Location
    Cambridge
    Posts
    5,394

    Re: [RESOLVED] Password Generator Validation (Visual Studio 2010)

    and your point is

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •  



Click Here to Expand Forum to Full Width