counting strings in a listbox

[engnouna]

Hi
I have a listbox that may contain up to 100 items,but many items are of the same format:
e.g
1daily25042006
12daily25042006
35morning25042006
13daily25042006
1morning25042006

I want to count the total number of items containing the string daily(in the above example there is 3),I want also to count the total number of items containing morning and i'll continue looping through the listbox,if i find items with another string,i'll count the total number of it occurence

how can i do it?
thanks

[vbasicgirl]

Try something along these lines

Dim Daily As Integer, Morning As Integer
Dim i As Integer
 
 For i = 0 To List1.ListCount - 1
  If InStr(1, List1.List(i), "daily") Then
   Daily = Daily + 1
  ElseIf InStr(1, List1.List(i), "morning") Then
   Morning = Morning + 1
  End If
 Next i

also i would consider having some global variables and each time you add an item then you can check and keep count.

casey.

[engnouna]

hI
well I tried a code like ur code but the problem is that I don't know at the begining what are the items of the listbox,what i want to do is counting the items that contain the same string,ur code works well if I know all the string that are contained in the listbox

[MartinLiss]

Hi
I have a listbox that may contain up to 100 items,but many items are of the same format:
e.g
1daily25042006
12daily25042006
35morning25042006
13daily25042006
1morning25042006

I want to count the total number of items containing the string daily(in the above example there is 3),I want also to count the total number of items containing morning and i'll continue looping through the listbox,if i find items with another string,i'll count the total number of it occurence

how can i do it?
thanks

Do a search for posts by me that have "SendMessageString" in the text. Using that and LB_FindStringExact you could create a second, hidden, listbox and move the List1 items to List2 if they are not already in List2. When done, List2.ListCount will be the count you want.

[Bearnerd]

Do you mean the listbox may contain not only "daily" and "morning" but also another string which you don't know what?

[MartinLiss]

Do you mean the listbox may contain not only "daily" and "morning" but also another string which you don't know what?

Sorry I may have misunderstood your question. Will list1 always contain data that contains "daily" and "morning"?

[Static]

im sure this can be done better but it works

Dim cWords As New Collection
Private Sub Count_Words()
    Dim tmp As String
    Dim tmpK() As String
    For x = 0 To List1.ListCount - 1
        tmp = List1.List(x)
        For i = 1 To Len(tmp)
            If IsNumeric(Mid(tmp, i, 1)) Then
                tmp = Replace(tmp, Mid(tmp, i, 1), ".")
            End If
        Next
        tmp = Replace(tmp, ".", "")
        If Not AddedWordAlready(tmp) Then
            cWords.Add 1 & "|" & tmp, tmp
        Else
            Dim t As Integer
            tmpK = Split(cWords.Item(tmp), "|")
            t = tmpK(0)
            t = t + 1
            cWords.Remove tmp
            cWords.Add t & "|" & tmpK(1), tmp
        End If
    Next
    For x = 1 To cWords.Count
        Debug.Print cWords.Item(x)
    Next
End Sub
Private Function AddedWordAlready(wrd As String) As Boolean
    Dim test As String
    On Error GoTo Added
    test = cWords.Item(wrd)
    AddedWordAlready = True
    Exit Function
Added:
    AddedWordAlready = False
    
End Function
 
Private Sub Command1_Click()
    Count_Words
End Sub
 
Private Sub Form_Load()
    List1.AddItem "1daily25042006"
    List1.AddItem "12daily25042006"
    List1.AddItem "35morning25042006"
    List1.AddItem "13daily25042006"
    List1.AddItem "1morning25042006"
End Sub

[Static]

output will have
count|word
like this

3|daily
2|morning


and it will work with any set of words..
removes all numbers from the word.. then adds to a collection...

[engnouna]

Hi Static,
thanks a lot for ur code but I want to display the results in labels rather than in print.debug window.How can I do it?
thanks

[noshaba]

then make control array of labels and then using for each loop u can put values in labels by creating as many labels at runtime as u need

[engnouna]

10x a lot

[engnouna]

Hi Static
I used ur code but I call the sub Private Sub Count_Words() 3 times for 3 lists,I noticed that I need to remove cWords.Item(x) each time i move to another list
how can i delete cWords.Item(x)

because if in list1 there are 3 Daily and in list2 there are 2 Daily
when I display the results it gives me in list 1 3Daily but in list 2, 5 daily

[Static]

ok, if u are outputing to the labels in the sub (Count_words) just move the Dim cWord inside of the sub
Moving it inside the sub will reset it on each call..

Private Sub Count_Words()
    Dim cWords As New Collection 'Moved inside the sub
    Dim tmp As String
    Dim tmpK() As String
    For x = 0 To List1.ListCount - 1
        tmp = List1.List(x)
        For i = 1 To Len(tmp)
            If IsNumeric(Mid(tmp, i, 1)) Then
                tmp = Replace(tmp, Mid(tmp, i, 1), ".")
            End If
        Next
        tmp = Replace(tmp, ".", "")
        If Not AddedWordAlready(tmp) Then
            cWords.Add 1 & "|" & tmp, tmp
        Else
            Dim t As Integer
            tmpK = Split(cWords.Item(tmp), "|")
            t = tmpK(0)
            t = t + 1
            cWords.Remove tmp
            cWords.Add t & "|" & tmpK(1), tmp
        End If
    Next
    For x = 1 To cWords.Count
        Debug.Print cWords.Item(x)
    Next
End Sub
'...

[engnouna]

thanks Static
you've been a great help!!!!!!!!!!!!!!!!!

[Static]

glad it work.. Im not good with collections LOL

[bushmobile]

if you use a dictionary object (requires reference to Microsoft Scripting Runtime), then that has an Exists function which avoids the need for error catching:

' Call it as:
CountWords List1
 
Private Sub CountWords(ByVal lstBox As ListBox)
    Dim N As Long, I As Long, b() As Byte, stemp As String, dict As New Dictionary
        
    For N = 0 To lstBox.ListCount - 1
        b = lstBox.List(N)
        For I = 0 To UBound(b) Step 2
            If b(I) > 47 And b(I) < 58 Then b(I) = 0
        Next I
        stemp = Replace(b, Chr$(0), vbNullString)
        If dict.Exists(stemp) Then
            dict.Item(stemp) = dict.Item(stemp) + 1
        Else
            dict.Add stemp, 1
        End If
    Next N
    
    ' Print Result:
    For N = 0 To dict.Count - 1
        Debug.Print dict.Keys(N), dict.Item(dict.Keys(N))
    Next N
End Sub

[Static]

BAHH!! The Dictionary object is what I was thinking!! couldnt remember