VB Snippet - Internet Status

[James Stanich]

Private Declare Function InternetCheckConnection Lib "wininet.dll" Alias "InternetCheckConnectionA" (ByVal lpszUrl As String, ByVal dwFlags As Long, ByVal dwReserved As Long) As Long
 
Private Const FLAG_ICC_FORCE_CONNECTION = &H1
 
Private Sub Form_Load()
 
    If InternetCheckConnection("http://www.galahtech.com", FLAG_ICC_FORCE_CONNECTION, 0&) = 0 Then
 
        MsgBox "No internet connection detected...", vbInformation
 
    Else
 
        MsgBox "Internet connection detected...", vbInformation
 
    End If
 
End Sub

[manavo11]

Private Declare Function InternetGetConnectedState Lib "wininet.dll" (ByRef lpSFlags As Long, ByVal dwReserved As Long) As Long 
 
Private Sub Command1_Click() 
If InternetGetConnectedState(0, 0) Then 
    MsgBox "Online" 
Else 
    MsgBox "Offline" 
End If 
End Sub

[manavo11]

'Example by Vijay Phulwadhawa (vijaycg44@hotmail.com) 
Private Declare Function InternetGetConnectedStateEx Lib "wininet.dll" (ByRef lpdwFlags As Long, ByVal lpszConnectionName As String, ByVal dwNameLen As Integer, ByVal dwReserved As Long) As Long 
Dim sConnType As String * 255 
Private Sub Form_Load() 
    Dim Ret As Long 
    Ret = InternetGetConnectedStateEx(Ret, sConnType, 254, 0) 
    If Ret = 1 Then 
        MsgBox "You are connected to Internet via " & sConnType, vbInformation 
    Else 
        MsgBox "You are not connected to internet", vbInformation 
    End If 
End Sub

[manavo11]

Option Explicit 
 
Private Sub Command1_Click() 
  Screen.MousePointer = vbHourglass 
  With Winsock1 
    .Protocol = sckTCPProtocol 
    .RemotePort = 80 
    .RemoteHost = "www.vbforums.com" 
    .Connect 
    
    Do While .State <> sckConnected And .State <> sckError 
      DoEvents 
    Loop 
    If .State = sckConnected Then 
      Caption = "Online" 
    Else 
      Caption = "Offline" 
    End If 
    .Close 
    .LocalPort = 0 
  End With 
  Screen.MousePointer = vbDefault 
End Sub

[shirazamod]

Private Declare Function InternetCheckConnection Lib "wininet.dll" Alias "InternetCheckConnectionA" (ByVal lpszUrl As String, ByVal dwFlags As Long, ByVal dwReserved As Long) As Long
 
Private Const FLAG_ICC_FORCE_CONNECTION = &H1
 
Private Sub Form_Load()
 
    If InternetCheckConnection("http://www.galahtech.com", FLAG_ICC_FORCE_CONNECTION, 0&) = 0 Then
 
        MsgBox "No internet connection detected...", vbInformation
 
    Else
 
        MsgBox "Internet connection detected...", vbInformation
 
    End If
 
End Sub

Will the above code work if user is connected via LAN?
Thanx, Shiraz

[manavo11]

It should. If there is an active internet connection then a connection to the site will be made.