Post Race!

Yep, that must be some experience

hey

night simon

evening all, back once again :)

hi

Night everyone, I need sleep badly

night keddie!

welcome ian into the bordom hole...

I'm not off yet, as said in msnmsnger

I said, why don't you suck my balls, Mr Garrison?!

i'll take her off your hands ked ;)

No way Simon!

you bastard!! ;)

present them!

nah nah :D them? :confused:

i dont think keddie has any to present, why dont you present your two to us :D:D ;)

I'm back, after a day of rebooting and updating :mad:

http://www.vbforums.com/attachment.php?s=&postid=492802

Our whole company was hit! He he.

I had the Sircam virus in today :(

Morning All, I haven't had any virus's yet.... what should I look out for?

Afternoon Chris and everyone else, no virus's on this comp yet, although i had one on my portable once.

I am proud to say I've never had a PC virus :)

I got a couple on my Acorn though - sorted that out pretty well although it's virus defs are a bit out of date (1997 :D)

I've had the Kak Worm before, entire network got screwed over. However it is a serious script kiddy job ad was emoved very easily. Other than that, nothign has infected us, but I've had this SirCam crap sent to me by some unknowing mates...

Quote:

---

Originally posted by parksie
I am proud to say I've never had a PC virus :)

---

I've gotten them but Norton Anti-Virus caught them. :)

Good morning, gentlemen. I need some one to calm me down after reading the "Wife" thread. Anyone have any suggestions?:( :mad:

Not sure I'll be able to calm you down, unfortunately ;)

Here ya go, Katie: http://www.vbforums.com/showthread.p...pagenumber=211 :D

Damn clipboard, here, Katie: http://www.vbforums.com/attachment.php?s=&postid=345901

unfortunately i forgot the magic word for this kind of situation :p

How about "hey lovely, how ya doing?" :)

Oh come on. Just cause some guy thinks something...you dont have to get all mad. I mean if all the Jewish people cared what Kovan said... think of what would happen....;)

No I think "I got a suprise for you" would be more effective

I don't think it would surprise her, she's used to them being that big :p

AAAAAAARRRRRRRRRRRGGGGGGGGGGHHHHHH

Bad day, Ian????? Me too!

I wonder if one of you would mind doing me a favor.........

In the General VB Section there is a post titled "E-mail Extraction". The system that has access to the internet does not have any software loaded and we aren't supposed to download but we need some code downloaded for us. If someone would download the code and post it in the thread it would help a lot!

Thanks!

Uhh theres a LOT of code. But if you want it all...heres the Form code:

VB Code:

Private SessionClosed As Boolean
Private SettingsChanged As Boolean
Private MailItem() As tMailItem
Private FatalError As Boolean
 
'Variables and constant for testing data returned from server
Private OutText As String
Private ResponseState As String
Private ThisChunk As String
Private WholeThing As String
Private DotLine As String
Const EOM As String = vbCrLf & "." & vbCrLf
 
'Mode constants for WaitFor
Const STATUS = 1
Const DOT = 2
Const CLOSED = 4
 
Private Sub chkPersistPW_Click()
        
    SettingsChanged = True
    cmdSave.Enabled = True
    
End Sub
 
Private Sub cmdConnect_Click()
 
'Initialize
    lstHeaders.Clear
    txtOutput = ""
    txtStatus = ""
    txtFrom = ""
    txtDate = ""
    txtBytes = ""
    ReDim MailItem(0)
    FatalError = False
    
    cmdSave.Enabled = False
    
    SessionClosed = False
    If GetID = False Then
        Exit Sub
    End If
    If SettingsChanged Then
        GetINI
    End If
    
    If InitiateSession = False Then
        Exit Sub
    End If
    
    If GetHeaders = False Then
        Exit Sub
    End If
    
    lstHeaders.Enabled = True
    
End Sub
 
Private Sub cmdDC_Click()
 
    Send "QUIT"
 
    WaitFor CLOSED, OutText
    If OutText <> "+OK" Then
        If MsgBox("Attempt to close connection anyway?", vbYesNo + vbExclamation, "QUIT failure!") = vbNo Then
            Exit Sub
        End If
    End If
    
    tcpIn.Close
    WaitFor STATUS, OutText
    cmdDC.Enabled = False
    cmdConnect.Enabled = True
    cmdDelete.Enabled = False
    cmdRset.Enabled = False
    lstHeaders.Enabled = False
 
End Sub
 
Private Sub cmdDelete_Click()
    
    Send "DELE " & (lstHeaders.ListIndex + 1)
 
    WaitFor STATUS, OutText
    If OutText <> "+OK" Then
        cmdDC_Click
        txtStatus = txtStatus & "***POPManager: DELE failure!"
        Exit Sub
    End If
 
    cmdDelete.Enabled = False
    cmdRset.Enabled = True
    
    MailItem(lstHeaders.ListIndex + 1).Deleted = True
 
End Sub
 
Private Sub cmdRset_Click()
 
    Send "RSET"
    
    WaitFor STATUS, OutText
    If OutText <> "+OK" Then
        cmdDC_Click
        txtStatus = txtStatus & "***POPManager: RSET failure!"
        Exit Sub
    End If
    
    For c = 1 To UBound(MailItem)
        MailItem(c).Deleted = False
    Next
    
    cmdDelete.Enabled = True
    cmdRset.Enabled = False
    
End Sub
 
Private Sub cmdSave_Click()
 
    cmdSave.Enabled = False
    PutINI
    
End Sub
 
Private Sub Form_Initialize()
 
    GetINI
 
End Sub
 
Private Sub Form_Load()
 
    fraHolder(0).ZOrder
    
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
 
    If cmdDC.Enabled Then
        cmdDC_Click
    End If
    
End Sub
 
Private Sub lstHeaders_Click()
 
    If MailItem(lstHeaders.ListIndex + 1).Deleted Then
        cmdDelete.Enabled = False
    Else
        cmdDelete.Enabled = True
    End If
    
    txtFrom = MailItem(lstHeaders.ListIndex + 1).From
    txtDate = MailItem(lstHeaders.ListIndex + 1).DateSent
    txtBytes = MailItem(lstHeaders.ListIndex + 1).Bytes
    If MailItem(lstHeaders.ListIndex + 1).Loaded Then
        GetBody lstHeaders.ListIndex + 1
    Else
        txtOutput = ""
    End If
 
End Sub
 
Private Sub lstHeaders_DblClick()
 
    GetBody lstHeaders.ListIndex + 1
    
End Sub
 
Private Sub tabOutput_Click()
 
    fraHolder(tabOutput.SelectedItem.Index - 1).ZOrder
    
    If tabOutput.SelectedItem.Index = 3 Then
        txtServer.SetFocus  'Start with first field
        If txtPW = "" Then  'or first empty
            txtPW.SetFocus
        End If
        If txtID = "" Then
            txtID.SetFocus
        End If
        If txtServer = "" Then
            txtServer.SetFocus
        End If
    End If
 
End Sub
 
Private Sub tcpIn_Close()
    
    SessionClosed = True
    
End Sub
 
Private Sub tcpIn_DataArrival(ByVal bytesTotal As Long)
 
    Dim strData As String
    tcpIn.GetData strData, vbString
    WholeThing = WholeThing + strData
    ThisChunk = strData                 'For testing content
    ResponseState = Left$(WholeThing, 3)   'For +OK and +ER tests
    DotLine = Right$(WholeThing, 5)        'For EOM tests
 
End Sub
 
Private Sub tcpIn_Error(ByVal Number As Integer, Description As String, ByVal Scode As Long, ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As Long, CancelDisplay As Boolean)
 
    txtStatus = txtStatus & "***POPManager: TCP/IP Error " & Number & ": " & Description
    FatalError = True
   
End Sub
 
Private Sub Send(TextOut As String)
 
    ClearTests
    
    tcpIn.SendData TextOut & vbCrLf
    
End Sub
 
Private Sub ClearTests()
    
    ResponseState = ""
    ThisChunk = ""
    WholeThing = ""
    DotLine = ""
 
End Sub
 
Private Sub WaitFor(Mode As Byte, TestFor As String)
 
    Do
        Select Case Mode
            Case STATUS
                If ResponseState = "+OK" Or ResponseState = "-ER" Then
                    txtStatus.Text = txtStatus.Text & ThisChunk 'show status
                    TestFor = ResponseState
                    Exit Do
                End If
            Case DOT
                If ResponseState = "-ER" Then  'if got here by mistake
                    txtStatus.Text = txtStatus.Text & ThisChunk 'show status
                    TestFor = ResponseState
                    Exit Do
                End If
                If DotLine = EOM Then
                    Exit Do
                End If
            Case CLOSED
                If SessionClosed Then
                    TestFor = "+OK"
                    Exit Do
                End If
        End Select
        If FatalError Then
            tcpIn.Close
            cmdConnect.Enabled = True
            Exit Sub
        End If
        DoEvents
    Loop
 
End Sub
 
Private Function GetID()
 
    GetID = True
    GetINI
    
    While modPOPMgr.InfoOk = False
        tabOutput.Tabs.Item(3).Selected = True
        tabOutput_Click
        If modPOPMgr.InfoOk = False Then
            GetID = False
            Exit Function
        End If
    Wend
 
End Function
 
Private Function InitiateSession() As Boolean
 
InitiateSession = True
 
    cmdConnect.Enabled = False
    ClearTests
    On Error Resume Next
    tcpIn.Connect modPOPMgr.POPServer, 110
    If Err Then
        FatalError = True
        Err = 0
        Exit Function
    End If
    On Error GoTo 0
    WaitFor STATUS, OutText
    If FatalError Then
        InitiateSession = False
        Exit Function
    End If
    If OutText = "+OK" Then
        Send "USER " & modPOPMgr.ID
    Else
        txtStatus = txtStatus + "POPManager: Login failure!"
        cmdDC_Click
        InitiateSession = False
        Exit Function
    End If
 
    WaitFor STATUS, OutText
    If OutText = "+OK" Then
        Send "PASS " & modPOPMgr.PW
    Else
        txtStatus = txtStatus + "POPManager: Login failure!"
        InitiateSession = False
        cmdDC_Click
        Exit Function
    End If
 
    WaitFor STATUS, OutText
    If OutText = "+OK" Then
        cmdDC.Enabled = True
    Else
        InitiateSession = False
        cmdDC_Click
        txtStatus = txtStatus & "***POPManager: Login failure!"
'        MsgBox "Login failure!"
        Exit Function
    End If
    
End Function
 
Private Function GetHeaders() As Boolean
 
Dim Messages As Long
Dim Start As Long
Dim Finish As Long
 
GetHeaders = True
 
'Get number of messages on server
 
    Send "STAT"
 
    WaitFor STATUS, OutText
    If OutText <> "+OK" Then
        GetHeaders = False
        cmdDC_Click
        MsgBox "STAT failure!"
        Exit Function
    End If
 
'   Parse returned string
    Start = InStr(WholeThing, " ") + 1
    Finish = InStr(Start, WholeThing, " ")
    Messages = Val(Mid$(WholeThing, Start, Finish - Start))
    
    If Messages = 0 Then    'bail out if none
        GetHeaders = False
        cmdDC_Click         'disconnect
        Exit Function
    End If
    
'Get size and headers for each message
    Dim c As Long   'Message counter
    
    For c = 1 To Messages
        ReDim Preserve MailItem(c)
'       Get info for a message
        Send "TOP " & c & " 1"
    
        WaitFor DOT, OutText
 
'       Parse out headers
        Start = InStr(UCase$(WholeThing), "+OK ") + 4
        Finish = InStr(Start, WholeThing, " ")
        MailItem(c).Bytes = Val(Mid$(WholeThing, Start, Finish - Start))
 
        Start = InStr(LCase$(WholeThing), "from:") + 5
        Finish = InStr(Start, WholeThing, vbCrLf)
        MailItem(c).From = Mid$(WholeThing, Start, Finish - Start)
        
        Start = InStr(LCase$(WholeThing), "subject:") + 8
        Finish = InStr(Start, WholeThing, vbCrLf)
        MailItem(c).Subject = Mid$(WholeThing, Start, Finish - Start)
 
        Start = InStr(LCase$(WholeThing), "date:") + 5
        Finish = InStr(Start, WholeThing, vbCrLf)
        MailItem(c).DateSent = Mid$(WholeThing, Start, Finish - Start)
        
        lstHeaders.AddItem MailItem(c).Subject
    Next
 
    lstHeaders.ListIndex = 0
 
End Function
 
Private Sub GetBody(BodyNum As Long)
 
'Get message body if needed
 
    If MailItem(BodyNum).Loaded Then
        txtOutput = MailItem(BodyNum).Body
    Else
        Send "RETR " & BodyNum
        WaitFor DOT, OutText
        MailItem(BodyNum).Body = WholeThing
        txtOutput = MailItem(BodyNum).Body
        MailItem(BodyNum).Loaded = True
    End If
 
End Sub

Form code (continued):

VB Code:

Sub PutINI()
 
    modPOPMgr.POPServer = Trim$(txtServer)
    modPOPMgr.ID = Trim$(txtID)
    modPOPMgr.PW = txtPW    'don't trim PW
    modPOPMgr.PersistPW = chkPersistPW
 
    SaveSetting "POPMgr", "User", "ID", modPOPMgr.ID
    SaveSetting "POPMgr", "User", "PersistPW", modPOPMgr.PersistPW
    If modPOPMgr.PersistPW Then
        SaveSetting "POPMgr", "User", "PW", modPOPMgr.PW
    Else
'        SaveSetting "POPMgr", "User", "PW", ""  'Flush it
'        modPOPMgr.PW = ""
'        txtPW = ""
    End If
    SaveSetting "POPMgr", "Server", "Address", modPOPMgr.POPServer
    SettingsChanged = False
 
End Sub
 
Sub GetINI()
 
    modPOPMgr.ID = GetSetting("POPMgr", "User", "ID", "")
    modPOPMgr.PersistPW = Val(GetSetting("POPMgr", "User", "PersistPW", "0"))
    If modPOPMgr.PersistPW Then
        modPOPMgr.PW = GetSetting("POPMgr", "User", "PW", "")
    Else
        modPOPMgr.PW = txtPW
    End If
    modPOPMgr.POPServer = GetSetting("POPMgr", "Server", "Address", "")
    
    If modPOPMgr.ID > "" And modPOPMgr.PW > "" And modPOPMgr.POPServer > "" Then
        modPOPMgr.InfoOk = True
    Else
        modPOPMgr.InfoOk = False
    End If
    
    txtServer = modPOPMgr.POPServer
    txtID = modPOPMgr.ID
    txtPW = modPOPMgr.PW
    chkPersistPW = modPOPMgr.PersistPW
    cmdSave.Enabled = False  'to counter checkbox click event
 
End Sub
 
Private Sub txtID_Change()
    
    SettingsChanged = True
    cmdSave.Enabled = True
 
End Sub
 
Private Sub txtPW_Change()
    
    SettingsChanged = True
    cmdSave.Enabled = True
 
End Sub
 
Private Sub txtServer_Change()
    
    SettingsChanged = True
    cmdSave.Enabled = True
 
End Sub

More is coming...and ill post a screen shot of the form so you can reconstruct it.

Module Code:

VB Code:

Private strPOPServer As String
Private strID As String
Private strPW As String
Private blnInfoOk As Boolean
Private btPersistPW As Byte
 
Type tMailItem
    From As String
    Subject As String
    DateSent As String
    Bytes As Long
    Body As String
    Loaded As Boolean
    Deleted As Boolean
End Type
 
Public Property Get POPServer() As String
 
    POPServer = strPOPServer
    
End Property
 
Public Property Let POPServer(ByVal strNewValue As String)
 
    strPOPServer = strNewValue
    
End Property
 
Public Property Get ID() As String
 
    ID = strID
    
End Property
 
Public Property Let ID(ByVal strNewValue As String)
    
    strID = strNewValue
 
End Property
 
Public Property Get PW() As String
 
    PW = strPW
 
End Property
 
Public Property Let PW(ByVal strNewValue As String)
 
    strPW = strNewValue
 
End Property
 
Public Property Get InfoOk() As Boolean
 
    InfoOk = blnInfoOk
 
End Property
 
Public Property Let InfoOk(ByVal blnNewValue As Boolean)
 
    blnInfoOk = blnNewValue
 
End Property
 
Public Property Get PersistPW() As Byte
 
    PersistPW = btPersistPW
 
End Property
 
Public Property Let PersistPW(ByVal btNewValue As Byte)
 
    btPersistPW = btNewValue
 
End Property

Screenshot coming....

Afternoon all. I thought that I would just say hello. :)

Screen shot of the form (hope this works, ive never posted a pic before):
[IMG]C:\WINNT\Profiles\paradhann\Desktop\Pop manager.jpg[/IMG]

Hello hello hello what's goin' on here, then?

Tut tut. Code posted in the Post Race? Terrible :rolleyes: ;)

well she did ask for it.