Keyboard Hook

[mike2]

Hello.

I was wondering, how can I hook the keyboard and wait for "Enter" key presses?
The hook must be system wide, not just for my application!

Also, I need to be able to cancel the "Enter" keypresses.

Thanks!

[manavo11]

Have a look at this : http://www.vbaccelerator.com/home/VB...ks/article.asp

I don't know if you can cancel the keypress but it's a start

[moeur]

Here is an example of discarding the return key with a system-wide low level keyboard hook.
Note, system-wide hooks are, in general, not a good idea because they can slow down your system if not properly used.
in a module

Option Explicit
 
Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" ( _
    ByVal idHook As Long, _
    ByVal lpfn As Long, _
    ByVal hmod As Long, _
    ByVal dwThreadId As Long _
) As Long
 
Private Declare Function UnhookWindowsHookEx Lib "user32" ( _
    ByVal hHook As Long _
) As Long
 
Private Declare Function CallNextHookEx Lib "user32" ( _
    ByVal hHook As Long, _
    ByVal ncode As Long, _
    ByVal wParam As Long, _
    lParam As Any _
) As Long
 
Public Const WH_KEYBOARD_LL = 13
Private Const HC_ACTION = 0
Private Const HC_NOREMOVE = 3
 
Public Type KBDLLHOOKSTRUCT
    vkCode As Long
    scanCode As Long
    flags As Long
    time As Long
    dwExtraInfo As Long
End Type
 
Private hHook As Long
Public IsHooked As Boolean
 
Public Sub SetKeyboardHook()
    If IsHooked Then
        MsgBox "Don't hook WH_KEYBOARD_LL twice or you will be unable to unhook it."
    Else
        hHook = SetWindowsHookEx(WH_KEYBOARD_LL, AddressOf LowLevelKeyboardProc, App.hInstance, 0)
        IsHooked = True
    End If
End Sub
 
Public Sub RemoveKeyboardHook()
    UnhookWindowsHookEx hHook
    IsHooked = False
End Sub
 
Public Function LowLevelKeyboardProc(ByVal uCode As Long, ByVal wParam As Long, lParam As KBDLLHOOKSTRUCT) As Long
    
    If uCode >= 0 Then
        Select Case uCode
            Case HC_ACTION
            'Debug.Print Hex(lParam.vkCode)
                'If a RETURN key is pulled from the queue then discard it.
                If lParam.vkCode = &HD Then
                    LowLevelKeyboardProc = 1
                    Exit Function
                End If
 
            Case HC_NOREMOVE
                'The message has not been removed from the message queue
        End Select
    End If
        
    LowLevelKeyboardProc = CallNextHookEx(hHook, uCode, wParam, lParam)
End Function

In your form

Option Explicit
 
Private Sub Command1_Click()
    SetKeyboardHook
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    RemoveKeyboardHook
End Sub

[Macka007]

i want to get a lowlevel hook of another program (Counter-Strike actually) so under certain conditions keypresses get detected by my program and not allowed to pass to CS, but im not sure how to get the "hInstance" of Counter-Strike.

Is "hInstance" the same as hwnd? or is there some other identifier i need?

[bushmobile]

why do you want to do that?

[Macka007]

The admin (one of my friends) keeps reading the "team_say" messages and so he knows what we are doing, so im making a chat program that ill give to my other friends so we can talk and he cant read what we are saying.

[bushmobile]

just use the system-wide hook in post #3.

just make sure you turn it on before playing and off after playing.

[Macka007]

Well, thats what i setup (because i couldnt get low-level hooking to work), but then i couldnt find anything that will block the keystrokes from being picked up by CS.

Any ideas?

[bushmobile]

what do you mean you could find anything that will block the keystrokes from being picked up by CS.

I used the hook above, changed this line:

If lParam.vkCode = [B]vbKeyA [/B]Then

and not able to press the A key when I tried to change my name in CS:S (wasn't able to test it in a game cos it failed to load - but i think that's just my computer not being able to handle it)

what's happening in your case?

[Macka007]

I Should have read through the code properly, i failed to notice the hook is only set by

Command1_Click()

Thanks for your help, it works really well now that i know how to initialize the hook

[Macka007]

Ok, it doesnt work as well as it should. I intergrated the Key Hook into my chat program.

To activate the hook you press ALT+Z, that does the following procedure.
When you press the Return key it Unhooks and the CS continues to work normally.

The first time it is activated it works fine, the second time however it allows keys to pass to CS and then CS starts getting erratic behavior and doesnt respond properly to key strokes (its hard to describe the symptoms as they seem to change each time).

Just thought of something.... i could keep the hook active but bypass the filtering and cancellation routines unless ALT+Z is pressed...
Might work, Ill keep you posted.

'Some other code to deal with shortcuts
 
            If Message.wParam = &HBFF1& Then
                SetKeyboardHook
                frmChatInjection.Shape2.BackStyle = 0
                MakeTransparent frmChatInjection 
            End If
 
'Some other code to deal with shortcuts
 
'***********************************************
'*********** Module to do with Hooks*****************
'***********************************************
 
Option Explicit
 
Private Declare Function SetWindowsHookEx Lib "user32" _
Alias "SetWindowsHookExA" (ByVal idHook As Long, ByVal lpfn As Long, _
 ByVal hmod As Long, ByVal dwThreadId As Long) As Long
 
Private Declare Function UnhookWindowsHookEx Lib "user32" _
(ByVal hHook As Long) As Long
 
Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, _
ByVal ncode As Long, ByVal wParam As Long, lParam As Any) As Long
 
Public Const WH_KEYBOARD_LL = 13
Private Const HC_ACTION = 0
Private Const HC_NOREMOVE = 3
 
Public Type KBDLLHOOKSTRUCT
    vkCode As Long
    scanCode As Long
    flags As Long
    time As Long
    dwExtraInfo As Long
End Type
 
Const SW_SHOWNORMAL = 1
Private hHook As Long
Public IsHooked As Boolean
 
Public Sub SetKeyboardHook()
    ShowWindow frmChatInjection.Hwndno, SW_SHOWNORMAL
    If IsHooked = False Then
        hHook = SetWindowsHookEx(WH_KEYBOARD_LL, AddressOf LowLevelKeyboardProc, App.hInstance, 0)
        IsHooked = True
    End If
End Sub
 
Public Sub RemoveKeyboardHook()
    
   ret = (UnhookWindowsHookEx(hHook))
    IsHooked = False
End Sub
 
Public Function LowLevelKeyboardProc(ByVal uCode As Long, ByVal wParam As Long, lParam As KBDLLHOOKSTRUCT) As Long
Dim Cnt As Integer
Static Counter As Integer
 
    If uCode >= 0 Then
        Select Case uCode
            Case HC_ACTION
            'Debug.Print Hex(lParam.vkCode)
                'If a RETURN key is pulled from the queue then discard it.
                Counter = Counter + 1
                If Counter = 2 Then
                    Counter = 0
                    lParam.vkCode = lParam.vkCode
                    GoTo FilterKeyUp
                End If
                Cnt = lParam.vkCode
                    If lParam.vkCode = lParam.vkCode Then
                        FilterKeys (Cnt)
                        LowLevelKeyboardProc = 1
                        Exit Function
                    End If
 
            Case HC_NOREMOVE
                'The message has not been removed from the message queue
        End Select
    End If
FilterKeyUp:
    LowLevelKeyboardProc = CallNextHookEx(hHook, uCode, wParam, lParam)
End Function
 
Public Function FilterKeys(ByVal Cnt As Integer)
If Cnt = 13 Then
    DoEvents
    frmChatInjection.Text2.SelStart = Len(frmChatInjection.Text2.Text)
    frmChatInjection.Text2.Text = frmChatInjection.Text2.Text & vbNewLine & frmChatInjection.Text1.Text
    frmChatInjection.Text2.SelStart = Len(frmChatInjection.Text2.Text)
    frmChatInjection.Text2.Locked = True
    frmChatInjection.Text2.Locked = False
    frmChatInjection.Text1.Text = ""
    frmChatInjection.Text1.Locked = True
    frmChatInjection.Text1.Locked = False
    RemoveKeyboardHook
    DoEvents
    frmChatInjection.Shape2.BackStyle = 1
    MakeTransparent frmChatInjection
    Exit Function
End If
On Error Resume Next
If Cnt = 8 Then
    frmChatInjection.Text1.Text = Left(frmChatInjection.Text1.Text, Len(frmChatInjection.Text1.Text) - 1)
    Exit Function
End If
If Cnt = 162 Then Exit Function
If Cnt = 160 Then Exit Function
If Cnt = 164 Then Exit Function
If Cnt = 9 Then Exit Function
If Cnt = 93 Then Exit Function
If Cnt = 20 Then Exit Function
If Cnt = 32 Then GoTo JumpCaseChange
If Cnt >= 48 And Cnt <= 57 Then GoTo JumpCaseChange
If Not Cnt <= 90 Then Exit Function
If Not Cnt >= 65 Then Exit Function
'If (GetKeyState(VK_SHIFT) And &HF0000000) = 0 Then
'Change the case from Upper to Lower
Cnt = Cnt + 32
 
JumpCaseChange:
frmChatInjection.Text1.Text = frmChatInjection.Text1.Text & Chr(Cnt)
 
End Function

[bushmobile]

Just thought of something.... i could keep the hook active but bypass the filtering and cancellation routines unless ALT+Z is pressed...

that was my initial thought. Try something like the below.

When the form loads you can type normally into textbox. Press Alt+T and then anything you type won't be passed to the textbox. Press Enter to see what you typed or press Esc to discard it. After pressing Return or Esc you can type in the textbox again:

Public Function LowLevelKeyboardProc(ByVal uCode As Long, ByVal wParam As Long, lParam As KBDLLHOOKSTRUCT) As Long
    
    If uCode >= 0 And uCode = HC_ACTION Then
        Select Case lParam.vkCode
            Case &HA4
                If wParam = WM_KEYUP And bLog Then
                    LowLevelKeyboardProc = CallNextHookEx(hHook, uCode, wParam, lParam)
                    Exit Function
                End If
            Case &HA0, &HA1 'Shift
                bShift = wParam = WM_KEYDOWN
            Case vbKeyA To vbKeyZ
                If bLog Then
                    If wParam = WM_KEYUP Then sText = sText & Chr$(lParam.vkCode + (Not bShift) * -32)
                Else
                    bLog = (((lParam.flags And LLKHF_ALTDOWN) = LLKHF_ALTDOWN) And (lParam.vkCode = vbKeyT))
                End If
            Case vbKeySpace
                sText = sText & Chr$(lParam.vkCode)
            Case vbKeyBack
                If bLog And wParam = WM_KEYUP Then sText = Left$(sText, Len(sText) - 1)
            Case vbKeyReturn
                If bLog And wParam = WM_KEYUP Then
                    SendText sText
                    sText = vbNullString
                    bLog = False
                End If
            Case vbKeyEscape
                If bLog And wParam = WM_KEYUP Then
                    sText = vbNullString: bLog = False
                    LowLevelKeyboardProc = 1: Exit Function
                End If
        End Select
        If bLog Then LowLevelKeyboardProc = 1: Exit Function
    End If
       
    LowLevelKeyboardProc = CallNextHookEx(hHook, uCode, wParam, lParam)
End Function

I've attached an example:

[Macka007]

That is amazing, how did you know to do it like that?

Im guessing the .Flags parameter tells you if ctrl, alt, shift are pressed.

What is the bLog Var for?

And what is the wParam for?

i looked in the API guide for wParam and lParam but all it said was

· wParam
Specifies the wParam value passed to the current hook procedure. The meaning of this parameter depends on the type of hook associated with the current hook chain.

· lParam
Specifies the lParam value passed to the current hook procedure. The meaning of this parameter depends on the type of hook associated with the current hook chain.

This is the code I have been using (its got a couple of patches here and there because I was trying to get capitals and '!' through ')' to work, but now I have decided they are not as important.

To run the code you may need Microsoft Direct Text-To-Speech and a L&H TTS engine installed.

[bushmobile]

bLog is just a boolean that distinguishes whether we're recording the text or not.

for the other questions, take a look at the MSDN articles: LowLevelKeyboardProc Function, KBDLLHOOKSTRUCT Structure

[Macka007]

The code you used to select case didnt work for me, so i changed it from this:

Case vbKeyA To vbKeyZ
                If bLog Then
                    If wParam = WM_KEYUP Then sText = sText & Chr$(lParam.vkCode + (Not bShift) * -32)
                Else
                    bLog = (((lParam.flags And LLKHF_ALTDOWN) = LLKHF_ALTDOWN) And (lParam.vkCode = vbKeyT))
                End If

To This:

Case vbKeyA To vbKeyZ
                If bLog Then
                    If wParam = WM_KEYUP Then sText = sText & Chr$((lParam.vkCode + IIf(bShift, 0, 32)))
                Else
                    bLog = (((lParam.flags And LLKHF_ALTDOWN) = LLKHF_ALTDOWN) And (lParam.vkCode = vbKeyT))
                End If

To detect numbers and their corresponding char's i added this code:

Case vbKey0 To vbKey9
                If bLog Then
                    If wParam = WM_KEYUP Then
                        If bShift Then
                            If lParam.vkCode = 48 Then Cnt = lParam.vkCode - 7
                            If lParam.vkCode = 49 Then Cnt = lParam.vkCode - 16
                            If lParam.vkCode = 50 Then Cnt = lParam.vkCode + 14
                            If lParam.vkCode = 51 Then Cnt = lParam.vkCode - 16
                            If lParam.vkCode = 52 Then Cnt = lParam.vkCode - 16
                            If lParam.vkCode = 53 Then Cnt = lParam.vkCode - 16
                            If lParam.vkCode = 54 Then Cnt = lParam.vkCode + 40
                            If lParam.vkCode = 55 Then Cnt = lParam.vkCode - 17
                            If lParam.vkCode = 56 Then Cnt = lParam.vkCode - 14
                            If lParam.vkCode = 57 Then Cnt = lParam.vkCode - 17
                            sText = sText & Chr$(Cnt)
                        Else
                            If wParam = WM_KEYUP Then sText = sText & Chr$(lParam.vkCode)
                        End If
                    End If
                End If

[bushmobile]

hmmm, strange.

(Not bShift) * -32 and IIf(bShift, 0, 32) should have the same outcome. Does my example project work correctly for you (it does for me).

anyhow, be aware that using IIf is significantly slower than using the If Then construct, and since speed is important here - if you can't get the method i suggested to work then you should use an If...Then block.

Regarding your number coding you have to think about how many operations you're performing each time. Let's take an example - say the lParam.vkCode is for vbKey0.

your code matches on the first line after "If bShift Then", but it then still has to check for the other 9 numbers - all of those operations are wasting time. Also if there is a match then you know Cnt has an absolute value it's being assigned, yet for each one you're performing a unnecessary operation:

Case vbKey0 To vbKey9
                If bLog Then
                    If wParam = WM_KEYUP Then
                        If bShift Then
                            Select Case lParam.vkCode
                                Case vbKey0
                                    cnt = 41
                                Case vbKey1, vbKey3 To vbKey5
                                    cnt = lParam.vkCode - 16
                                Case vbKey2
                                    cnt = 64
                                Case vbKey6
                                    cnt = 94
                                Case vbKey7, vbKey9
                                    cnt = lParam.vkCode - 17
                                Case vbKey8
                                    cnt = 42
                            End Select
                            sText = sText & Chr$(cnt)
                        Else
                            If wParam = WM_KEYUP Then sText = sText & Chr$(lParam.vkCode)
                        End If
                    End If
                End If

I make no guarentees those numbers are correct!

[Aleoss]

Contrary to what the script says, if you hook it twice. It only hooks it until Windows restarts, otherwise it stays hooked even after application termination.

It isn't writing any settings, it's just hooking that keystroke, thus it is only a change of a low-level setting without saving.

Also, I have a question regarding more advanced key hooking.

I'm trying to make a password application that runs through svchost.exe as a secondary to Windows logon. Requires the user to use Safe-Mode to bypass it, but using Safe-Mode will prevent any third party software from initializing which in turn will make the system more secure as I have the hidden Administrator account disabled and the guest account disabled as well.

By making a full-screened application that key hooks the following:
Ctrl + Alt + Del
Ctrl + Shift + Esc
Alt + F4
Alt + Tab
Ctrl + Esc
Alt + Esc
Left Win Key + D
Left Win Key + E
Right Win Key + D
Right Win Key + E
Left Win Key
Right Win Key
Open Context Menu Key
Alt Tab (Lock) Key (AKA Window Panes Key)



Edit:

Sorry for reviving an ancient thread, but this could be elaborated on further.