[RESOLVED]BROWSEINFO or common dialog?

[pickarooney]

I've inherited a set of macros, one of which allows the running of one or more macros on a batch of files. The main dialog has a browse button on it which opens up a little browse dialog to allow the user to choose the path to the folder containing the files on which to run the macro(s). The thing is, this browser window is kind of annoying as it always defaults to the my computer view (the one in this page) and the user has to click down through the tree structure to the directory (s)he wants, which is rather tedious. I'd like to replace this dialog with one which allows the user to paste a path into the text-box at the bottom of the dialog and hit OK - a more modern Windows dialog. I'm not very experienced in VB (about 5 weeks if the truth be told) and don't understand the code fully, but have narrowed it down to two possible places where I have to make the change.
Is there much of a change needed in the following code, just the addition of a few lines, or do I need to use a completely different dialog and rewrite the code (I assume it's been done before, but attempts to find the code I need have been a bit confusing)?
When I open the form corresponding to the main dialog of the multimacrorunner, I can see that the name of the selected folder is lbFolder, and clicking browse activates this code:

Private Sub btnBrowse_Click()
     lblFolder.Caption = BrowseFolder
End Sub

Not much info there, but further on in the code there's the bit that corresponds to the opened folder:

Private Declare Function GlobalFree Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Function SHBrowseForFolder Lib "shell32.dll" ( _
                ByRef lpbi As BROWSEINFO) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32.dll" ( _
                pidl As Any, ByVal pszPath As String) As Long
 
'======= .bas wrapper for ShBrowseForFolder  =======
Private Const BIF_RETURNONLYFSDIRS As Long = &H1&
Private Const BIF_DONTGOBELOWDOMAIN = &H2&
Private Const BIF_STATUSTEXT = &H4&
Private Const BIF_RETURNFSANCESTORS = &H8&
Private Const BIF_EDITBOX = &H10&
Private Const BIF_VALIDATE = &H20& ' insist on valid result (or CANCEL)
Private Const BIF_BROWSEFORCOMPUTER = &H1000&  ' Browsing for Computers.
Private Const BIF_BROWSEFORPRINTER = &H2000&   ' Browsing for Printers
Private Const BIF_BROWSEINCLUDEFILES = &H4000& ' Browsing for Everything
 
Private Const MAX_PATH = 260
 
Private Const CSIDL_DRIVES As Long = &H11&
 
Private Type BROWSEINFO
    hwndOwner As Long ' HWND
    pidlRoot As Long '* pointer to: LPCITEMIDLIST (opens at ID)
    sDisplayName As String 'buffer for result
    sTitle As String 'prompt string
    ulFlags As Long ' UINT
    lpfn As Long '* pointer to: BFFCALLBACK
    lParam As Long ' LPARAM
    iImage As Long ' int
End Type
 
Private Declare Function FindWindow Lib "user32" Alias _
"FindWindowA" (ByVal lpClassName As String, _
          ByVal lpWindowName As Long) As Long
 
Public Function BrowseFolder(Optional sPrompt As String = "Select a folder..") As String
    'returns "" if Cancel selected, else Path
    Dim BINF As BROWSEINFO
    Dim lpItem As Long
    Dim sDir As String
 
    With BINF
        .hwndOwner = FindWindow("ThunderXFrame", 0)
        '.pidlRoot = 0& 'open at desktop
        .pidlRoot = 0 'CSIDL_DRIVES 'skips desktop <*> changed to 0 to show network folders
        .sDisplayName = Space$(MAX_PATH + 1)
        .sTitle = sPrompt
        .ulFlags = BIF_RETURNONLYFSDIRS
        .lpfn = 0
        .lParam = 0
        .iImage = 0
    End With
    lpItem = SHBrowseForFolder(BINF)
  
    If lpItem Then
        sDir = Space$(MAX_PATH)
        If SHGetPathFromIDList(ByVal lpItem, sDir) Then
            BrowseFolder = FixPath(Left(sDir, InStr(1, sDir, Chr(0)) - 1))
        End If
    End If
 
 
' The following step is most important. Neither Windows or VB will
'automatically release the memory consume by lpItem
 'so its up to the programmer to it.
 
GlobalFree lpItem
 
End Function

[westconn1]

have a look here
for more information and a list of the constants you can use for the start folders to browse from

.pidlRoot = 0 'CSIDL_DRIVES 'skips desktop <*> changed to 0 to show network folders

this line is the one that sets the starting directory

0 is CSIDL_DESKTOP (0x0000)
The virtual folder representing the Windows desktop, the root of the namespace.

CSIDL_DRIVES is 11

CSIDL_DRIVES (0x0011)
The virtual folder representing My Computer, containing everything on the local computer: storage devices, printers, and Control Panel. The folder may also contain mapped network drives.

pete

[pickarooney]

Cheers pete. I messed about with that, trying different values, and I now (I don't know why as as far as I can see the code is back to the way it was!) get the last-opened folder as the default, which is the value I want at least half the time.
Now, will I be able to enable this style of dialog with the input boxes at the bottom for file and type replaced by a pth to a directory?
I have to try rephrase that... I'd like to have a dialog like the one in the screenshot open instead of the current browser but with no option to select a file or filetype, only a directory.

[westconn1]

i have used the common dialog box like that to select a folder only by setting the filetitle to "Select folder to save to", before showning the dialog

the path you want to save to then is

left(filename,len(filename) - len(filetitle))

even if they do select a file name in the dialog it doesn't matter, as long as they select it in the right folder.

pete

[pickarooney]

OK, sounds good. How to display the common dialog then?

I tried this

Dim dlgFileOpen As New Dialog
       
    dlgFileOpen.Display

but it's not right

[manavo11]

You need to add the Microsoft Common Dialog Control component (Project -> Components) to your form. Then you can use :

CommonDialog1.ShowOpen

[Joacim Andersson]

If I understand you correctly you want to set an initial path for the BrowseForFolder dialog box. To be able to do that you need to create a callback function for the BrowseForFolder dialog box to call. You then have to check for the BFFM_INITIALIZED message and set the initial path you want to have selected when the dialog appears on screen.

Copy the below code to a regular BAS module (that's the only place a callback function can exist in).

Private Declare Function SendMessageString _
 Lib "user32" Alias "SendMessageA" ( _
 ByVal hWnd As Long, _
 ByVal wMsg As Long, _
 ByVal wParam As Long, _
 ByVal lParam As String) As Long
 
Private Const WM_USER = &H400
Private Const BFFM_SETSELECTIONA = (WM_USER + 102)
Private Const BFFM_INITIALIZED = 1
Private m_thePath As String
 
Public Property Let Path(ByVal sNewVal As String)
    m_thePath = sNewVal
End Property
 
'This function will be our callback function
Public Function ShowFolderCallback( _
 ByVal hWnd As Long, _
 ByVal uMsg As Long, _
 ByVal lParam As Long, _
 ByVal lpData As Long) As Long
    
    If uMsg = BFFM_INITIALIZED Then
        If Len(m_Path) > 0 Then
            SendMessageString hWnd, BFFM_SETSELECTIONA, 1&, m_thePath
        End If
    End If
    ShowFolderCallback = 0
End Function

Now let's say you've named this module FolderCallback you need to set the following code in your existing BrowseForFolder code.

With BINF
   [b] FolderCallback.Path [/b]= [i]sThePathYouWantToUse[/i]
   [b] .lpfn [/b]= ReturnParam(AddressOf FolderCallback.ShowFolderCallback)
    'set other BROWSEINFO members here
End With
'... call the SHBrowseForFolder function here... 
'... and the rest of the code to determent the selected folder

As you can see above I make a call to a ReturnParam function, this is just a dummy function that returns the AddressOf the function. It looks like this:

Private Function ReturnParam(ByVal nParam As Long) As Long
    'This function is a dummy function that only returns
    'the argument passed to it.
    ReturnParam = nParam
End Function

You need this function simply because you can't assign the AddressOf ShowFolderCallback directly to the structure member.

[pickarooney]

Thanks for all the answers, but I'm in way over my head. I did a terrible job of trying to explain what I wanted, partially because I wasn't sure what I wanted. I'm going to read through the code in these replies and try and understand it, as it's bound to be useful to know.
This is going to sound stupid now, but I think what I want to do is simply replace the entire BrowseFolder function with something that simply opens a common dialog and returns a path to a directory.

Also, I plan to completely rewrite the multimacrorunner macro some day, as I think it's needlessly complicated for something that simply runs a selection of macros on a selection of files (hear the sound of an idiot underestimating work!)

[westconn1]

add a project component to commondialog, then

commondialog.showopen or commondialog1.showsave

the folder path is the filename less the filetitle (see my previous reply)

pete

[pickarooney]

I don't understand. I have no Project menu in my VB IDE, and don't know how I can add a component.

[dglienna]

Press Control-T to bring up the Components screen. You can also call if from the Projects menu.

[Joacim Andersson]

I think I misunderstood your request in my earlier reply since I thought you wanted to be able to set an initial directory when the BrowseForFolder dialog box opened. But after reading it again I suspect what you're after is the dialog shown in the attached image.

That's easily fixed with the code you had. You only need to add on flag constant, marked as red in the code. You already had the flag constant for the edit box declared but you didn't use it so I added that to and marked it yellow below. Besides these changes the code is the same as you posted it. So there is no need to show an Open File dialog box when you want the user to select a folder.

Private Declare Function GlobalFree Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Function SHBrowseForFolder Lib "shell32.dll" ( _
                ByRef lpbi As BROWSEINFO) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32.dll" ( _
                pidl As Any, ByVal pszPath As String) As Long
 
'======= .bas wrapper for ShBrowseForFolder  =======
Private Const BIF_RETURNONLYFSDIRS As Long = &H1&
Private Const BIF_DONTGOBELOWDOMAIN = &H2&
Private Const BIF_STATUSTEXT = &H4&
Private Const BIF_RETURNFSANCESTORS = &H8&
Private Const [color="#CECE00"][b]BIF_EDITBOX[/b][/color] = &H10&
Private Const BIF_VALIDATE = &H20& ' insist on valid result (or CANCEL)
Private Const BIF_BROWSEFORCOMPUTER = &H1000&  ' Browsing for Computers.
Private Const BIF_BROWSEFORPRINTER = &H2000&   ' Browsing for Printers
Private Const BIF_BROWSEINCLUDEFILES = &H4000& ' Browsing for Everything
Private Const [color=red][b]BIF_USENEWUI = &H40[/b][/color]
 
Private Const MAX_PATH = 260
 
Private Const CSIDL_DRIVES As Long = &H11&
 
Private Type BROWSEINFO
    hwndOwner As Long ' HWND
    pidlRoot As Long '* pointer to: LPCITEMIDLIST (opens at ID)
    sDisplayName As String 'buffer for result
    sTitle As String 'prompt string
    ulFlags As Long ' UINT
    lpfn As Long '* pointer to: BFFCALLBACK
    lParam As Long ' LPARAM
    iImage As Long ' int
End Type
 
Private Declare Function FindWindow Lib "user32" Alias _
"FindWindowA" (ByVal lpClassName As String, _
          ByVal lpWindowName As Long) As Long
 
Public Function BrowseFolder(Optional sPrompt As String = "Select a folder..") As String
    'returns "" if Cancel selected, else Path
    Dim BINF As BROWSEINFO
    Dim lpItem As Long
    Dim sDir As String
 
    With BINF
        .hwndOwner = FindWindow("ThunderXFrame", 0)
        '.pidlRoot = 0& 'open at desktop
        .pidlRoot = 0 'CSIDL_DRIVES 'skips desktop <*> changed to 0 to show network folders
        .sDisplayName = Space$(MAX_PATH + 1)
        .sTitle = sPrompt
        .ulFlags = BIF_RETURNONLYFSDIRS Or [color=red][b]BIF_USENEWUI[/b][/color] Or [color="#CECE00"][b]BIF_EDITBOX[/b][/color]
        .lpfn = 0
        .lParam = 0
        .iImage = 0
    End With
    lpItem = SHBrowseForFolder(BINF)
  
    If lpItem Then
        sDir = Space$(MAX_PATH)
        If SHGetPathFromIDList(ByVal lpItem, sDir) Then
            BrowseFolder = Left(sDir, InStr(1, sDir, Chr(0)) - 1)
        End If
    End If
' The following step is most important. Neither Windows or VB will
'automatically release the memory consume by lpItem
 'so its up to the programmer to it.
 
    GlobalFree lpItem
 
End Function

[Joacim Andersson]

You can also call if from the Projects menu.

I think he's using VBA in which there is no Project menu, the Component dialog box is called Additional Controls and can be reach from the Tools menu.

[pickarooney]

Haha, thanks a million Joacim A picture's worth 1000 words - next time I'll just post two images: what I have and what I want to make