[RESOLVED] Please help : How to embed sound file into a project..

Hi everyone,
can anyone help me how to embed a sound file without requiring any additional RES file??
I mean something like a standalone application that has a playable sound file in it. Please help.. Thank you

But a RES file is compiled into the exe file.

That's why i'd like to do it without using res file. How should i?

I don't understand. You say that you want the sound file in your EXE but you don't want to use a RES file that does exactly that? If you put the sound file into the project RES file it is compiled into the EXE. Meaning that you don't have to distribute the sound file nor the RES file.

The only way ou are going to do it is with a resource file.

Without a resource file, you sound file can not be embedded in your EXE

The only other option that I'm aware of is to physically store the file in a database field.

Is that really so? So, you mean there's no such possibility to embed sound file into an EXE? Well, ok but i've ever seen a program built that way (something like a keygen), it does standalone with no RES file included..
Sorry for my lack of knowledge is Vb..

Thanks for the reply anyway. I wish someday i'd find one like i described, so that i can show you. :D

Quote:

---

Originally Posted by vibiEn

Thanks for the reply anyway. I wish someday i'd find one like i described, so that i can show you. :D

---

If you do find it, it will either have an embedded resource file that you don't know about or it won't be written in VB.

Quote:

---

Originally Posted by Hack

...The only other option that I'm aware of is to physically store the file in a database field.

---

Could you show me how to do it?
Thanks again..

One little thing that come to my mind is that to open the file by accessing it through binary and save it into a textbox field, then reopen it using binary access as the original sound file (i.e. *.Wav)

this sounds a bit odd but i dunno whether or not it can be done..

you can put a sound file into your EXE (not a res file) but it's not practical to do so and is a bit akward to build the binary byte codes and have them in your source code as such. I didn't use a sound file but I did put the binary of a Java class file in my VB source but the principal is the same for any binary file.

Quote:

---

Originally Posted by jmsrickland

you can put a sound file into your EXE (not a res file) but it's not practical to do so and is a bit akward to build the binary byte codes and have them in your source code as such. I didn't use a sound file but I did put the binary of a Java class file in my VB source but the principal is the same for any binary file.

---

could you please show me some simple code to clearly explain to me? I dunno how

much appreciate. Thanks..

I really need help on this. Please help me out

Why can't you use a Resource File? Why has it 'got' to be embeded? You'll have to build a Setup file if you're going to distribute your program and that will take care of dependencies - what's the problem ?

Just like VB embeds Icon and bitmap files i want it to be done. I wonder if i can use a byte array to store the data somehow..

Our database FAQs cover how to store a file in a database table.

Well, however i thank you all for the assistance :)

Quote:

---

Originally Posted by vibiEn

Just like VB embeds Icon and bitmap files i want it to be done. I wonder if i can use a byte array to store the data somehow..

---

These files are stored in the resource section of your exe file. I think you have misunderstood what a resource file is.

These files are stored in the resource section of your exe file. I think you have misunderstood what a resource file is.

Ummm, I don't think so. When you put a bitmap on your Form or in a Picturebox Control the bitmap data is stored in the Form1.frx file which is not the same as the .RES file. I think what he wants is the same thing for a sound file where it is stored either directly in the source code (which when I get the time I will show him how I did it) or he wants the sound file stored in the same manner as a bitmap in the .FRX file.

The Form.frx file is a sort of resource file, the frx file is only used by the VB IDE, the content is compiled into the exe just like any other resource. A resource file will be embedded into the exe. If you want something embedded into your exe use a resource file. I just don't get the question at all. "I want the sound embedded in my exe that is why I don't want to use a resource file"????

I too don't understand what his problem is using a resource file. Doesn't make any sense. Even when I was able to figure out how to put the Java class file into the source code it was still a hassle to do but that was before I knew about the resource file and now I won't bother doing it the old way I now use the resource file to embed Java class files or any binary file for that matter.

Quote:

---

Originally Posted by jmsrickland

Ummm, I don't think so. When you put a bitmap on your Form or in a Picturebox Control the bitmap data is stored in the Form1.frx file which is not the same as the .RES file. I think what he wants is the same thing for a sound file where it is stored either directly in the source code (which when I get the time I will show him how I did it) or he wants the sound file stored in the same manner as a bitmap in the .FRX file.

---

You did get what i really mean, Great! I'm looking forward to hearing good news from you soon.. Thanks alot :D

vibiEn, can you please explain why you don't want to use a resource file? Understanding your requirements makes it easier to come up with a solution. The icon is indeed a resource and is put inside the resource section of your exe file. The frx file is beside the point.

Quote:

---

Originally Posted by SilverDog

vibiEn, can you please explain why you don't want to use a resource file? Understanding your requirements makes it easier to come up with a solution. The icon is indeed a resource and is put inside the resource section of your exe file. The frx file is beside the point.

---

Thanks for asking.
I got a pretty simple answer that is, i'm about to build a simple learning program that will require no additional file. The reason's so that i can easily move the exe anywhere without caring other related files. Just to make it stand-alone. Is that really impossible to do without resource??

If it really is, then is there any other way to make a program with built-in custom files that require no files? Just an exe, that's all

thanks alot

Thanks for trying to answer the question, but you actually never said *why* you wouldn't use a resource file. All you say is that you just want a standalone exe file that doesn't need any additional files (which BTW isn't possible using VB since all VB programs needs the run-time files) and a resource file actually does exactly that! So can you please try to answer this question: If a resource file meets your requirements to 100% then why don't you want to use it? You do not need to copy the resource file with your EXE, since the resource is embedded into the EXE. I do like to help you if I can I just don't understand your requirements, and without that understanding I don't really think anyone can answer your question. Embedding the file into a database, as suggested above, doesn't meet your requirements since you then need to distribute the database (and possibly the database engine) with your EXE.

Haha, sorry for the mess i started..
Ok. From the beginning what i've got is just RES and RES again.. Umm, i'm working on this silly mistery of my own and i wish to be able to get the solution somehow, and show it to you.. Sorry for this confusion.
If the only way to do it is just by using Resource file, then perhaps i'll start to think about using it..
Thanks to you all :)

Well, there are probably other ways of doing it. I just wondered what your requirements are that force you to use a non-standard approach?

Well, no other requirements. Just a stand-alone EXE (without any RES or DLLs) with a sound file (i.e. Wav) in it. That's all. So..

You will still need DLLs since VB needs its run-time. The RES is just a developer file, just like your frm, cls, bas files which is not distributed but all compiled into the EXE. So unlike DLLs the RES file does not need to be distributed with your EXE.

Aha, i'm aware of that. I mean i knew that vb needs frm or dll or other files while it is not compiled. But will the EXE be an independent app when it is compiled into an exe ?
I myself even get confused due to my own question.. :blush:

Any idea where I could get a tut or code examples on using a RES?
Thanks :)

Notwithstanding Joacim's comments and your desire not to use a RES file, you could just append the contents of the sound file to the end of your .exe, and in your Program read the contents back into an array and use, whatever API it is, to play a sound from an array. You'll need to understand how to use Binary files, Get, Put, Seek and. probably, Seek().

Also, with this method you may run the risk of Virus Scanners deciding that your program is a virus, because of the additional bytes in the .exe file.

All in all, a RES file seems to be the correct method for you to adopt as it gets 'imbedded' into the .exe in a standard fashion.
If you've not used them before there's a Tutorial here: http://www.vbforums.com/showthread.php?t=345097

Quote:

---

Originally Posted by vibiEn

Aha, i'm aware of that. I mean i knew that vb needs frm or dll or other files while it is not compiled. But will the EXE be an independent app when it is compiled into an exe ?
I myself even get confused due to my own question.. :blush:

---

When your .exe is compiled it will have Dependencies, for instance, any controls you use on the form (ie .OCX files, DLL files). All these dependencies must exist on the target machine for your program to run successfully. Some will be in the VB Runtimes so at a minimum, the target machine will have to have those, other files will have to be installed and registered.

The Package and Deployment Wizard will do all that for you. It works out all the dependencies and will create a Setup.exe and associated cabinets, so all you have to do is run the setup program on the target machine to install the program and its dependencies.

If you don't mind, Please show me a simple code on this, i long for codes :D

Thanks for all

I am working on the method I stated earlier on how to put your sound file inside your VB source code.

If you still want to use this method then OK but I told you earlier that it is quite akward and kind of silly to do so when a resource file will solve your problem without any hassle.

Quote:

---

Originally Posted by jmsrickland

I am working on the method I stated earlier on how to put your sound file inside your VB source code.

If you still want to use this method then OK but I told you earlier that it is quite akward and kind of silly to do so when a resource file will solve your problem without any hassle.

---

Thanks for the assistance. No matter what the result will be, I just like to see it is done that way :)

I don't know how JM is getting on, but I've created an example of the 'append it to the .exe file' method.

You need a Form with the following controls:
Timer - Named: Timer1
CommandButtons - Names: cmdPut, cmdRead, and cmdPlay. Then Copy and Paste the code below into the Declarations Section of the Form

Code:

---

Option Explicit

Private Declare Function PlaySound Lib "winmm.dll" Alias "PlaySoundA" _
        (ByVal lpszName As Long, _
        ByVal hModule As Long, _
        ByVal dwFlags As Long) As Long
       
Private Const SND_ASYNC = &H1        '  play asynchronously
Private Const SND_MEMORY = &H4        '  lpszSoundName points to a memory file
Private Const SND_LOOP = &H8          '  loop the sound until next sndPlaySound

Private Const SIGNATURE As String = "SOUND_FILE_IMBEDDED"

Private bytSound() As Byte

Private Function GetEmbeddedSound() As Boolean
Dim bytName() As Byte
Dim intFile As Integer
Dim intLen As Integer
Dim lngPos As Long
Dim lngEOF As Long
Dim lngSLen As Long
Dim strName As String
Dim intI As Integer
intFile = FreeFile
'
' Open the .exe and position to eof
'
Open App.Path & "\" & App.EXEName & ".exe" For Binary Access Read As intFile
Seek intFile, LOF(intFile)
'
' Size the array to hold the signature
' Position the .exe to the start of the signature
' and read it
'
intLen = Len(SIGNATURE)
ReDim bytName(intLen - 1)
lngEOF = Seek(intFile)
lngPos = lngEOF - intLen + 1
Seek intFile, lngPos
Get #intFile, , bytName
For intI = 0 To UBound(bytName)
    strName = strName & Chr(bytName(intI))
Next intI
'
' If the signature is valid
' Position the .exe at the start of the length of the data
' read it, and use it to size an array to receive the data.
' Position to the start of the data, read it, and then close the .exe file
'
If strName = SIGNATURE Then
    lngPos = lngPos - 4
    Seek intFile, lngPos
    Get #intFile, , lngSLen
    ReDim bytSound(lngSLen - 1)
    lngPos = lngPos - UBound(bytSound)
    Seek intFile, lngPos - 1
    Get #intFile, , bytSound
    Close intFile
    GetEmbeddedSound = True
Else
    GetEmbeddedSound = False
End If
End Function

Private Function PutEmbeddedSound(strFile As String, strSound As String) As Long
'
' Function appends the contents of the file defined in strSound
' to the Program (.exe) file specified in strFile
'
' Format is:
' Sound file contents
' 4 byte Length of Sound Contents
' Signature
'
Dim bytName() As Byte
Dim intFile As Integer
Dim intSound As Integer
Dim intI As Integer
Dim lngEOF As Long
Dim lngSLen As Long
intFile = FreeFile
If Dir$(strFile) <> "" Then
    If Dir$(strSound) <> "" Then
        '
        ' Open the .exe and position it at EOF
        '
        Open strFile For Binary Access Write As intFile
        Seek intFile, LOF(intFile)
        '
        ' Read the Sound File into an array
        '
        intSound = FreeFile
        Open strSound For Binary Access Read As intSound
        ReDim bytSound(LOF(intSound) - 1)
        Get #intSound, , bytSound
        Close #intSound
        '
        ' Get our current position in
        ' the exe file and append the sound data to it
        '
        lngEOF = Seek(intFile)
        Seek intFile, lngEOF + 1
        Put #intFile, , bytSound
        lngSLen = UBound(bytSound) + 1
        lngEOF = Seek(intFile)
        '
        ' Now write the length of the sound data
        '
        Put #intFile, lngEOF, lngSLen
        '
        ' Now write the signature
        ' and close the .exe
        '
        ReDim bytName(Len(SIGNATURE) - 1)
        For intI = 0 To Len(SIGNATURE) - 1
            bytName(intI) = Asc(Mid$(SIGNATURE, intI + 1, 1))
        Next intI
        lngEOF = Seek(intFile)
        Put #intFile, lngEOF, bytName
        Close #1
        PutEmbeddedSound = 1
    Else
        PutEmbeddedSound = -1
    End If
Else
    PutEmbeddedSound = 0
End If
End Function

Private Sub cmdPlay_Click()
Dim lngReturn As Long
'
' Play the sound from the byte Array
' Start the duration timer
'
lngReturn = PlaySound(VarPtr(bytSound(0)), 0, SND_ASYNC Or SND_LOOP Or SND_MEMORY)
Timer1.Enabled = True
End Sub

Private Sub cmdPut_Click()
Dim lngResult As Long
Dim strExe As String
Dim strSound As String
strExe = App.Path & "\" & App.EXEName & ".exe"
strSound = App.Path & "\buzzer3_x.wav"
lngResult = PutEmbeddedSound(strExe, strSound)
Select Case lngResult
    Case 0
        MsgBox "File: " & strExe & " Not Found"
    Case -1
        MsgBox "File: " & strSound & " Not Found"
End Select
End Sub

Private Sub cmdRead_Click()
Dim boResult As Boolean
boResult = GetEmbeddedSound
If boResult = False Then
    MsgBox "This program does not have a valid Sound Embedded"
End If
End Sub

Private Sub Form_Load()
Timer1.Enabled = False
Timer1.Interval = 5000
End Sub

Private Sub Timer1_Timer()
Dim lngReturn As Long
'
' Stop playing the sound
' Disable the timer
'
lngReturn = PlaySound(0, 0, 0)
Timer1.Enabled = False
End Sub

---

Put the name of the .wav file in this statement to replace buzzer3_x.wav (making sure that the file you choose is in the App.Path Directory)

Code:

---

strSound = App.Path & "\buzzer3_x.wav"

---

Make the .exe. Then, run the program and press the cmdPut button. This will append the contents of the sound file to the .exe file. Then, either from the IDE or by running the .exe, click the cmdRead button, this will read the sound data embedded within the .exe into memory, then click on cmdPlay and the sound will be played continuously for 5 seconds.

The duration can be adjusted by modifying the Timer Interval and whether it runs synschonously or asychronously and repeats or not can be adjusted by changing the appropriate SND_ flags. (but don't remove SND_MEMORY).

Obviously you could make a separate program that, given a sound file and an exe file will append the contents of the sound file to the .exe, using the PutEmbeddedSound and supporting code, and just run that against the files you want, making sure that the necessary GetEmbeededSound and supporting code is already in the target program. With a few modifications you could embedd more than one sound file and other types of files if you wished to.

EDIT: Then, just out of interest, copy the .exe file to a machine that hasn't got VB6 installed run it, click on cmdRead, and then on cmdPlay and see what happens.

Wow, the code almost did it. But still the exe file has a dependence to the wav file. When i compiled it into exe and move it to another directory, it says "Run time error 70" Permission denied..

But the thing that make me suprised is that when i clicked "put" and then followed by "Read" then i deleted the Wav file before clicking on the play button.. It did it! The exe played with an embedded sound file (Wav)!

Maybe i should figure it out on how to do this without put and read first..
I mean the Play button will be the only executor of the sound playing in the exe.. Wow.. Thanks alot you're great!

Please note that adding a file to the end of the exe file may result in that some antivirus programs will report it as a virus.

Yes, as I mentoned in Post #31 by adding into a .exe, some anti virus programs will report a suspect file.

One of the reasons I put a 'signature' in there, was to enable the user to check, if SOUND_FILE_EMBEDDED appeared as the last characters of the .exe (opening the file with Notepad, for example). Another idea might be to actually put the old and new file sizes of the file as a signature, again, giving the user an opportunity to check.

I don't think there's any 'sure fire' method to persuade the end user that it's not a virus, if their virus scanner reports it as suspicious - I wouldn't be persuaded, unless I'd been pre-warned.

But, if it's for your own use then it doesn't really matter.

I don't understand the error 70, what did you do, exactly? Remember, you have to add the sound file before moving the .exe anywhere. Once it is added it is completely independent of the .wav file.

Thanks alot! I got it now. Couldn't do it without your help :D

I'll just simply set the 'read' button to 'invisible' and then in the Form_Load()
event, cmdRead_Click() :p

I don't know how JM is getting on, but I've created an example of the 'append it to the .exe file' method.

I will probably get it finished sometime today but I have been busy with other details at work. I think, however, that your method is probably better than what I am doing since what I am doing is putting the sound file as part of the VB scouce code so it will be compiled just like all the rest of the variables and stuff. It's not a true binary embedded file but rather the binary file converted to string data and then pasted into the source code as a string array of the sound bytes. But I pointed out earlier that this method is akward and rather silly to do, in my opinion, when the resource file method is so much better but if he is still interested then OK otherwise I may just put it on the self if what you did satisfies him.

vibien, please have a quick look at this. It uses a Res file but I'm under the impression that you don't actually understand what a Res file is. This code won't work in the IDE, compile and run the executable to hear the sound play. The sound is embedded inside the exe (not in another file somewhere else)

Quote:

---

Originally Posted by jmsrickland

[B]But I pointed out earlier that this method is akward and rather silly to do, in my opinion, when the resource file method is so much better but if he is still interested then OK otherwise I may just put it on the self if what you did satisfies him.

---

Sometimes we (I) learn doing 'silly' things. Keep going with what you are trying, you will learn a lot :D

I am having a little problem working out a suitable For Loop with my array of character bytes. Example: 1 Byte = "7A" = a 2 character string byte

The array is (1 to 152). Please don't ask me to change that

Each element of the array has 50 2-character bytes in it except for element #152 which has only 4 2-character bytes

So, 50 * 151 = 7550
plus 4 from element 152 = 7554 bytes

the sound file is exaclty 7554 bytes is size

I need a loop that pulls out each 2-character byte pair form the array and place them in another array which is pure binary so it will be 1-byte for every 2-character pair from the first array.

Here is my code but I am unable to get it to come out right. Everything works out just fine until I get to the point where I am only dealing with the final element of 4 bytes (element 152).

Code:

---

Private Sub cmdMakeByteArray_Click()
 Dim ByteString() As Byte
 Dim h As String
 
 '
 ' The value 152 is only for this particular sound file and will change
 ' when other sound files or any binary file is used to whatever their
 ' total bytes are divided by 50
 '
 ' 50 is just a number I picked to put in each element
 '
 ReDim BinArray(1 To 152) '<---- Must be as listed
 
 LoadArray '<----------- will load BinArray with 7554 2-character byte value as I stated above
 
 'Total number of bytes in sound file = 7554
 
 '
 ' Have no real idea if this is even needed
 '
 If UBound(BinArray) Mod BytesPerLine = 0 Then
  t = UBound(BinFile) \ BytesPerLine
  ReDim ByteString(1 To BytesPerLine * UBound(BinArray)) ' \ BytesPerLine)
 Else
  t = UBound(BinArray) \ BytesPerLine + 1
  ReDim ByteString(1 To BytesPerLine * UBound(BinArray) + t) ' \ BytesPerLine + t)
 End If
 
 k = 100 '<---number of bytes per element * 2 excep for last element
 
 For q = 1 To UBound(BinArray)
  For q1 = 1 To k Step 2
    j = j + 1
   
    ByteString(j) = CByte(Hex2Dec(CStr(Mid(BinArray(q), q1, 2))))
  Next q1
 
  '
  ' Here is where I'm not sure what to do
  '
  p = p + 1
  If p = UBound(BinArray) \ BytesPerLine Then
    k = t '<---- change the loop counter to 4
  End If
 
 Next q
 
 '
 ' Now output this as a new wave file so I can test it using WMP
 '
 Open App.Path & "\NEW_SOUND.WAV" For Binary As #1
 Put #1, 1, ByteString
 Close #1
End Sub

---

OK, never mind. I figured out a very simple solution for the For...Next loop

Quote:

---

Originally Posted by Doogle

Sometimes we (I) learn doing 'silly' things. Keep going with what you are trying, you will learn a lot :D

---

Yeah, I greatly agree with that! :bigyello:

Well, it will probably be in the morning as I am having a little problem playing the sound array within my program although it plays correctly using WMP for testing

Wow, big bunch of codes! I'll check these all :thumb: and inform you soon
thanks

Wow! I'm using Milk's code, and it goes GREAT and understandable! And moreover you made it pretty simple. Just like one i wishing for :D

Thank you so much. I appreciate your assistances :thumb:

It's not surprising that code I posted is shorter, I'm using a RES file to embed. JMS and Doogle are offering alternative embedding methods which invariably will be more complex.

I think what JMS is doing is quite interesting because the data can be stored within the code. I'm thinking of a portable class that requires some data to run, if all the data could be held in the code then it makes the class that bit easier to just drop into different projects.

Now like I said it's not the desirable way of doing it but for whatever it's worth here it is.

It comprises of two projects. One project reads in a binary file that you select from a dialog box and converts it to an array of text data and saves it on your hard drive.

The second project is what you use to play that text data.

After you run the first program it will make a text file which you will need to load into a text editor like Notepad and copy the contents to the ClipBoard.

Open up the second project and paste the code into the source code area according to the instructions and then click on the play button.

Here is the source code for the first project which makes the text file.

On a Form simply add a Command button.

Code:

---

Option Explicit
Const MAX_BYTES_PER_LINE = 50

Dim FileName As String

Dim BinArray() As String
Dim BinFile() As Byte
Dim ByteString() As Byte
Private Sub Command1_Click()
 Dim FilePath As String
 
 On Error GoTo ErrHandler

 CommonDialog1.InitDir = App.Path & "\"
 CommonDialog1.CancelError = True
 CommonDialog1.ShowOpen
 
 FilePath = CommonDialog1.FileName
 FileName = UCase(CommonDialog1.FileTitle)
 
 Open FilePath For Binary As #1
 ReDim BinFile(LOF(1) - 1)
 Get #1, 1, BinFile
 Close #1
 
 MakeTextArray
 Exit Sub
ErrHandler:
 MsgBox "No file selected"
End Sub
Private Sub MakeTextArray()
 Dim BYTEDATA As String
 
 Dim FileString As String
 Dim k As String
 
 Dim g As Integer, i As Integer, m As Integer, p As Integer, q As Integer
 
 FileString = ""

 k = ""
 m = 0
 i = 0
 
 If UBound(BinFile) Mod MAX_BYTES_PER_LINE = 0 Then
  ReDim BinArray(1 To UBound(BinFile) \ MAX_BYTES_PER_LINE)
 Else
  ReDim BinArray(1 To UBound(BinFile) \ MAX_BYTES_PER_LINE + 1)
 End If
 
 g = MAX_BYTES_PER_LINE
 
 For q = 0 To UBound(BinFile)
  k = k & Right("100" & Hex(UCase(BinFile(q))), 2)
 
  m = m + 1
 
  If m = g Then
    i = i + 1
   
    k = " BinArray(" & i & ") = " & Chr(34) & k & Chr(34)
   
    FileString = FileString & k & vbCrLf
   
    DoEvents
   
    p = p + 1
   
    If p = UBound(BinFile) \ MAX_BYTES_PER_LINE Then g = UBound(BinFile) - q
   
    m = 0
    k = ""
  End If
 Next q
 
 FileString = "" & FileString
 
 FileString = " '" & vbCrLf & _
              " ' Copy and Paste below into Sub LoadArray in you Application" & vbCrLf & _
              " '" & vbCrLf & FileString
 
 Open App.Path & UCase("\Binary_Text_Array_For_") & FileName & UCase(".txt") For Output As #1: Close #1
 
 Open App.Path & UCase("\Binary_Text_Array_For_") & FileName & UCase(".txt") For Binary As #1
 Put #1, 1, FileString
 Close #1
 
 MsgBox "Your binary text array file is now ready. You must load it into" & vbCrLf & _
        "into a text editor program (ex Notepad) and Copy and Past" & vbCrLf & _
        "the contents into the Sub LoadArray in your VB project" & vbCrLf & vbCrLf & _
        "The name of the file is:" & vbCrLf & vbCrLf & _
        UCase("Binary_Text_Array_For_") & FileName & UCase(".txt")
End Sub

---

Here is the code for the second project which plays the sound file
On a Form simply add a Command button

Code:

---

Private Declare Function PlaySound Lib "winmm.dll" Alias "PlaySoundA" _
 (ByRef lpszName As Any, _
  ByVal hModule As Long, _
  ByVal dwFlags As Long) As Long

Private Const SND_ASYNC = &H1
Private Const SND_MEMORY = &H4

'
' NOTE: This program is for VB Project Design Time Only
'
'      Do Not Compile this Project
'
Private Const MAX_BYTES_PER_LINE = 50

Dim BinArray() As String
Dim BinFile() As Byte
Dim ByteString() As Byte
Private Sub Command1_Click()
 MakeByteArray
 Play ByteString
End Sub
Private Sub MakeByteArray()
 Dim i As Integer
 Dim j As Integer
 Dim k As Integer
 
 If Not LoadArray Then Exit Sub
 
 k = 0
 
 ReDim ByteString(1 To MAX_BYTES_PER_LINE * (UBound(BinArray) - 1) + Len(BinArray(UBound(BinArray))) \ 2)
 
 For i = 1 To (UBound(BinArray))
  For j = 1 To Len(BinArray(i)) Step 2
    k = k + 1
   
    ByteString(k) = CByte(Hex2Dec(CStr(Mid(BinArray(i), j, 2))))
  Next j
 Next i
End Sub
Private Function Hex2Dec(InputData As String) As Double
 '
 '  Converts Hexadecimal to Decimal
 '
 Dim i As Integer
 Dim DecOut As Double
 Dim Lenhex As Integer
 Dim HexStep As Double

 '
 ' Zero the output
 '
 DecOut = 0

 '
 ' The length of the input
 '
 InputData = UCase(InputData)
 Lenhex = Len(InputData)

 '
 ' Check to make sure its a valid Hex Number
 '
 For i = 1 To Lenhex
  If IsNumeric(Mid(InputData, i, 1)) Then
    GoTo NumOk
  ElseIf Mid(InputData, i, 1) = "A" Then
    GoTo NumOk
  ElseIf Mid(InputData, i, 1) = "B" Then
    GoTo NumOk
  ElseIf Mid(InputData, i, 1) = "C" Then
    GoTo NumOk
  ElseIf Mid(InputData, i, 1) = "D" Then
    GoTo NumOk
  ElseIf Mid(InputData, i, 1) = "E" Then
    GoTo NumOk
  ElseIf Mid(InputData, i, 1) = "F" Then
    GoTo NumOk
  Else
    MsgBox "Number given is not in Hex format", vbCritical
    Exit Function
  End If
NumOk:
 Next i

 HexStep = 0

 '
 ' Convert the Number to Decimal
 '
 For i = Lenhex To 1 Step -1
  HexStep = HexStep * 16

  If HexStep = 0 Then
    HexStep = 1
  End If

  If Mid(InputData, i, 1) = "0" Then
    DecOut = DecOut + (0 * HexStep)
  ElseIf Mid(InputData, i, 1) = "1" Then
    DecOut = DecOut + (1 * HexStep)
  ElseIf Mid(InputData, i, 1) = "2" Then
    DecOut = DecOut + (2 * HexStep)
  ElseIf Mid(InputData, i, 1) = "3" Then
    DecOut = DecOut + (3 * HexStep)
  ElseIf Mid(InputData, i, 1) = "4" Then
    DecOut = DecOut + (4 * HexStep)
  ElseIf Mid(InputData, i, 1) = "5" Then
    DecOut = DecOut + (5 * HexStep)
  ElseIf Mid(InputData, i, 1) = "6" Then
    DecOut = DecOut + (6 * HexStep)
  ElseIf Mid(InputData, i, 1) = "7" Then
    DecOut = DecOut + (7 * HexStep)
  ElseIf Mid(InputData, i, 1) = "8" Then
    DecOut = DecOut + (8 * HexStep)
  ElseIf Mid(InputData, i, 1) = "9" Then
    DecOut = DecOut + (9 * HexStep)
  ElseIf Mid(InputData, i, 1) = "A" Then
    DecOut = DecOut + (10 * HexStep)
  ElseIf Mid(InputData, i, 1) = "B" Then
    DecOut = DecOut + (11 * HexStep)
  ElseIf Mid(InputData, i, 1) = "C" Then
    DecOut = DecOut + (12 * HexStep)
  ElseIf Mid(InputData, i, 1) = "D" Then
    DecOut = DecOut + (13 * HexStep)
  ElseIf Mid(InputData, i, 1) = "E" Then
    DecOut = DecOut + (14 * HexStep)
  ElseIf Mid(InputData, i, 1) = "F" Then
    DecOut = DecOut + (15 * HexStep)
  Else
    MsgBox "Error has occured", vbCritical
  End If
 Next i

 Hex2Dec = DecOut

eds:
End Function
Private Sub StopPlay()
 PlaySound "", ByVal 0&, SND_MEMORY
End Sub
Private Sub Play(WavSound() As Byte)
 On Error GoTo ErrHandler
 PlaySound WavSound(1), 0, SND_MEMORY Or SND_ASYNC
 Exit Sub
ErrHandler:
End Sub
Private Function LoadArray() As Boolean
 On Error Resume Next
 '
 ' NOTE: The second value must always be the total
 '      number of elements you pasted from the
 '      text file into this Function
 '
 ReDim BinArray(1 To nnn)
 
 If Err Then
  LoadArray = False
  MsgBox "The Array has not been added to your source code"
  Exit Function
 Else
  LoadArray = True
 End If
 '
 ' You must ReDim BinArray above after you have
 ' pasted the code from the text file below
 '
End Function

---

JMS: You may like to see another method to convert Hex to Decimal, using the &H operator:

Code:

---

Private Function HexToDecimal(strHex As String) As Long
Dim intI As Integer
Dim boInvalid As Boolean
If Len(strHex) <= 8 Then
    strHex = UCase(strHex)
    intI = 1
    Do
        Select Case Mid$(strHex, intI, 1)
            Case "0" To "9", "A" To "F"
                intI = intI + 1
            Case Else
                boInvalid = True
        End Select
    Loop Until intI > Len(strHex) Or boInvalid = True
    If boInvalid = False Then
        HexToDecimal = CLng("&H" & strHex)
    Else
        MsgBox "Invalid Hexadecimal Data: " & strHex, "HexToDecimal"
    End If
Else
    MsgBox "Hexadecimal String too Long (Max 8 characters): " & strHex, "HexToDecimal"
End If
End Function

---

Yeh, I didn't know how to do it so I got the code I used off the Internet and I simply took the first example I found so I'm sure there are many better ways to do it but I was only interested in getting anything that worked because I was only interested in the overall project and not wheather I got the best code to do anything as long as it worked.

Definitely though your code is far better and I will use it instead of what I had.