Open existing Word Doc in active Word App?

[BarankinBeAMan]

Could anybody help with this?

Scenario:

There is already Word doc open, I just need to add another existing one, to the same Word Application, just onw Word Active window for all documents.

I used SetParent API, did not help much, it opens new word appl for existing doc.


Thank you all.

[RobDog888]

Use GetObject to attach to the current running Word application.
Then you can open as usual off of the attached word aplication so
the document will be another window in word.

HTH

[BarankinBeAMan]

Something like that?:

Public Sub New
Set Me.word_application = Nothing
Set Me.word_document = Nothing
On Error Resume Next
Set Me.word_application = GetObject("", "Word.Application")
If (Err = 208) Then
' Word not active. Create new object to launch Word in background.
Err = 0
Set Me.word_application = CreateObject("Word.Application")
End If
Call Me.word_application.Documents.Add
Set Me.word_document = Me.word_application.ActiveDocument
End Sub

[RobDog888]

Yes, but why do you need all the Me's?

[BarankinBeAMan]

no me's, that was for Net.

But this code still does not help, even if no Word App is active, this getobject still returns 0 for the error. Even if I kill all WinWord apps.
Any ather suggestions?

Thanks

[RobDog888]

This works in VB6. Can't test for .NET because my test system is
taken apart right now.

Option Explicit
'Add reference to M$ Office Word Object Library
Private moApp As Word.Application
Private moDoc As Word.Document
 
Private Sub Command1_Click()
    Set moDoc = moApp.Documents.Open("C:\Test.doc")
End Sub
 
Private Sub Form_Load()
    
    On Error GoTo No_Set
    
    Set moApp = GetObject(, "Word.Application")
    If TypeName(moApp) = "Nothing" Then
        Set moApp = CreateObject("Word.Application")
    End If
    moApp.Visible = True
    Exit Sub
No_Set:
    If Err.Number = 429 Then
        Resume Next
    Else
        MsgBox Err.Number & " - " & Err.Description, vbOKOnly + vbExclamation
    End If
End Sub

[RobDog888]

It will open the Test.doc in the same Word window. Although
it will still show each document in the taskbar as separate windows.

[BarankinBeAMan]

Yes, the code runs fine, it opens Test.doc in the same app.
But if you add second doc. Test1.doc, it opens new window for me. Is there anyway to open Test1.doc in the same window?

Thanks.

Private moApp As Object 'Word.Application
Private moDoc As Object 'Word.Document
Private moDoc2 As Object

Private Sub Command1_Click()
Set moDoc = moApp.Documents.Open("C:\Test.doc")
End Sub
Private Sub Command3_Click()
Set moDoc2 = moApp.Documents.Open("C:\Test1.doc")
End Sub

Private Sub Command2_Click()

On Error GoTo No_Set

Set moApp = GetObject(, "Word.Application")
If TypeName(moApp) = "Nothing" Then
MsgBox "No Word is running, creating new."
Set moApp = CreateObject("Word.Application")
Else
MsgBox "Word is running, add document."
End If
moApp.Visible = True
Exit Sub
No_Set:
If Err.Number = 429 Then
Resume Next
Else
MsgBox Err.Number & " - " & Err.Description, vbOKOnly + vbExclamation
End If

End Sub

[RobDog888]

I added two more docs and they are all in the same instance of
Word. Do you mean that you dont want them to show separate
in the taskbar?

'This is what I did for three docs.
Option Explicit
'Add reference to M$ Office Word Object Library
Private moApp As Word.Application
Private moDoc As Word.Document
 
Private Sub Command1_Click()
    Set moDoc = moApp.Documents.Open("D:\Add1.doc")
    Set moDoc = moApp.Documents.Open("D:\Add2.doc")
End Sub
 
Private Sub Form_Load()
    
    On Error GoTo No_Set
    
    Set moApp = GetObject(, "Word.Application")
    If TypeName(moApp) = "Nothing" Then
        Set moApp = CreateObject("Word.Application")
    End If
    moApp.Visible = True
    Set moDoc = moApp.Documents.Open("D:\Test.doc")
    Exit Sub
No_Set:
    If Err.Number = 429 Then
        Resume Next
    Else
        MsgBox Err.Number & " - " & Err.Description, vbOKOnly + vbExclamation
    End If
End Sub

If you dont want them to show separately in the
taskbar, you can change the settings in Word programmatically
like this.

moApp.ShowWindowsInTaskbar = False

Or manually like this.

[BarankinBeAMan]

Thank you.

Ñëàâà Òðóäó !

[RobDog888]

No prob.

Was it just eliminating the showing in the taskbar or was it the
code that solved it for you?

[BarankinBeAMan]

GetObject is pretty much what I needed.
Also I realized I wanted something else that I did not really need