[RESOLVED] weird text question

Ok I have a richtextbox and I want a button that splices text together.

for example

<Hi>
1
<by>
2
</by>
</Hi>

<Hi>
once
<by>
twice
</by>
</Hi>

and I want it so when you press my command button you get
<Hi>
1
once
<by>
2
twice
</by>
</Hi>

I could just use a cut and past code but there might be differnent text in between and more or less of it. If your curios I'm making a coder. :thumb:

What's a coder?

I think You'll be wanting a loop, won't you?

Code:

---

While xChar <> EOF
    xChar = xChar + 1
    SelChar = Left((Right(RichTextbox1.Text,xChar),1)
    If IsNumeric(SelChar) Then
          Case Select "1" ...
          End Select
    End If
Loop Until EOF

---

That's semi-psuedo-code, but is that the kind of thing you want?

are you getting the data from an XML File?

Yes I am.

I tried to run that code and got this error
Compile error: Argument not opional and it highlights EOF

*Bump

any other ideas?

You will need to add reference to Microsoft XML, I used version 4.0

VB Code:

Option Explicit
 
Private Sub Form_Load()
Dim xmlDocA As New MSXML2.DOMDocument
Dim xmlDocB As New MSXML2.DOMDocument
Dim ndsA As IXMLDOMNodeList
Dim ndsB As IXMLDOMNodeList
Dim cnt As Long
 
   'xmlDocA.Load App.Path & "\srcA.xml"   'changed to rtb.LoadFile
   'xmlDocB.Load App.Path & "\srcB.xml"
   
   rtbA.LoadFile App.Path & "\srcA.xml"   'load xml text into richtextbox
   rtbB.LoadFile App.Path & "\srcB.xml"
   xmlDocA.loadXML rtbA.Text
   xmlDocB.loadXML rtbB.Text
   
   Call Recurse(xmlDocA, xmlDocB)   'recurse and update xmlDocA
   Debug.Print xmlDocA.xml  'or output to textfile with print statement
End Sub
 
 
 
Private Sub Recurse(ndA As IXMLDOMNode, ndB As IXMLDOMNode)
Dim cnt As Long
 
   If StrComp(ndA.nodeName, "#text", vbTextCompare) = 0 Then  'then update text
      ndA.nodeValue = Replace(ndA.nodeValue & ndB.nodeValue & "", vbLf & vbLf, vbLf)  'nodeValue have leading and trailing vbLf, hence use of replace()
   ElseIf ndA.hasChildNodes Then
      For cnt = 0 To ndA.childNodes.length - 1
         Call Recurse(ndA.childNodes(cnt), ndB.childNodes(cnt))
      Next
   End If
End Sub

Where do you get the control? I downloaded MSXML 4.0 SP2 Parser and SDK(msxml.msi) off microsoft and I cant find the control anywhere. :(

you can do this with clever use of the Split() function, theres no need for extra componants, I havent vb6 here so I can't give you the code but just a suggestion

Quote:

---

Originally Posted by LawnNinja

Where do you get the control? I downloaded MSXML 4.0 SP2 Parser and SDK(msxml.msi) off microsoft and I cant find the control anywhere. :(

---

theres no out of the ordinary control involved with the code above (that had just 2 richtextboxes on a form), i didnt say you'll add a component to the project for msxml... add the reference to msxml 4... click project (between view and format) in the ide menu then click references.

Ok I think I'm confused :ehh: Here is my project file. I want it so when you click my button at the bottem it takes the text from the top one and adds it to the second one in the way I said in Post #1. I used both code together was I only suposed to used 1? Also does anyone know about the split function? :thumb:

VB Code:

str1 = "<Hi>" & vbNewLine & "1" & vbNewLine & "<by>" & vbNewLine & "2" & vbNewLine & "</by>" & vbNewLine & "</Hi>"
 str2 = "<Hi>" & vbNewLine & "once" & vbNewLine & "<by>" & vbNewLine & "twice" & vbNewLine & "</by>" & vbNewLine & "</Hi>"
arr1 = split(str1, vbNewLine)
arr2 = split(str2, vbNewLine)
For i = 0 To UBound(arr1)
    If Not arr1(i) = arr2(i) Then arr1(i) = arr1(i) & vbNewLine & arr2(i)
Next
str1 = join(arr1, vbNewLine)
Debug.Print str1

returns
<Hi>
1
once
<by>
2
twice
</by>
</Hi>

Your confused about adding a reference? Here the project with the reference added... if it errors out on load then that means you don't have MSXML 4 in your references list.

Split works but you will pass up the chance to learn to use MSXML objects if you go that way.

I had the refence and you code worked just fine :) but I don't want the the text to appear in a dialog as it does. This is how I have my coder layed out. I have two forms. One is the main form and two is the secondary. I want it so when you press a command button in form2(Secondary) it takes the text from the richtextbox in form2
<Hi>
whatevers here
<by>
whatevers here
</by>
</Hi>

and does what your example does but adds the text to the existing richtextbox's text in form1..... Can this be done?

I was just trying to apply that code the way I wanted and found out something that poses a problem for my app :( As long as its text in the spot above called "whatevers here" it works fine Etc. Hi, By,........

But if you use something like this <building> and then </Bulding> inbetween in just gives you whats typed in rtb1 in a message box. Does anyone know how to fix this?

have a look at the sample i posted, it should do what you want, just replace str1 and str2 with your rich textboxes

There are only three steps in that algorithm, loading the data, recursion, and display. So you will obviously update code after the recursion. Change the MsgBox or Debug.Print Line to

rtbA.Text = xmlDocA.xml

EDIT westconn, this is xml, a line can contain several tags such as

<Hi>
1
<by>
2
</by></Hi>

... your algo assumes they are formatted similarly per line and fails if not similarly formatted even if the tags are ordered/nested properly...

@leinad31: Ya your code works perfect until you add something like <House> or </House> or anything with a < or a > between <Hi> and <by> or between <by> and </by> in either one of the xml soarce file and then it doesn't work and just displays whats in the first soarce file. :( Do you know how to fix this? ;)

@westconn1: I used your code in the example below to demostrate the kind of thing I want. The problem is the I want anything in between to show up and not just put that code in. Maybe I didn't apply it right, check it out ;)

Post what's the possible complete structure, or note the optional tags... the previous algorithm updated source A with B elements on the assumption that A and B have the same structure (by in hi and no other elements)... if the structure is variable, eg for <Hi> elements to be combined either A or B have additional tags such as <building> then we have to include additional processing to ensure that only Hi and By are combined.

:thumb: Heres some of the start of my coder. Check it out and see if you can help :)

I'll look into it later when I get home, I'm at a rental so there's no VB here.

And I need representative copies of the source xmls... does the zip above contain those? or does the project retrieve them from an online site? Otherwise the posts above are my only reference for the xml structure.

Ok... this makes a collection of the <Hi> elements then uses XPath, on value passed to selectsinglenode method's argument, to get the <by> child by element of each <Hi> element. I mentioned those in case you want to do additional research related to the code below.

VB Code:

Private Sub Command1_Click()
Dim xmlDocA As New MSXML2.DOMDocument
Dim xmlDocB As New MSXML2.DOMDocument
Dim ndsHiA As IXMLDOMNodeList
Dim ndsHiB As IXMLDOMNodeList
Dim ndA As IXMLDOMNode
Dim ndB As IXMLDOMNode
Dim cntHi As Long
 
'===========================================================
'temp implementation for loading text xml update accordingly
   'xmlDocA.loadXML Form1.RichTextBox1.Text
   'xmlDocB.loadXML Form1.RichTextBox1.Text
   xmlDocA.Load App.Path & "\srcA.xml"
   xmlDocB.Load App.Path & "\srcB.xml"
'===========================================================
 
   Set ndsHiA = xmlDocA.getElementsByTagName("Hi")
   Set ndsHiB = xmlDocB.getElementsByTagName("Hi")
   Do
      Set ndA = ndsHiA.Item(cntHi).selectSingleNode("text()")
      Set ndB = ndsHiB.Item(cntHi).selectSingleNode("text()")
      ndA.nodeValue = Replace(ndA.nodeValue & ndB.nodeValue, vbLf & vbLf, vbLf)
 
      'your currently at Hi so access path by/text()... think of it similar to folder/subfolders
      Set ndA = ndsHiA.Item(cntHi).selectSingleNode("by/text()")  
      Set ndB = ndsHiB.Item(cntHi).selectSingleNode("by/text()")
      ndA.nodeValue = Replace(ndA.nodeValue & ndB.nodeValue, vbLf & vbLf, vbLf)
 
      cntHi = cntHi + 1
   Loop While (cntHi < ndsHiA.length - 1 Or cntHi < ndsHiB.length - 1)
   
   Form1.RichTextBox1.Text = xmlDocA.xml 'or output to textfile with print statement
End Sub

Please note that only the text node of the <Hi> and <by> elements are merged... the richtextbox final output is the updated xml for source A, hence uses the xml structure of A... if there were child nodes in source B, such as <buildings>, they are left in source B and not transffered/merged with source A.

And lastly, your last project assigned the same xml (richtextbox.text) to xmlDocA and xmlDocB objects.

Ok, when I try to run that code with my program I get this error

Run-Time error '91' :object variable or with block variable not set

and highlight this code.

Code:

---

Set ndA = ndsHiA.Item(cntHi).selectSingleNode("text()")

---

Did you have this problem?

nope, did you update the loading part of the algorithm? That will only happen if xmlDocA was not loaded an xml source.

Thats odd, heres you code added to my program. See if it runs fine with you. :thumb:

O wait know I know what your saying :) The problem is I dont want to load the xml files I want it so you type it into the form2 richtextbox and then add it to the current code the method I said above. How do you make this code work in this fashion?

First off, get rid of the duplicate declarations/references in procedure level and module levels...

Since your passing the xml stream/string/source and not a path to an xml file then use loadxml method

xmlDocA.LoadXML Form1.RichTextBox1.Text

Do something similar for xmlDocB...

Ok, I did that an I still get the smae error.....I've attached my project file.
The error happens when I'm in form1 then I type

<Hi>
<1>
</1>
<by>
<2>
</2>
</by>
</Hi>

into the form1 richtextbox, then I go to form2 and type

<Hi>
<house>
</house>
<by>
<hill>
</hill>
</by>
</Hi>

into the form2 richtextbox. Then I click the commannd button in form2 (Add Code) and get this error. Do you know how to fix this?

I didn't put error handling cause I thought you would be passing valid xml's

<1>... tag name is erroneous... so you will have to rename that
text() node does not exist in childnodes if there's no text... just test if ndA Or ndB is Nothing

VB Code:

'blah blah lines
      Set ndA = ndsHiA.Item(cntHi).selectSingleNode("text()")
      Set ndB = ndsHiB.Item(cntHi).selectSingleNode("text()")
      If Not (ndA Is Nothing) And Not (ndB Is Nothing) Then
         ndA.nodeValue = Replace(ndA.nodeValue & ndB.nodeValue, vbLf & vbLf, vbLf)
      End If
 
      'your currently at Hi so access path by/text()... think of it similar to folder/subfolders
      Set ndA = ndsHiA.Item(cntHi).selectSingleNode("by/text()")
      Set ndB = ndsHiB.Item(cntHi).selectSingleNode("by/text()")
      If Not (ndA Is Nothing) And Not (ndB Is Nothing) Then
         ndA.nodeValue = Replace(ndA.nodeValue & ndB.nodeValue, vbLf & vbLf, vbLf)
      End If
 
'blah blah lines

Ok I replaced my current code with that one and it still gave me this error again.

Run-Time error '91' bject variable or with block variable not set

and highlight this code.

Code:

---

Set ndA = ndsHiA.Item(cntHi).selectSingleNode("text()")

---

Any ideas?

Did you remove/replace the invalid xml tags <1> and <2>? If the xml is invaliud then of course it won't be loaded into the domdocument. Try this instead

<Hi>
<a1>
</a1>
<by>
<b2>
</b2>
</by>
</Hi>

For your reference

http://www.w3schools.com/xml/xml_elements.asp

Look up element naming

I used that so its valid and all it did was take my form1 richtextbox and reorganize it like so.

Code:

---

<Hi>
        <a1>
        </a1>
        <by>
                <b2>
                </b2>
        </by>
</Hi>

---

when it was like this

Code:

---

<Hi>
<a1>
</a1>
<by>
<b2>
</b2>
</by>
</Hi>

---

I doesn't add my code form2 richtextbox though.
Maybe my code is invalid for the form2 richtextbox. Can you post some xml code that will splice in my program with the one you just posted ?

Quote:

---

Originally Posted by leinad31

Please note that only the text node of the <Hi> and <by> elements are merged... the richtextbox final output is the updated xml for source A, hence uses the xml structure of A... if there were child nodes in source B, such as <buildings>, they are left in source B and not transffered/merged with source A.

---

So what are you really trying to accomplish? We've been beating around the bush and making samples for cases which appear to be related to what you need but is not exactly what you needed.

So what exactly?

The code I wish to actual merge is,
<gauge> and <mouse> </mouse> and then </gauge>. Like so.

Code:

---

<Gauge>
<element>
</element>
<mouse>
<area>
</area>
</mouse>
</gauge>

---

I want it so from <gauge> to <mouse> all the text from the other form gets added inbetween its <gauge> to <mouse> and also between <mouse> and </mouse>. ;)

It already does that if you replace Hi with Gauge and by with mouse.

I changed it and typed

Code:

---

<Gauge>
<element>
</element>
<Mouse>
<area>
</area>
</Mouse>
</Gauge>

---

in the form1 richtextbox and...

Code:

---

<Gauge>
<element>
</element>
<Mouse>
<area>
</area>
</Mouse>
</Gauge>

---

in form2 richtextbox and I still got the error. I'v attached my current code

Sorry, what I meant is I typed the first section of code into form1 richtextbox and the second to form2 richtextbox and pressed the "add code" command button in form2 and it gave be the error. I'v changed Hi to Gauge and by to Mouse ??? Any ideas?

seems the xml object automatically indents the elements to show the nesting... similar to what happens when you view the xml source in a browser... using Replace() to remove the vbTab indents returns a non-indented source if that's what you want.

Here's the updated command click event

VB Code:

Private Sub Command1_Click()
Dim xmlDocA As New MSXML2.DOMDocument
Dim xmlDocB As New MSXML2.DOMDocument
Dim ndsHiA As IXMLDOMNodeList
Dim ndsHiB As IXMLDOMNodeList
Dim ndA As IXMLDOMNode
Dim ndB As IXMLDOMNode
Dim cntHi As Long
 
   xmlDocA.loadXML Replace(Form1.RichTextBox1.Text, vbCrLf, vbLf)
   xmlDocB.loadXML Replace(Form2.RichTextBox1.Text, vbCrLf, vbLf)
 
   If Len(xmlDocA.xml) = 0 Or Len(xmlDocB.xml) = 0 Then Exit Sub
   
   Set ndsHiA = xmlDocA.getElementsByTagName("Gauge")
   Set ndsHiB = xmlDocB.getElementsByTagName("Gauge")
   Do
      Set ndA = ndsHiA.Item(cntHi).selectSingleNode("text()")
      Set ndB = ndsHiB.Item(cntHi).selectSingleNode("text()")
      If Not (ndA Is Nothing) And Not (ndB Is Nothing) Then
         ndA.nodeValue = Replace(ndA.nodeValue & ndB.nodeValue, vbLf & vbLf, vbLf)
      End If
      
      'your currently at Hi so access path by/text()... think of it similar to folder/subfolders
      Set ndA = ndsHiA.Item(cntHi).selectSingleNode("Mouse/text()")
      Set ndB = ndsHiB.Item(cntHi).selectSingleNode("Mouse/text()")
      If Not (ndA Is Nothing) And Not (ndB Is Nothing) Then
         ndA.nodeValue = Replace(ndA.nodeValue & ndB.nodeValue, vbLf & vbLf, vbLf)
      End If
      
      cntHi = cntHi + 1
   Loop While (cntHi < ndsHiA.length - 1 Or cntHi < ndsHiB.length - 1)
 
   Form1.RichTextBox1.Text = Replace(xmlDocA.xml, vbTab, "")
End Sub

Now nothing seems to happen when I press add code ??? Did this happen with you?

We are obviously running into a language barrier here. Given:

Code:

---

<Hi>
1
<by>
2
</by>
</Hi>

---

My definition for text in <Hi> tag is "1"... and not "1<by>2</by>". And as I've repeatedly explained over and over again, the merging code above involves only the text in <Hi> and <by>, which was your requirement as indicated by post #1,

Now the last xml you used...

Code:

---

<Gauge>
<element>
</element>
<Mouse>
<area>
</area>
</Mouse>
</Gauge>

---

has no text whatsoever in any of the tags. So of course nothing happens. There's no text in Form1.richtextbox's <Gauge> tag and Form2.richtextbox' <Gauge> tag to merge... so it stays as <Gauge></Gauge> with no text.

So once again, what are you trying to accomplish? Are you trying to merge tags and not just text? Such as...

Code:

---

<Gauge>1
<element>2
</element>
<Mouse>3
<area>4
</area>
</Mouse>
</Gauge>

plus

<Gauge>A
<element>B
</element>
<Mouse>C
<area>D
</area>
</Mouse>
</Gauge>

equals

<Gauge>1A
<element>2
</element>
<element>B
</element>
<Mouse>3C
<area>4
</area>
<area>D
</area>
</Mouse>
</Gauge>

---

Is that what your after? And please make it clear this time.

I'm sorry I Havn't made it clear enough for you. ;) I will us your above post as an example to expalin it more clearly

Code:

---

<Gauge>
<element>
<position x="7" y="1">
</element>
<Mouse>
<Help id="baron">
</Mouse>
</Gauge>

plus

<Gauge>
<element>
</element>
<Mouse>
<area>
</area>
</Mouse>
</Gauge>

equals

<Gauge>
<element>
<position x="7" y="1">
</element>
<element>
</element>
<Mouse>
<Help id="baron">
<area>
</area>
</Mouse>
</Gauge>

---

What is being done here is that everything inbetween <Gauge> and <Mouse> is being added to what is between <Gauge> and <Mouse> on the second richtextbox. Between <Mouse> and </Mouse> this process is also done. Can this be done? If your confused as to what I want please post back. ;)

So <element> tags from both source A and B are combined?
Not the same with <Mouse>, it stays as one element per <Gauge>?
How about <Help> and <area>, are they treated like <element> wherein the tags from both sources are taken?

1st Question: Yes, everthing inbetween <Gauge> and <Mouse> on both soarces are combined.
2nd Question: No, The same thing happens inbetween <Mouse> and </Mouse>. Both soarces are combine in this area to.
3nd Question: Yes

Can what I said be done???

VB Code:

Private Sub Command1_Click()
Dim xmlDocA As New MSXML2.DOMDocument
Dim xmlDocB As New MSXML2.DOMDocument
Dim ndsA As IXMLDOMNodeList
Dim ndsB As IXMLDOMNodeList
Dim ndA As IXMLDOMNode
Dim ndB As IXMLDOMNode
 
Dim cnt As Long
Dim sGauge As String
Dim sMouse As String
Dim sSource() As String
 
   xmlDocA.loadXML Replace(Form1.RichTextBox1.Text, vbCrLf, vbLf)
   xmlDocB.loadXML Replace(Form2.RichTextBox1.Text, vbCrLf, vbLf)
   If Len(xmlDocA.xml) = 0 Or Len(xmlDocB.xml) = 0 Then Exit Sub
   
   Set ndsA = xmlDocA.getElementsByTagName("Gauge")
   Set ndsB = xmlDocB.getElementsByTagName("Gauge")
   If (ndsA Is Nothing) Or ndsB Is Nothing Then Exit Sub
   
   ReDim sSource(ndsA.length - 1)
   Do
      Set ndA = ndsA(cnt).selectSingleNode("Mouse")
      Set ndB = ndsB(cnt).selectSingleNode("Mouse")
      If Not (ndA Is Nothing) And Not (ndB Is Nothing) Then
         'combine two <Gauge> nodes, excluding <Mouse> nodes
         sGauge = Replace(Replace(ndsA(cnt).xml, vbTab, ""), Replace(ndA.xml, vbTab, ""), "")
         sGauge = sGauge & Replace(Replace(ndsB(cnt).xml, vbTab, ""), Replace(ndB.xml, vbTab, ""), "")
         sGauge = Replace(sGauge, "</Gauge><Gauge>", "")
         
         'combine two <Mouse> nodes
         sMouse = Replace(ndA.xml, vbTab, "") & Replace(ndB.xml, vbTab, "")
         sMouse = Replace(sMouse, "</Mouse><Mouse>", "")
         
         'append <Mouse> node by updating </Gauge>
         sGauge = Replace(sGauge, "</Gauge>", sMouse & vbCrLf & "</Gauge>")
         
         'clean up
         Do While InStr(1, sGauge, vbCrLf & vbCrLf) > 0
            sGauge = Replace(sGauge, vbCrLf & vbCrLf, vbCrLf)
         Loop
         Do While InStr(1, sGauge, vbLf & vbLf) > 0
            sGauge = Replace(sGauge, vbLf & vbLf, vbLf)
         Loop
         
         sSource(cnt) = sGauge
      End If
      cnt = cnt + 1
   Loop While cnt < ndsA.length And cnt < ndsB.length
   
   Form1.RichTextBox1.Text = Join(sSource, vbCrLf)
End Sub

Thanks works great!!! ;)