Show folders/files in TreeView

[nbrege]

Does anyone have a code snippet they could post that will take a specified folder & show the files & subfolders hierarchy in a TreeView? I did a quick search but I couldn't what I was looking for. Thanks...

[stanav]

Add a treeview and a button to your form then try this:

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        'Get a list of drives
        Dim drives As System.Collections.ObjectModel.ReadOnlyCollection(Of IO.DriveInfo) = My.Computer.FileSystem.Drives
        Dim rootDir As String = String.Empty
        'Now loop thru each drive and populate the treeview
        For i As Integer = 0 To drives.Count - 1
            rootDir = drives(i).Name
            'Add this drive as a root node
            TreeView1.Nodes.Add(rootDir)
            'Populate this root node
            PopulateTreeView(rootDir, TreeView1.Nodes(i))
        Next
    End Sub
 
    Private Sub PopulateTreeView(ByVal dir As String, ByVal parentNode As TreeNode)
        Dim folder As String = String.Empty
        Try
            Dim folders() As String = IO.Directory.GetDirectories(dir)
            If folders.Length <> 0 Then
                Dim childNode As TreeNode = Nothing
                For Each folder In folders
                    childNode = New TreeNode(folder)
                    parentNode.Nodes.Add(childNode)
                    PopulateTreeView(folder, childNode)
                Next
            End If
        Catch ex As UnauthorizedAccessException
            parentNode.Nodes.Add(folder & ": Access Denied")
        End Try
    End Sub

[nbrege]

Nice code Stanav ... thanks.

[nbrege]

Stanav ... can you help me with one more thing? Your code shows just the folders & subfolders. I want to show the files also, that are in the folders. I tried doing this myself, but I ended up with a big mess. Can you show me how to add the files to the TreeView also? I know how to get all the files in a folder, I'm just not sure where to add the code in the loop.

[stanav]

Try this now. Note that on the tree nodes, I only display the folder name or the file name. The full path is stored in the node.Tag property should you need it later. Just remember, since the Tag property returns an Object, you have to cast it back to String whenever you read the Tag property of a node.

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        'Get a list of drives
        Dim drives As System.Collections.ObjectModel.ReadOnlyCollection(Of IO.DriveInfo) = My.Computer.FileSystem.Drives
        Dim rootDir As String = String.Empty
        'Now loop thru each drive and populate the treeview
        For i As Integer = 0 To drives.Count - 1
            rootDir = drives(i).Name
            'Add this drive as a root node
            Dim root As TreeNode = TreeView1.Nodes.Add(rootDir)
            root.Tag = rootDir
            'Populate this root node
            PopulateTreeView(rootDir, TreeView1.Nodes(i))
 
        Next
 
    End Sub
 
    Private Sub PopulateTreeView(ByVal dir As String, ByVal parentNode As TreeNode)
        Dim folder As String = String.Empty
        Try
            'Add the files to treeview
            Dim files() As String = IO.Directory.GetFiles(dir)
            If files.Length <> 0 Then
                Dim fileNode As TreeNode = Nothing
                For Each file As String In files
                    fileNode = parentNode.Nodes.Add(IO.Path.GetFileName(file))
                    fileNode.Tag = file
                Next
            End If
            'Add folders to treeview
            Dim folders() As String = IO.Directory.GetDirectories(dir)
            If folders.Length <> 0 Then
                Dim folderNode As TreeNode = Nothing
                Dim folderName As String = String.Empty
                For Each folder In folders
                    folderName = IO.Path.GetFileName(folder)
                    folderNode = parentNode.Nodes.Add(folderName)
                    folderNode.Tag = folder
                    PopulateTreeView(folder, folderNode)
                Next
            End If     
        Catch ex As UnauthorizedAccessException
            parentNode.Nodes.Add("Access Denied")
        End Try
    End Sub

[Cavar]

If you want to convert it, you can use the load-on-demand treeview attached. The project is a VS2005 C# project that was converted to VS2008 C#, but you can just cut and paste the code into one of the many online C# to VB.NET converters.

It loads folders and files, displays a folder/file icon and a checkbox on each node that selects all children. The sub-folders and files are only loaded when you click the plus (+), that way it's faster than recursing all folders/files at once.

CT

[bhains_bhai]

Love you for this, i was trying to learn how to build complex tree structure that goes up to n times.

i found several articles like load tree from XML, datatable blah..blah.. and none could be useful to me.

but your article made me to understand better about treeview


Thank you very much

[rinjin]

Hello Stanav...

Good Day!!!

I get 3 error messages while using ur code.


1) In the code "Dim drives As System.Collections.ObjectModel.ReadOnlyCollection(of IO.DriveInfo) = My.Computer.FileSystem.Drives " there is a blue line below 'of' and while placing cursor below it says 'Array bounds cannot appear in type specifiers'.

2) 'Treeview1.Nodes.Add(rootDir)', there is a line below 'rootDir' and it says 'Value of type string cannot be converted 'Microsoft.Web.UI.Webcontrols. TreeNode'.

3) childNode = New TreeNode(folder). Here it says 'Too many argumenst to 'Public Sub New()'

Please help me sort this out as I am very new to asp.net.

Thanks and Regards,
Reenna

[rinjin]

Hi Stanav,

Good Day!!!

I get 3 errors while using ur code. Please help me solve them.

1. Dim drives As System.Collections.ObjectModel.ReadOnlyCollection(Of IO.DriveInfo) displays a line below 'Of' and says 'Array Bounds cannot appear in type specifiers'.

2.Treeview1.Nodes.Add(rootDir) - line below 'rootDir' and says 'va;ue of type String cannot be converted to Microsoft.Web.UI.Webcontrol.TreeNode.

3. childNode = New TreeNode(folder)..'Too many arguments to 'Public Sub New()'

I am very new to asp.net. Please help me solve these...

Regards,
Reena

[rinjin]

Hello Bhains Bhai...

If you used the vb.net code by Stanav and not C#. Please help me with the same...I am using VS2003.

Any help in this regard is highly appreciated.

Thanks.
Reena.

[stanav]

Hello Bhains Bhai...

If you used the vb.net code by Stanav and not C#. Please help me with the same...I am using VS2003.

Any help in this regard is highly appreciated.

Thanks.
Reena.

VS2003 is the culprit here. That code only works with VS2005 or VS2008.

[StianR]

Hi.

I get a System.IO.IOException "The device is not ready."Are there any way to ignore this node and go to the next one ?

by using something like this :

Catch ex As System.IO.IOException
With ex
If .Message.Substring(0, 24) = "The device is not ready." Then