Expandable Props [RESOLVED]

Basically, (in my user control) I have a child class with properties and these will be expandable (like the Size property).
Now on the UC I have a second set of props which expose these props. would both sets of props need an ExpandableObjectConverter
or would the dummy UC props pass everything needed to the underlying class of expandable props?

Thanks

Edit: You can skip to post #36 since that is where the new part starts. :thumb:

You should only need to define the TypeConverter Once.

For example if you added a property of the type System.Drawing.Point to your user control (this is the same type as the Size Property). You dont need to do anything else because the TypeConverter was already made by M$ (System.Drawing.PointConverter)

--

Once a TypeConverter is defined you dont need to explicitly tell Visual Studio to use it.

Thanks, but would I pass a class from the dummy props defined in the UC to the converter or pass my
child class - gradientpanel? Also, these props are custom and not any default ones.

Ex.
DrawStyles
- GraphicsMode
- BrushType
- Color1
- Color2

So somewhere in your Control you got

VB Code:

Public Class DrawStylesConverter
      Inherits TypeConverter 
      '.....

and you got your DrawStyles Class

VB Code:

'This attribute links the TypeConverter to the DrawStyles type,
'After this is defined, the propertygrid will automatically use the 
'Custom TypeConverter
<TypeConverter(GetType(DrawStylesConverter))>
Public Class DrawStyles
   'ect

----

VB Code:

Public Class MyPanel
   ' ect...
   
   Private _MyDrawingStyles as DrawStyles
 
   Public Property DrawingStyles() as DrawStyles
       Get
          Return _MyDrawingStyles
       End Get
       Set(Value as DrawStyles)
           m_MyDrawStyles
       End Set
   End Property

VB Code:

Public Class MyUserControl
   'ect
 
   Public Property DrawingStyles() as DrawStyles
       Get
          Return MyPanelControlInstance.DrawingStyles
       End Get
       Set(Value as DrawStyles)
           MyPanelControlInstance.DrawingStyles = Value
       End Set
   End Property

should to the trick

Thanks, thats what I was hoping to hear. I'm working on it right now to see if I can get it going. :D

Ok, almost finished it but a question arises. My expandable properties have to be concatinated
in the DrawStyles property text field?

DrawStyles = Vertical; LinearGradient; Color.White; Color.Blue;

I wanted something generic in there but not sure what to put or how to keep
it readonly without making the entire property read only.

DrawStyles = ?
- DrawMode = Vertical
- BrushType = LinearGradient
- Color1 = Color.White
- Color2 = Color.Blue

etc.

I have everything in place but no expansion :(

My prop tree -

DrawStyles = LineraGradient; Color.White; Color.Blue
- DrawMode = LinearGradient
- Color1 = Color.White
- Color2 = Color.Blue

I am Inheriting in my class the ExpandableObjectConverter and added the attribute for TypeConverter. :(

VB Code:

<TypeConverter(GetType(GraphicsModeConverter))> _
Friend Class GradientPanel
 
    Public Property Blah, Blah, ...
 
End Class
 
Friend Class GraphicsModeConverter
 
    Inherits ExpandableObjectConverter
'...
'...

Here's an example of what I think you're trying to do, maybe you missed a step:

DrawStylesConverter:

VB Code:

Imports System.ComponentModel
Imports System.Globalization
 
' Expandable TypeConverter for the DrawStyles class
Public Class DrawStylesConverter
   Inherits ExpandableObjectConverter
 
   Private m_lastValue As DrawStyles = New DrawStyles
 
   Public Overloads Overrides Function CanConvertFrom(ByVal context As ITypeDescriptorContext, ByVal t As Type) As Boolean
      ' Indicate which types this class can convert "From"
      If t Is GetType(String) Then
         Return True
      End If
      Return MyBase.CanConvertFrom(context, t)
   End Function
 
   Public Overloads Overrides Function ConvertFrom(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object) As Object
      If value.GetType() Is GetType(String) Then
         Try
            ' Attempt to parse the string representation 
            ' into the constituent properties
            Dim ds As New DrawStyles
            Dim s As String = value
            Dim c As String
 
            Dim props As String() = s.Split(",".ToCharArray())
 
            ds.DrawMode = [Enum].Parse(GetType(DrawMode), Trim(props(0)))
            c = Trim(props(1))
            If Not IsNumeric(c) Then
               ds.Color1 = Color.FromKnownColor([Enum].Parse(GetType(KnownColor), c))
            Else
               ds.Color1 = Color.FromArgb(Convert.ToInt32(c))
            End If
            c = Trim(props(2))
            If Not IsNumeric(c) Then
               ds.Color2 = Color.FromKnownColor([Enum].Parse(GetType(KnownColor), c))
            Else
               ds.Color2 = Color.FromArgb(Convert.ToInt32(c))
            End If
 
            Return ds
 
         Catch ex As Exception
            ' Revert back to the last good value if an error is encountered
            ' trying to parse the entered "text" value for the constiuent properties
            Return m_lastValue
 
         End Try
      End If
      MyBase.ConvertFrom(context, culture, value)
   End Function
 
   Public Overloads Overrides Function CanConvertTo(ByVal context As ITypeDescriptorContext, ByVal t As Type) As Boolean
      ' Indicate which types this class can convert "To"
      If t Is GetType(DrawStyles) Then Return True
      Return MyBase.CanConvertTo(context, t)
   End Function
 
   Public Overloads Overrides Function ConvertTo(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object, ByVal destType As Type) As Object
      If destType Is GetType(String) Then
         ' Attempt to convert the value into a string representation
         Try
            Dim styles As DrawStyles = CType(value, DrawStyles)
            m_lastValue = styles
            Return String.Format("{0}, {1}, {2}", styles.DrawMode, styles.Color1.Name, styles.Color2.Name)
 
         Catch ex As Exception
            ' If there was an error, display it instead of the string value
            Return String.Format("Error: {0}", ex.Message)
 
         End Try
      End If
      Return MyBase.ConvertTo(context, culture, value, destType)
   End Function
End Class

DrawStyles:

VB Code:

Imports System.ComponentModel
 
'
' Draw Styles Class: Demonstates an expandable property
'
<TypeConverter(GetType(DrawStylesConverter))> _
Public Class DrawStyles
   Private _drawMode As DrawMode = DrawMode.Normal
   Private _color1 As Color = Color.Red
   Private _color2 As Color = Color.Blue
 
   ' Specify property defaults and indicate that the property grid should repait when
   ' this property value changes (to make sure the string representation is updated)
   <DefaultValue(GetType(DrawMode), "Normal"), RefreshProperties(RefreshProperties.Repaint)> _
   Public Property DrawMode() As DrawMode
      Get
         Return _drawMode
      End Get
      Set(ByVal Value As DrawMode)
         _drawMode = Value
      End Set
   End Property
 
   <DefaultValue(GetType(Color), "Red"), RefreshProperties(RefreshProperties.Repaint)> _
   Public Property Color1() As Color
      Get
         Return _color1
      End Get
      Set(ByVal Value As Color)
         _color1 = Value
      End Set
   End Property
 
   <DefaultValue(GetType(Color), "Blue"), RefreshProperties(RefreshProperties.Repaint)> _
   Public Property Color2() As Color
      Get
         Return _color2
      End Get
      Set(ByVal Value As Color)
         _color2 = Value
      End Set
   End Property
End Class

MyControl:

VB Code:

Imports System.ComponentModel
 
'
' Example control implementing a custom expandable property
'
Public Class MyControl
   Inherits System.Windows.Forms.UserControl
 
#Region " Windows Form Designer generated code "
 
   Public Sub New()
      MyBase.New()
 
      'This call is required by the Windows Form Designer.
      InitializeComponent()
 
      'Add any initialization after the InitializeComponent() call
 
   End Sub
 
   'UserControl overrides dispose to clean up the component list.
   Protected Overloads Overrides Sub Dispose(ByVal disposing As Boolean)
      If disposing Then
         If Not (components Is Nothing) Then
            components.Dispose()
         End If
      End If
      MyBase.Dispose(disposing)
   End Sub
 
   'Required by the Windows Form Designer
   Private components As System.ComponentModel.IContainer
 
   'NOTE: The following procedure is required by the Windows Form Designer
   'It can be modified using the Windows Form Designer.  
   'Do not modify it using the code editor.
   <System.Diagnostics.DebuggerStepThrough()> Private Sub InitializeComponent()
      components = New System.ComponentModel.Container
   End Sub
 
#End Region
 
   Private _drawStyle As New DrawStyles
 
   ' Indicate this property should appear in the property grid and that
   ' Code should be generate for the child properties of this property and
   ' not the property itself.
   <Browsable(True), DesignerSerializationVisibility(DesignerSerializationVisibility.Content)> _
   Public Property DrawStyle() As DrawStyles
      Get
         Return _drawStyle
      End Get
      Set(ByVal Value As DrawStyles)
         _drawStyle = Value
      End Set
   End Property
 
   ' Implement separate "ShouldSerialize" and "Reset" methods because of the 
   ' Complex nature of the expandable property type
   Private Function ShouldSerializeDrawStyle() As Boolean
      ' Return True to indicate the value is not default and should be persisted
      Return Not (_drawStyle.DrawMode = DrawMode.Normal AndAlso _drawStyle.Color1.Equals(Color.Red) AndAlso _drawStyle.Color2.Equals(Color.Blue))
   End Function
 
   Private Sub ResetDrawStyle()
      ' Reset the property to a default value
      _drawStyle = New DrawStyles
   End Sub
End Class

I think you got what I was trying to do exactly. I had all three properties on the control and in the child class.
Then I had the child class' converting the props to make them expandable.

Your demo looks great! Give me a few minutes to incorporate it into my uc for testing.

Thanks :thumb:

I am getting an error because of an Option Strict issue...

VB Code:

ds.DrawStyle = [Enum].Parse(GetType(DrawMode), Trim(props(0))) '<--ERROR
    c = Trim(props(1))
    If Not IsNumeric(c) Then
        ds.PanelColor1 = Color.FromKnownColor([Enum].Parse(GetType(KnownColor), c)) '<---ERROR
    Else
        ds.PanelColor1 = Color.FromArgb(Convert.ToInt32(c))
    End If
    c = Trim(props(2))
    If Not IsNumeric(c) Then
        ds.PanelColor2 = Color.FromKnownColor([Enum].Parse(GetType(KnownColor), c)) '<---ERROR
    Else
        ds.PanelColor2 = Color.FromArgb(Convert.ToInt32(c))
    End If

If I take the Option Strict Off then it works (see bottom of message) but I would like
to get it converted correctly so I can leave it on.

I guess I mixed something up. It expands correctly finally but its attached to
my gradientpanel class which the properties are in.
So I get all the properties of a panel object and my two panelcolor1 and 2 props.

Cant I just have the assignment of the props and not have to use the class?
My issues are in the DrawStyles class (actually GradientPanel class). :(

This should fix your Option Strict Problems

VB Code:

Public Overloads Overrides Function ConvertFrom(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object) As Object
        If value.GetType() Is GetType(String) Then
            Try
                ' Attempt to parse the string representation 
                ' into the constituent properties
                Dim ds As New DrawStyles
                Dim s As String = [B]CType(value, String)[/B]
                Dim c As String
 
                Dim props As String() = s.Split(",".ToCharArray())
 
                ds.DrawMode = [b]CType([Enum].Parse(GetType(DrawMode), Trim(props(0))), DrawMode)[/b]
                c = Trim(props(1))
                If Not IsNumeric(c) Then
                    ds.Color1 = Color.FromKnownColor([B]CType([Enum].Parse(GetType(KnownColor), c), KnownColor)[/b])
                Else
                    ds.Color1 = Color.FromArgb(Convert.ToInt32(c))
                End If
                c = Trim(props(2))
                If Not IsNumeric(c) Then
                    ds.Color2 = Color.FromKnownColor([b]CType([Enum].Parse(GetType(KnownColor), c), KnownColor)[/b])
                Else
                    ds.Color2 = Color.FromArgb(Convert.ToInt32(c))
                End If
 
                Return ds
 
            Catch ex As Exception
                ' Revert back to the last good value if an error is encountered
                ' trying to parse the entered "text" value for the constiuent properties
                Return m_lastValue
 
            End Try
        End If
        MyBase.ConvertFrom(context, culture, value)
    End Function

Quote:

---

Cant I just have the assignment of the props and not have to use the class?
My issues are in the DrawStyles class (actually GradientPanel class).

---

I would think that you would need to create a DrawStyles Class with just the properties you want exposed and have that as a property of GradiendPanel.

You mean that the whole drawstyles class would be a property of the gradientpanel?

I think part of the problem is the both DrawStyles and DrawMode areReserved enumerations and they are conflicting
with my property. Guess a naming change is in order.

Getting allot closer, but I still cant get this line to convert correctly.

VB Code:

gs.GradientMode = [Enum].Parse(GetType(GradientStyle), Trim(props(0)))

When I wrap it with the CType it tells me that the GradientStyle is undefined?

VB Code:

gs.GradientMode = CType([Enum].Parse(GetType(GradientStyle), Trim(props(0))), GradientStyle)

What am I doing wrong?

Duh! I figured out! I needed to ctype it to a lineargradientmode and not a class.

VB Code:

gs.GradientMode = CType([Enum].Parse(GetType(GradientStyle), Trim(props(0))), LinearGradientMode)

Now I have two issues left.

1. Defaults are not Resetting to the correct values. I have the default attributes on each of the
   three properties but when I reset them it goes to Horizontal, 0, 0 and not ForwardDiagonal, White, Blue.
   
   Do I need to supply something different as a default since the prop is expandable?
   
   
   
2. The gradient panel is not respondin at all to the property changes. :(

Ok, now I get some kind of hex number for RGB colors? :mad:

"ForwardDiagonal, ff7ba2e7, ff6375d6"

I am trying to get the Reset right click context menu to function at the DrawStyles level just like it does
for the Font property. The Font property lets you reset all the child properties at the top level with one
click.

I have the GradientMode, PanelColor1, and PanelColor2 all with the DefaultValues attrib, so I dont know
what else to do to fix it?

VB Code:

Public Overloads Overrides Function ConvertTo(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object, ByVal destType As Type) As Object
      If destType Is GetType(String) Then
         ' Attempt to convert the value into a string representation
         Try
            Dim styles As DrawStyles = CType(value, DrawStyles)
            m_lastValue = styles
            [b]Return String.Format("{0}, {1}, {2}", styles.DrawMode, styles.Color1.Name, styles.Color2.Name)[/b]
 
         Catch ex As Exception
            ' If there was an error, display it instead of the string value
            Return String.Format("Error: {0}", ex.Message)
 
         End Try
      End If
      Return MyBase.ConvertTo(context, culture, value, destType)
   End Function
End Class

The problem with the colors displaying as hex should be on the bold line.

-----
Default values:

VB Code:

Public Overloads Overrides Function ConvertFrom(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object) As Object
      If value.GetType() Is GetType(String) Then
         [b]If IsNothing(Value) OrElse DirectCast(Value,String).Text.Length = 0 Then
                 Dim x as New DrawStyles
 
                 x.DrawMode = Vertical
                 x.Color1 = Color.White
                 x.Color2 = Color.Blue
               
                 Return x
         End If[/b]
         Try
            ' Attempt to parse the string representation 
            ' into the constituent properties
            Dim ds As New DrawStyles
            Dim s As String = value
            Dim c As String
 
            Dim props As String() = s.Split(",".ToCharArray())
 
            ds.DrawMode = [Enum].Parse(GetType(DrawMode), Trim(props(0)))
            c = Trim(props(1))
            If Not IsNumeric(c) Then
               ds.Color1 = Color.FromKnownColor([Enum].Parse(GetType(KnownColor), c))
            Else
               ds.Color1 = Color.FromArgb(Convert.ToInt32(c))
            End If
            c = Trim(props(2))
            If Not IsNumeric(c) Then
               ds.Color2 = Color.FromKnownColor([Enum].Parse(GetType(KnownColor), c))
            Else
               ds.Color2 = Color.FromArgb(Convert.ToInt32(c))
            End If
 
            Return ds
 
         Catch ex As Exception
            ' Revert back to the last good value if an error is encountered
            ' trying to parse the entered "text" value for the constiuent properties
            Return m_lastValue
 
         End Try
      End If
      MyBase.ConvertFrom(context, culture, value)
   End Function

I think that should do the trick

On ConvertFrom procedure I get an error stating that Text is not a member of string

VB Code:

If IsNothing(value) OrElse DirectCast(value, String).Text.Length = 0 Then
 
'Would this be the same thing?
If IsNothing(value) OrElse DirectCast(value, String).ToString.Length = 0 Then

Thanks

I spaced...

VB Code:

If IsNothing(value) OrElse DirectCast(value, String).Length = 0 Then

for some reason I was thinking it was a textbox :confused:

Cool getting even closer. But the top level prop only reset if I delete the concatinated string, but then it
reset correctly. When I reset the top level prop it resets to horizontal, 0, 0 and not my custom defaults I
added to each of the three child props. Do I need to add the defaults to the top level mailn prop too? Idf so
then how since you cant have more then one?

To properly implement the reset you'll need to add the ShouldSerialize and Reset methods for the expandable class, see my example for details.

I have everything from your example, but only the child properties reset properly.

This is what I have in my user control main class. Do I need to put a default on this one fall all?

VB Code:

<Browsable(True), DesignerSerializationVisibility(DesignerSerializationVisibility.Content), _
        Category("MyPanel")> _
        Public Property DrawStyle() As GradientStyle
            Get
                Return _GradientStyle
            End Get
            Set(ByVal Value As GradientStyle)
                _GradientStyle = Value
                MyBase.Refresh()
            End Set
        End Property
 
        Private Function ShouldSerializeDrawStyle() As Boolean
            ' Return True to indicate the value is not default and should be persisted
            Return Not (_GradientStyle.GradientMode = LinearGradientMode.ForwardDiagonal AndAlso _GradientStyle.PanelColor1.Equals(Color.FromArgb(255, 200, 0)) AndAlso _GradientStyle.PanelColor2.Equals(Color.FromArgb(88, 88, 88)))
        End Function
 
        Private Sub ResetDrawStyle()
            ' Reset the property to a default value
            _GradientStyle = New GradientStyle
        End Sub

Ok, still getting the hex values for rgb color values. Wouldnt the Else condition be what I need to fix?

VB Code:

'ConvertFrom procedure...
 
If Not IsNumeric(c) Then
    gs.PanelColor1 = Color.FromKnownColor(CType([Enum].Parse(GetType(KnownColor), c), KnownColor))
Else
    gs.PanelColor1 = Color.FromArgb(Convert.ToInt32(c)) 'Is this changing it to a hex number?
End If

VB Code:

Color.FromArgb(Convert.ToInt32(c))

Returns a Color not a Integer, so I dont thin that would be the problem.


-----

Heres what I think is happening

VB Code:

Public Overloads Overrides Function ConvertTo(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object, ByVal destType As Type) As Object
      If destType Is GetType(String) Then
         ' Attempt to convert the value into a string representation
         Try
            Dim styles As DrawStyles = CType(value, DrawStyles)
            m_lastValue = styles
            [b]Return String.Format("{0}, {1}, {2}", styles.DrawMode, styles.Color1.Name, styles.Color2.Name)[/b]
 
         Catch ex As Exception
            ' If there was an error, display it instead of the string value
            Return String.Format("Error: {0}", ex.Message)
 
         End Try
      End If
      Return MyBase.ConvertTo(context, culture, value, destType)
   End Function
End Class

I think the problem is that when sytles.Color2 was assigned by Color.FromArgb(....) the integer does not represent a "KnownColor" so it can't name the color therefore it returns the hex value of the color.

Ok, I think I see what you mean. If its a RGB color there is no known color so the name will fail so it
stays as an hex value. So how do I fix that? Something like testing it for a known color name and if it
doesnt match then change it to a rgb value. How?

So when I take the .Name property off I get this for the top level parent property.

VB Code:

DrawStyle | Horizontal, Color [A=255, R=255, G=128, B=128], Color [A=255, R=128, G=255, B=128]

So how do I go about converting it to be like:

VB Code:

DrawStyle | Horizontal, 255, 128, 128,  128, 255, 128

*BUMP*

I just need to first get the color rgb conversion solved in the ConvertTo and ConvertFrom procedures.
Then I will work on the panel painting correclty issue.


Any help is appreciated.

VB Code:

Option Strict On
Option Explicit On 
 
Public Class ARGBColor
 
#Region " Member Variables "
    Private _Red As Byte
    Private _Blue As Byte
    Private _Green As Byte
    Private _Alpha As Byte
#End Region
 
#Region " Properties "
    Public Property Red() As Byte
        Get
            Return _Red
        End Get
        Set(ByVal Value As Byte)
            _Red = Value
        End Set
    End Property
    Public Property Blue() As Byte
        Get
            Return _Blue
        End Get
        Set(ByVal Value As Byte)
            _Blue = Value
        End Set
    End Property
    Public Property Green() As Byte
        Get
            Return _Green
        End Get
        Set(ByVal Value As Byte)
            _Green = Value
        End Set
    End Property
    Public Property Alpha() As Byte
        Get
            Return _Alpha
        End Get
        Set(ByVal Value As Byte)
            _Alpha = Value
        End Set
    End Property
#End Region
 
#Region " Constructors "
    Public Sub New()
    End Sub
 
    Public Sub New(ByVal ARGBColor As Integer)
        Dim bytValue() As Byte = BitConverter.GetBytes(ARGBColor)
 
        _Red = bytValue(0)
        _Blue = bytValue(1)
        _Green = bytValue(2)
        _Alpha = bytValue(3)
    End Sub
 
    Public Sub New(ByVal Red As Byte, ByVal Blue As Byte, ByVal Green As Byte, ByVal Alpha As Byte)
        _Red = Red
        _Blue = Blue
        _Green = Green
        _Alpha = Alpha
    End Sub
#End Region
 
#Region " ConvertTo Methods "
 
    Public Function ToColor() As System.Drawing.Color
        Return System.Drawing.Color.FromArgb(ToInteger)
    End Function
 
    Public Function ToInteger() As Integer
        Return BitConverter.ToInt32(New Byte() {_Red, _Blue, _Green, _Alpha}, 0)
    End Function
 
    Public Overrides Function ToString() As String
        Return String.Format("R={0}, B={2}, G={1}, A={3}", Red, Blue, Green, Alpha)
    End Function
 
#End Region
 
#Region " ConvertFrom Methods "
 
    Public Shared Function FromColor(ByVal Color As System.Drawing.Color) As ARGBColor
        Return FromInteger(Color.ToArgb)
    End Function
 
    Public Shared Function FromInteger(ByVal Color As Integer) As ARGBColor
        Dim bytColor() As Byte = BitConverter.GetBytes(Color)
 
        Dim x As New ARGBColor(bytColor(0), bytColor(1), bytColor(2), bytColor(3))
 
        Return x
 
    End Function
 
#End Region
 
End Class

This class should help you easily convert from color to A/RGB

I would suggest testing using this :

VB Code:

Public Shared Function IsKnownColor(ByVal Color As System.Drawing.Color) As Boolean
        Return [Enum].IsDefined(GetType(System.Drawing.KnownColor), Color.Name)
    End Function

If IsKnownColor is True Then Use the Color.Name property
If IsKnownColor is False Then use ARGBColor.FromColor(Color).ToString ' or apply custom formatting

If the property is already a Color type, then you don't need to bother converting the ARGB value into it's components, instead you can access them via the R, G, B properties, here's an example using the DrawingStyles sample I posted previously:

VB Code:

Imports System.ComponentModel
Imports System.Globalization
 
' Expandable TypeConverter for the DrawStyles class
Public Class DrawStylesConverter
   Inherits ExpandableObjectConverter
 
   Private m_lastValue As DrawStyles = New DrawStyles
 
   Public Overloads Overrides Function CanConvertFrom(ByVal context As ITypeDescriptorContext, ByVal t As Type) As Boolean
      ' Indicate which types this class can convert "From"
      If t Is GetType(String) Then
         Return True
      End If
      Return MyBase.CanConvertFrom(context, t)
   End Function
 
   Public Overloads Overrides Function ConvertFrom(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object) As Object
      If value.GetType() Is GetType(String) Then
         Try
            ' Attempt to parse the string representation 
            ' into the constituent properties
            Dim ds As New DrawStyles
            Dim s As String = value
            Dim c As String
            Dim i As Integer
 
            Dim props As String() = s.Split(",".ToCharArray())
 
            ds.DrawMode = [Enum].Parse(GetType(DrawMode), Trim(props(0)))
            c = Trim(props(1))
            If Not IsNumeric(c) Then
               ds.Color1 = Color.FromKnownColor([Enum].Parse(GetType(KnownColor), c))
               i = 2
            Else
               ds.Color1 = Color.FromArgb(Convert.ToInt32(c), Convert.ToInt32(Trim(props(2))), Convert.ToInt32(Trim(props(3))))
               i = 4
            End If
            c = Trim(props(i))
            If Not IsNumeric(c) Then
               ds.Color2 = Color.FromKnownColor([Enum].Parse(GetType(KnownColor), c))
            Else
               ds.Color2 = Color.FromArgb(Convert.ToInt32(c), Convert.ToInt32(Trim(props(i + 1))), Convert.ToInt32(Trim(props(i + 2))))
            End If
 
            Return ds
 
         Catch ex As Exception
            ' Revert back to the last good value if an error is encountered
            ' trying to parse the entered "text" value for the constiuent properties
            Return m_lastValue
 
         End Try
      End If
      MyBase.ConvertFrom(context, culture, value)
   End Function
 
   Public Overloads Overrides Function CanConvertTo(ByVal context As ITypeDescriptorContext, ByVal t As Type) As Boolean
      ' Indicate which types this class can convert "To"
      If t Is GetType(DrawStyles) Then Return True
      Return MyBase.CanConvertTo(context, t)
   End Function
 
   Public Overloads Overrides Function ConvertTo(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object, ByVal destType As Type) As Object
      If destType Is GetType(String) Then
         ' Attempt to convert the value into a string representation
         Try
            Dim styles As DrawStyles = CType(value, DrawStyles)
            m_lastValue = styles
            Return String.Format("{0}, {1}, {2}", styles.DrawMode, ColorToString(styles.Color1), ColorToString(styles.Color2))
 
         Catch ex As Exception
            ' If there was an error, display it instead of the string value
            Return String.Format("Error: {0}", ex.Message)
 
         End Try
      End If
      Return MyBase.ConvertTo(context, culture, value, destType)
   End Function
 
   Private Function ColorToString(ByVal theColor As Color)
      ' Converts a Color into an appropriately formatted string
      ' For Known Colors the name is returned, otherwise the RGB value is returned
      ' in the format "R, G, B"
      If Not [Enum].IsDefined(GetType(KnownColor), theColor.Name) Then
         Return String.Format("{0}, {1}, {2}", theColor.R, theColor.G, theColor.B)
      Else
         Return theColor.Name
      End If
   End Function
End Class

This formats an unknow color in the format; "<R>, <G>, <B>" and returns the Name of a Known Color.

One thing to note; a possible drawback of formatting the RGB value with comma's is that you're using comma's as a sub-property delimiter, so it makes the parsing a little trickier and may not be as readable to the user.

Ok, so far I got Aarons code working but its not working when you type the drawstyle or known colors
into the parent property: DrawStyles :(

Is there something else I need to do to get the typed text like "Horizontal, Red, Green" accepted in the top property?

Also, the reset at the parent property level resets the props to Horizontal, 0, 0, 0, 0, 0, 0.

Thanks

The code as I've posted works fine when entering the text equivelent of the sub property values into the parent property field.

Maybe it's something in the way you've altered it to fit your control?

Can you post the code for the Convertor as it appears in your control?

As for the reset, that's handled by the ShouldSerialize and Reset supporting methods of the property in the Control.

If you'd rather not post the code here, I'd be happy to take a look at it outside the forums.

Regards,

- Aaron.

Ok, I can post this part since it parallels yours and is not specific. Here is the expandable prop class.
Its part of a namespace that I am importing into my UC class. Not too
sure if that makes a difference?
Also, I changed the name of the class to GradientStyle instead of DrawStyle

VB Code:

'...
    '...
    '...
    End Class
 
    ' Expandable TypeConverter for the DrawStyles class
    Public Class GradientStyleConverter
 
        Inherits ExpandableObjectConverter
 
        Private m_lastValue As GradientStyle = New GradientStyle
 
        Public Overloads Overrides Function CanConvertFrom(ByVal context As ITypeDescriptorContext, ByVal t As Type) As Boolean
            ' Indicate which types this class can convert "From"
            If t Is GetType(String) Then
                Return True
            End If
            Return MyBase.CanConvertFrom(context, t)
        End Function
 
        Public Overloads Overrides Function ConvertFrom(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object) As Object
            If value.GetType() Is GetType(String) Then
                Try
                    ' Attempt to parse the string representation 
                    ' into the constituent properties
                    Dim gs As New GradientStyle
                    Dim s As String = CType(value, String)
                    Dim c As String
                    Dim i As Integer
                    Dim props As String() = s.Split(",".ToCharArray())
                    gs.GradientMode = CType([Enum].Parse(GetType(GradientStyle), Trim(props(0))), LinearGradientMode)
                    c = Trim(props(1))
                    If Not IsNumeric(c) Then
                        gs.PanelColor1 = Color.FromKnownColor(CType([Enum].Parse(GetType(KnownColor), c), KnownColor))
                        i = 2
                    Else
                        gs.PanelColor1 = Color.FromArgb(Convert.ToInt32(c), Convert.ToInt32(Trim(props(2))), Convert.ToInt32(Trim(props(3))))
                        i = 4
                    End If
                    c = Trim(props(i))
                    If Not IsNumeric(c) Then
                        gs.PanelColor2 = Color.FromKnownColor(CType([Enum].Parse(GetType(KnownColor), c), KnownColor))
                    Else
                        gs.PanelColor2 = Color.FromArgb(Convert.ToInt32(c), Convert.ToInt32(Trim(props(i + 1))), Convert.ToInt32(Trim(props(i + 2))))
                    End If
                    Return gs
 
                Catch ex As Exception
                    ' Revert back to the last good value if an error is encountered
                    ' trying to parse the entered "text" value for the constiuent properties
                    Return m_lastValue
                End Try
            End If
            MyBase.ConvertFrom(context, culture, value)
        End Function
 
        Public Overloads Overrides Function CanConvertTo(ByVal context As ITypeDescriptorContext, ByVal t As Type) As Boolean
            ' Indicate which types this class can convert "To"
            If t Is GetType(GradientStyle) Then Return True
            Return MyBase.CanConvertTo(context, t)
        End Function
 
        Public Overloads Overrides Function ConvertTo(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object, ByVal destType As Type) As Object
            If destType Is GetType(String) Then
                ' Attempt to convert the value into a string representation
                Try
                    Dim styles As GradientStyle = CType(value, GradientStyle)
                    m_lastValue = styles
                    Return String.Format("{0}, {1}, {2}", styles.GradientMode, ColorToString(styles.PanelColor1), ColorToString(styles.PanelColor2))
                Catch ex As Exception
                    ' If there was an error, display it instead of the string value
                    Return String.Format("Error: {0}", ex.Message)
                End Try
            End If
            Return MyBase.ConvertTo(context, culture, value, destType)
        End Function
 
        Private Function ColorToString(ByVal theColor As Color) As String
            ' Converts a Color into an appropriately formatted string
            ' For Known Colors the name is returned, otherwise the RGB value is returned
            ' in the format "R, G, B"
            If Not [Enum].IsDefined(GetType(KnownColor), theColor.Name) Then
                Return String.Format("{0}, {1}, {2}", theColor.R, theColor.G, theColor.B)
            Else
                Return theColor.Name
            End If
        End Function
 
    End Class
 
End Namespace

I think the code is good and the issue is perhaps in either the GradientPanel or UC classes.

Thanks

The problem lies in the ConvertFrom method where you're assigning the GradientMode.
The Enumeration is being passed the Gradient class type instead of the LinearGradientMode Enumeration type.

This:

VB Code:

gs.GradientMode = CType([Enum].Parse(GetType(GradientStyle), Trim(props(0))), LinearGradientMode)

Should Be This:

VB Code:

gs.GradientMode = CType([Enum].Parse(GetType(LinearGradientMode), Trim(props(0))), LinearGradientMode)

Regards,

- Aaron.

w00t, w00t! Success :thumb: You saved the day yet again. Thanks a million!

Now since I had taken a break from this project its time to move on to the next issue. :rolleyes:


For some reason (probably someting that I missed again) the panel does not change graphics when the properties
are changed.

With the regular properties I had this working. Now that the expandable props are in place I need to hook
the actual drawing back up. I think it may be because there may be different instances of classes being created?

Thanks

Took a while to track down, but it looks like you need to implement a few more methods in the ExpandableObjectConverter,
in particular the CreateInstance method, which seems to be called whenever the sub-properties are changed,
triggering a change in the Expandable proeprty which can be intercepted and reacted to.

You'll need to tweak this a little, I didn't recognize the LinearGradientMode enum,
so I mocked up my own.

VB Code:

Imports System.ComponentModel
Imports System.Globalization
 
' Expandable TypeConverter for the DrawStyles class
Public Class GradientStyleConverter
 
   Inherits ExpandableObjectConverter
 
   Private m_lastValue As GradientStyle = New GradientStyle
 
   Public Overloads Overrides Function CanConvertFrom(ByVal context As ITypeDescriptorContext, ByVal t As Type) As Boolean
      ' Indicate which types this class can convert "From"
      If t Is GetType(String) Then
         Return True
      End If
      Return MyBase.CanConvertFrom(context, t)
   End Function
 
   Public Overloads Overrides Function ConvertFrom(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object) As Object
      If value.GetType() Is GetType(String) Then
         Try
            ' Attempt to parse the string representation 
            ' into the constituent properties
            Dim gs As New GradientStyle
            Dim s As String = CType(value, String)
            Dim c As String
            Dim i As Integer
            Dim props As String() = s.Split(",".ToCharArray())
            gs.GradientMode = CType([Enum].Parse(GetType(LinearGradientMode), Trim(props(0))), LinearGradientMode)
            c = Trim(props(1))
            If Not IsNumeric(c) Then
               gs.PanelColor1 = Color.FromKnownColor(CType([Enum].Parse(GetType(KnownColor), c), KnownColor))
               i = 2
            Else
               gs.PanelColor1 = Color.FromArgb(Convert.ToInt32(c), Convert.ToInt32(Trim(props(2))), Convert.ToInt32(Trim(props(3))))
               i = 4
            End If
            c = Trim(props(i))
            If Not IsNumeric(c) Then
               gs.PanelColor2 = Color.FromKnownColor(CType([Enum].Parse(GetType(KnownColor), c), KnownColor))
            Else
               gs.PanelColor2 = Color.FromArgb(Convert.ToInt32(c), Convert.ToInt32(Trim(props(i + 1))), Convert.ToInt32(Trim(props(i + 2))))
            End If
            Return gs
 
         Catch ex As Exception
            ' Revert back to the last good value if an error is encountered
            ' trying to parse the entered "text" value for the constiuent properties
            Return m_lastValue
         End Try
      End If
      MyBase.ConvertFrom(context, culture, value)
   End Function
 
   Public Overloads Overrides Function CanConvertTo(ByVal context As ITypeDescriptorContext, ByVal t As Type) As Boolean
      ' Indicate which types this class can convert "To"
      If t Is GetType(GradientStyle) Then Return True
      Return MyBase.CanConvertTo(context, t)
   End Function
 
   Public Overloads Overrides Function ConvertTo(ByVal context As ITypeDescriptorContext, ByVal culture As CultureInfo, ByVal value As Object, ByVal destType As Type) As Object
      If destType Is GetType(String) Then
         ' Attempt to convert the value into a string representation
         Try
            Dim styles As GradientStyle = CType(value, GradientStyle)
            m_lastValue = styles
            Return String.Format("{0}, {1}, {2}", styles.GradientMode, ColorToString(styles.PanelColor1), ColorToString(styles.PanelColor2))
         Catch ex As Exception
            ' If there was an error, display it instead of the string value
            Return String.Format("Error: {0}", ex.Message)
         End Try
      End If
      Return MyBase.ConvertTo(context, culture, value, destType)
   End Function
 
   Public Overloads Overrides Function GetPropertiesSupported(ByVal context As ITypeDescriptorContext) As Boolean
      ' Indicate the we support returning a list 
      ' of the properties this type contains
      Return True
   End Function
 
   Public Overloads Overrides Function GetProperties(ByVal context As ITypeDescriptorContext, ByVal value As Object, ByVal attributes As Attribute()) As PropertyDescriptorCollection
      ' Return a collection of the Properties that make up this type
      Dim collection As PropertyDescriptorCollection = TypeDescriptor.GetProperties(GetType(GradientStyle), attributes)
      Dim props As String() = New String() {"GradientMode", "PanelColor1", "PanelColor2"}
      Return collection.Sort(props)
   End Function
 
   Public Overloads Overrides Function GetCreateInstanceSupported(ByVal context As System.ComponentModel.ITypeDescriptorContext) As Boolean
      ' Indicate that creating an instance is supported
      Return True
   End Function
 
   Public Overloads Overrides Function CreateInstance(ByVal context As System.ComponentModel.ITypeDescriptorContext, ByVal propertyValues As System.Collections.IDictionary) As Object
      ' Create a new instance of the Gradient Style 
      ' with the supplied property values
      Dim obj1 As Object = propertyValues("GradientMode")
      Dim obj2 As Object = propertyValues("PanelColor1")
      Dim obj3 As Object = propertyValues("PanelColor2")
 
      If obj1 Is Nothing Then obj1 = LinearGradientMode.Mode1
      If obj2 Is Nothing Then obj1 = Color.Red
      If obj3 Is Nothing Then obj1 = Color.Blue
 
      Dim gs As New GradientStyle
      gs.GradientMode = obj1
      gs.PanelColor1 = obj2
      gs.PanelColor2 = obj3
 
      Return gs
   End Function
 
   Private Function ColorToString(ByVal theColor As Color) As String
      ' Converts a Color into an appropriately formatted string
      ' For Known Colors the name is returned, otherwise the RGB value is returned
      ' in the format "R, G, B"
      If Not [Enum].IsDefined(GetType(KnownColor), theColor.Name) Then
         Return String.Format("{0}, {1}, {2}", theColor.R, theColor.G, theColor.B)
      Else
         Return theColor.Name
      End If
   End Function
End Class

Then you should just need to make a call to Invalidate or whatever you call to repaint your control, i.e.

VB Code:

<Browsable(True), _
    DesignerSerializationVisibility(DesignerSerializationVisibility.Content)> _
   Public Property GradientStyle() As GradientStyle
      Get
         Return _gradientStyle
      End Get
      Set(ByVal Value As GradientStyle)
         _gradientStyle = Value
         Me.Invalidate()
      End Set
   End Property

Regards,

- Aaron.

Ok, I think I am following you but for some reason I dont have anything available in my props.
No MyBase.Refresh, MyBase.Invalidate, MyBase.Update, Me.Refresh, Me.Invalidate, Me.Update.

Also, why do some of the procedures do nothing other then Return True?

If you're control is inheriting from UserControl or Control it
should have an Invalidate method which triggers a Paint event.

Either way, it doesn't matter, you must have something in your control
that gets called when you want it to draw itself, if so, then that's what you want
to call in the Set of the expandable property in your control.

Those methods that just return True are called by the IDE to see if your
class supports certain things, like supplying a list of the sub-properties and
creating instances of your class.

Regards,

- Aaron.

Edit: Re-reading your post makes me think that maybe you thought the Invalidate call would be in the converter class, it's not,
it's in your UserControl when you expose the property of type GradientStyle. - Aaron.

Ok, I think I found whats wrong.

I have these three classes in one class file wrapped by a namespace and this namespace is being imported into the user control base.

The first class is the one (GradientPanel) that is inheriting the panel control and is where I am overridding the OnPaint event
to draw the gradient.

The second one (GradientStyle) is the one that has the 3 properties (DrawMode, PanelColor1, and PanelColor2). This one has the typeconverter (GradientStyleConverter) atribute.

The third one (GradientStyleConverter) is the one that inherits the ExpandableObjectConverter.


I think the first and second classes need to be in the same class and not separate?

Having them in separate class files or not should make no difference (they're all separate in mine.)

So in the GradientPanel class you have the GradientStyle property and it's in the
Set portion of that property where you want to call Invalidate to have the Panel redraw
itself when you change one of the component properties of GradientStyle.

Not quite. The GradientPanel class (inherits Panel) just has the OnPaint override and thats all. Then in the GradientStyle class I
have the expandable properties. shouldnt the 3 props be in the GradientPanel? Basically, the GradientPanel &
GradientStyle classes should be merged in order to get the MyBase or Me for invalidating?

I think we're getting crossed-wires here somewhere.

If GradientPanel is going to have a property called GradientStyle
which is of the type GradientStyle, then it will have a Get and Set accessor,
that's where you call the Invalidate, not in either the GradientStyle or GradientStyleConverter classes.

Here's a mock up of what your GradientPanel control would look like:

VB Code:

Imports System.ComponentModel
 
Public Class MyControl
   Inherits Panel
 
   Private _gradientStyle As New GradientStyle
 
   ' This is the property your control exposes that uses the 
   ' Expandable class type and converter
   <Browsable(True), _
    DesignerSerializationVisibility(DesignerSerializationVisibility.Content)> _
   Public Property GradientStyle() As GradientStyle
      Get
         Return _gradientStyle
      End Get
      Set(ByVal Value As GradientStyle)
         _gradientStyle = Value
         ' Need to call Invalidate Here to cause your
         ' control to redraw itself when the expandable
         ' properties change
         Me.Invalidate()
      End Set
   End Property
 
   ' Implement separate "ShouldSerialize" and "Reset" methods because of the 
   ' Complex nature of the expandable property type
   Private Function ShouldSerializeGradientStyle() As Boolean
      ' Return True to indicate the value is not default and should be persisted
      Return Not (_gradientStyle.GradientMode = LinearGradientMode.Mode1 AndAlso _gradientStyle.PanelColor1.Equals(Color.Red) AndAlso _gradientStyle.PanelColor2.Equals(Color.Blue))
   End Function
 
   Private Sub ResetGradientStyle()
      ' Reset the property to a default value
      _gradientStyle = New GradientStyle
   End Sub
 
   Protected Overrides Sub OnPaint(ByVal e As System.Windows.Forms.PaintEventArgs)
      ' This is where you use your control settings to redraw your control
      MyBase.OnPaint(e)
      Select Case _gradientStyle.GradientMode
         Case LinearGradientMode.Mode1
            e.Graphics.FillRectangle(Brushes.Red, New Rectangle(New Point(0, 0), Me.Size))
 
         Case LinearGradientMode.Mode2
            e.Graphics.FillRectangle(Brushes.Green, New Rectangle(New Point(0, 0), Me.Size))
 
         Case LinearGradientMode.Mode3
            e.Graphics.FillRectangle(Brushes.Blue, New Rectangle(New Point(0, 0), Me.Size))
 
      End Select
   End Sub
End Class

Regards,

- Aaron.

Thats what I thought it should be like. Instead I had two of the classes split. so thats why I dont have the me or
mybase when setting the props?

I am going to make the necessary mods and it will probably take a while since I dont want to mess it up and
loose what I have got so far. Its usually a pain to rollback source safe unless I do it to a new directory.

Thanks for all your help. I will post back when I finish the changes :thumb:

Ok, I got the CreateInstance procedure updated so I thought I would post it. I had to do a few mods since I am
using Option Strict and Explicit ON.

VB Code:

Public Overloads Overrides Function CreateInstance(ByVal context As System.ComponentModel.ITypeDescriptorContext, _
ByVal propertyValues As System.Collections.IDictionary) As Object
    ' Create a new instance of the Gradient Style 
    ' with the supplied property values
    Dim obj1 As Object = propertyValues("GradientMode")
    Dim obj2 As Object = propertyValues("PanelColor1")
    Dim obj3 As Object = propertyValues("PanelColor2")
 
    If obj1 Is Nothing Then obj1 = LinearGradientMode.ForwardDiagonal
    If obj2 Is Nothing Then obj2 = Color.Red
    If obj3 Is Nothing Then obj3 = Color.Blue
 
    Dim gs As New GradientStyle
    gs.GradientMode = CType(obj1, LinearGradientMode)
    gs.PanelColor1 = CType(obj2, Color)
    gs.PanelColor2 = CType(obj3, Color)
 
    Return gs
 
End Function

I'm "still" working on the modifications to merge the two classes together.
Hopefully this will be done real soon. :)

Aaron, you are a true Guru!!!

Thanks for solving the Reset issue and drawing issue!

I am implementing the changes tonight and can hopefully move forward "finally"!!!


Many Thanks,
Robert

Hey,

Very quick first post to thank you for this ridiculously helpful post - after 2 days of trawling the web, this solved my problem in a couple of hours (and it would have been even quicker if I'd read the whole post, rather than trying to second guess what was coming...).

Thanks again, and VBForums is my new favourite forum!
Dave.