VB6.0 – Sound and DirectXSound Tutorial

[CVMichael]

Splitting a Stereo buffer to 2 Mono buffers

In a Stereo buffer, the left channel is stored first, then the right channel.
So, at position 1, you will find the sample of the left channel, position 2 is right channel, position 3 is left channel again, and so on.

Here is code to split Stereo buffer to 2 Mono buffers, for 8 and 16 Bit:

Public Sub SoundStereoToMono16(InStereo() As Integer, OutLeftChannel() As Integer, OutRightChannel() As Integer)
    Dim InPos As Long
    Dim OutPos As Long
    
    ReDim OutLeftChannel((UBound(InStereo) + 1) \ 2 - 1)
    ReDim OutRightChannel(UBound(OutLeftChannel))
    
    For InPos = 0 To UBound(InStereo) Step 2
        OutLeftChannel(OutPos) = InStereo(InPos)
        OutRightChannel(OutPos) = InStereo(InPos + 1)
        
        OutPos = OutPos + 1
    Next InPos
End Sub
 
Public Sub SoundStereoToMono8(InStereo() As Byte, OutLeftChannel() As Byte, OutRightChannel() As Byte)
    Dim InPos As Long
    Dim OutPos As Long
    
    ReDim OutLeftChannel((UBound(InStereo) + 1) \ 2 - 1)
    ReDim OutRightChannel(UBound(OutLeftChannel))
    
    For InPos = 0 To UBound(InStereo) Step 2
        OutLeftChannel(OutPos) = InStereo(InPos)
        OutRightChannel(OutPos) = InStereo(InPos + 1)
        
        OutPos = OutPos + 1
    Next InPos
End Sub

[CVMichael]

Mixing buffers

Mixing sound is actually very easy, you simply add the value from the first buffer to the value from the second buffer (and so on...).

When mixing sounds, since you add 2 (or more) sounds into one, the volume might get too loud, therefore I also added a parameter to the function to lower the volume.

I posted 2 functions, one mix 2 sounds, and another to mix 3 sounds. As you can see the only difference is where it's adding the buffers together, so it's easy to make a function to mix 4 sounds (and more), because all you do is to add all of them together.

The last parameter is the "Divisor" (Div), if you mix 2 sounds you might want to put the divisor to 1/2 (0.5), or if you mix 3 sounds, 1/3 (0.33), and so on. I put the Div value equal to 1, because this is optional.

Public Function WaveMIX2(Buffer1() As Integer, Buffer2() As Integer, Optional Div As Single = 1) As Integer()
    Dim K As Long, Sample As Single
    Dim Ret() As Integer
    
    ReDim Ret(UBound(Buffer1))
    
    For K = 0 To UBound(Buffer1)
        Sample = (CSng(Buffer1(K)) + Buffer2(K)) * Div
        
        If Sample < -32768 Then Sample = -32768
        If Sample > 32767 Then Sample = 32767
        
        Ret(K) = Sample
    Next K
    
    WaveMIX2 = Ret
End Function
 
Public Function WaveMIX3(Buffer1() As Integer, Buffer2() As Integer, Buffer3() As Integer, Optional Div As Single = 1) As Integer()
    Dim K As Long, Sample As Single
    Dim Ret() As Integer
    
    ReDim Ret(UBound(Buffer1))
    
    For K = 0 To UBound(Buffer1)
        Sample = (CSng(Buffer1(K)) + Buffer2(K) + Buffer3(K)) * Div
        
        If Sample < -32768 Then Sample = -32768
        If Sample > 32767 Then Sample = 32767
        
        Ret(K) = Sample
    Next K
    
    WaveMIX3 = Ret
End Function