[RESOLVED] vb6 - horizontal scrollbar not showing in listbox

[lynnooi]

Hi all,

I had include the API for the horizontal scroll bar but then it still not showing. below is the codes i included for the scrollbar. Can anyone please help me look at it and provide me some guidance?

Public Sub getlistboxHScrollBar(str As String)
    Dim x As Long
    
    If x < TextWidth(str & "  ") Then
       x = TextWidth(str & "  ")
        If ScaleMode = vbTwips Then
            x = x / Screen.TwipsPerPixelX  ' if twips change to pixels
            SendMessageByNum lstScript.hwnd, LB_SETHORIZONTALEXTENT, x, 0&
        End If
    End If
 
End Sub

I called this function whenever i add an item into the listbox

[LaVolpe]

Welcome to the forums.

Is your scalemode twips? If not, the SendMessage call is not even being triggered. Otherwise, what is the value of X, before & after the division, when you believe the scrollbar should have been displayed?

[MartinLiss]

If I remember correctly it has to do with the order in which you add the data and when you add the scrollbar but I don't remember which is correct. In other words it's either...

1. Add the scrollbar
2. Populate the listbox

or

1. Populate the listbox
2. Add the scrollbar

[lynnooi]

Thanks all. I had remove the scalemode but still it doesn't appear.
Does it work if my getscrollbar function is in formA, my listbox is in formA too but i call this function from formB?
I had also try to change the sequence but no luck.

[MartinLiss]

Thanks all. I had remove the scalemode but still it doesn't appear.
Does it work if my getscrollbar function is in formA, my listbox is in formA too but i call this function from formB?
I had also try to change the sequence but no luck.

As long as it's a Public function then you do FormA.MyFunction

[lynnooi]

Ok. it's already a public function and there is no problem in calling it. no errors occur but the scrollbar did not show. Is there anything else which might cause it not showing?

[MartinLiss]

This works for me.

Option Explicit
 
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Const LB_SETHORIZONTALEXTENT = &H194



Private Sub Form_Load()
    Dim lLength As Long
    
    List1.AddItem "1234567891011121314151617181920"
    lLength = 2 * (List1.Width / Screen.TwipsPerPixelX)
    Call SendMessage(List1.hWnd, LB_SETHORIZONTALEXTENT, lLength, 0&)

End Sub

[lynnooi]

Hi all,

Thanks a lot for the guidance. I got the horizontal scrollbar appeared. However, I not sure what is going on. It just appear after i delete the old list box and replace with a newly created listbox.

[LaVolpe]

If you are calling that routine for each item you add to your listbox, you can inadvertently reset it to where the scrollbar won't show. If the width of the text is less than client width of the listbox, the scrollbar will disappear. I think you'll want to keep track of the widest item and set the horizontal extent when a new widest item is added.

[SwampeastMike]

Hi all,

Thanks a lot for the guidance. I got the horizontal scrollbar appeared. However, I not sure what is going on. It just appear after i delete the old list box and replace with a newly created listbox.

Realize the issue is marked as "resolved" but I'll give an update.

Working with VB6 under Windows 10

The following works perfectly, however, I had to delete and replace the listbox for the scrollbar to appear.

Declares:

'declare public function to add horizontal scroll bar to list box
    Public Declare Function SendMessageByNum Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal _
                                             wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    Public Const LB_SETHORIZONTALEXTENT = &H194

The subroutine to set the width:

Public Sub lstAddHScroll(argList As ListBox)
    'the purpose of this subroutine is to add a horizontal scrollbar to a listbox
    'call AFTER populating the listbox!
    
    Dim i&
    Dim lngBigWidth As Long

    lngBigWidth = 0

    For i& = 0 To argList.ListCount - 1
    'find the longest item
    'use "Me." preceding .TextWidth if working in a class module
        If frmMetadata.TextWidth(argList.List(i&)) > lngBigWidth Then 
               lngBigWidth = frmMetadata.TextWidth(argList.List(i&))
        End If
    Next
 'call function
'scale in twips - divide by 14
    i& = SendMessageByNum(argList.hwnd, LB_SETHORIZONTALEXTENT, lngBigWidth \ 14, 0)
End Sub

[VanGoghGaming]

'scale in twips - divide by 14
    i& = SendMessageByNum(argList.hwnd, LB_SETHORIZONTALEXTENT, lngBigWidth \ 14, 0)
End Sub

You should use the "ScaleX" method, divide by 14 is not a thing.

SendMessageByNum(argList.hwnd, LB_SETHORIZONTALEXTENT, frmMetadata.ScaleX(lngBigWidth, frmMetadata.ScaleMode, vbPixels), 0)

[SwampeastMike]

You should use the "ScaleX" method, divide by 14 is not a thing.

SendMessageByNum(argList.hwnd, LB_SETHORIZONTALEXTENT, frmMetadata.ScaleX(lngBigWidth, frmMetadata.ScaleMode, vbPixels), 0)

Thank you! That didn't seem correct yet compared to the example I found (using a different divisor) at least it worked [with listboxes of the same width].

Really strange the way I had to delete and replace (using exact same name/settings) the listbox before the scroll bar appeared for longer entries.

[yokesee]

You should use the "ScaleX" method, divide by 14 is not a thing.

SendMessageByNum(argList.hwnd, LB_SETHORIZONTALEXTENT, frmMetadata.ScaleX(lngBigWidth, frmMetadata.ScaleMode, vbPixels), 0)

I formatted the PC and installed Windows 11.
Many times in projects that previously worked well, the error

error 16 expression too complex

If Form1.TextWidth(argList.List(i&)) > lngBigWidth Then

[VanGoghGaming]

As far as I know, the expression too complex error comes after using the "Not Not Array" syntax to check whether an array is initialized or not.
This syntax will destabilize the IDE and make it spit out the expression too complex nonsense.

If you need to check for an initialized array then it's recommended to dereference the array pointer:

GetMem4 ByVal ArrPtr(Array), pSA
If pSA = 0 Then ' Array is not yet initialized