DataGrid or Flexgrid for Multiple Selections?

Will this work... Create public variables in frmChoice and set these to the values needed before the form is shown? ie:

in frmChoice (declarations section):

VB Code:

Public strSomething as string
Public strSomethingElse as string

in the form calling it, (in the event that calls the form):

VB Code:

frmChoice.strSomething = "Something"
frmChoice.strSomethingElse = "Something else"
frmChoice.Show

gotta run, will check back later.

One last problem to fix. I am not sure why it does this.

When the user moves from one of the "View" options, the Row numbering screws up.

For example, the default view comes in when the user runs the program. After the user changes the view (by radio button, choosing either one of the optView (0, 1, 2, or 3)), the view is then off by one. If the user goes to the last view (optView(3), or "Comment Rating"), the numbering is not off. The numbering is only off when the user decides to go to the optViews 0, 1, or 2. When the program first runs, the row numbering is okay. It is only when the user changes the view to 0, 1, or 2. All of the numbering is "bumped" down one (row 2 = row 1; row 3 = row 2; etc. and the first row (row 1) is now near the last row.

Here is the program, I hope you can help me with this last problem. On Monday, it goes into production and then I am "out the door."

Thanks, one last time :(
Reaper

Honestly, I am not seeing the problem. Logically, it seems to be in TableRefresh, since selecting optView(3) is the option which does not call TableRefresh and is the only option not having the problem.

I suspect it is in the adodc. I never use them!! I access my data using ado, but through code. Unfortunately, that puts me a little at a loss. a couple posibilities come to mind: (1). Clear the flexgrid before refreshing the data; and/or (2) immediately after refreshing the adodc, call

VB Code:

adoData.Recordset.MoveFirst

I hope this helps. Good Luck.

John

One more problem (mainly with just the "looks" part of the program). I need to dynamically set the width of "child" form. When the user clicks on the "Batch Count" button, a separate form appears and tells the user some info in 2 columns. Is there a way that I can set the width of the form as the width of the MSHFlexgrid (or atleast the same size as the 2 columns in the grid)? If so, how? (This is the code for the form in question - I placed it here because once this is finished, I am finished)

Thanks,
Reaper

VB Code:

Option Explicit
Public DSN_Name As String
Public Table_Name As String
Public adoConn As ADODB.Connection
 
Public Sub Form_Load()
' Hide the MSHFlexgrid, connect to the database, run the select query, fill the grid with the values, and unhide the grid
    With MSHFlexGrid1
        .Visible = False
        adoData.ConnectionString = "Provider=MSDASQL.1;Persist Security Info=False;Data Source=" & DSN_Name & ";"
        adoData.CommandType = adCmdText
        adoData.RecordSource = "SELECT LEFT(RTRIM(docid),8) AS [Batch Number], COUNT(docid) AS [Batch Count(s)] from " & Table_Name & " GROUP BY LEFT(RTRIM(docid),8)"
        adoData.Refresh
        .ColWidth(0) = 0
        .Visible = True
    End With
    Call ChangeColumnWidth
 
End Sub
 
Public Sub ChangeColumnWidth()
' Sets column width to width of longest text, or column header, in column
    Dim Flex As MSHFlexGrid
    Dim lngMaxLength As Long
    Dim intCounter As Integer
    Dim lngLength As Long
    Dim lngWidth As Long
    Dim lngMinWidth As Long
    Dim i As Integer
    Dim Parent As Form
    
    Set Flex = MSHFlexGrid1
    Set Parent = Flex.Parent
 
    Flex.Redraw = False
    Flex.FocusRect = flexFocusNone
    
    ' This For...Loop will check to see if the text of the column header has the largest width _
    ' and set the width of the column to whichever is largest
    For i = 1 To Flex.Cols - 1
        Flex.Row = 0
        Flex.Col = i
        If (i <> Flex.Cols) Then
            intCounter = Flex.TopRow
            With Parent
                .Font = Flex.FontFixed
                .FontSize = Flex.CellFontSize
                .FontBold = Flex.CellFontBold
                .FontItalic = Flex.CellFontItalic
            End With
            
            ' Get minsize of column from column header
            lngMinWidth = Parent.TextWidth(Flex.TextMatrix(0, i))
            lngMaxLength = 0
            intCounter = 0
            
            ' Check the width of each row
            While intCounter < Flex.Rows - 1
                Flex.Row = intCounter
                With Parent
                    .Font = Flex.CellFontName
                    .FontSize = Flex.CellFontSize
                    .FontBold = Flex.CellFontBold
                    .FontItalic = Flex.CellFontItalic
                End With
                
                lngLength = Parent.TextWidth(Flex.TextMatrix(intCounter, i))
                
                ' Compare the column header width with the row width
                If lngMaxLength < lngLength Then
                    lngMaxLength = lngLength
                End If
                intCounter = intCounter + 1
            Wend
 
            lngWidth = lngMaxLength
            If lngWidth < lngMinWidth Then
                lngWidth = lngMinWidth
            End If
            
            ' Set the column width of each column, but, if the column is longer than 3500 twips _
            ' divide the column width by 4 to fit the width of the MSHFlexgrid
            If lngWidth >= 3500 Then
                Flex.ColWidth(i) = ((lngWidth / 4) + 100)
            Else
                Flex.ColWidth(i) = lngWidth + 100
            End If
        End If
    Next i
    
    Flex.FocusRect = flexFocusLight
    Flex.Redraw = True
End Sub

In this example, the grid is name 'grd'

VB Code:

Private Sub Form_Load()
    With grd
        .ColWidth(0) = 500
        .ColWidth(1) = 2500
        .Left = 0
        .Top = 0
        .Width = .ColWidth(0) + .ColWidth(1)
    End With
    
    Me.Move 0, 0, grd.Width + 100, Me.Height
End Sub

I put the code in the Form_Load event, but it is not working correctly. The height of the form can stay the height that was created at design-time (that is not very important). The width has to be the width of the MSHFlexgrid AND have the verticle scroll bar so that the user can scroll up and down (since the height of the form is not important). Here is the code for the Form_Load event, any suggestions on how to keep the vertical scrollbar and make the width of the form a little bigger than the width of the MSHFlexgrid?

Thanks,
Reaper

VB Code:

Public Sub Form_Load()
' Hide the MSHFlexgrid, connect to the database, run the select query, fill the grid with the values, and unhide the grid
    Dim intFormWidth As Integer
 
    With MSHFlexGrid1
        .Visible = False
        adoData.ConnectionString = "Provider=MSDASQL.1;Persist Security Info=False;Data Source=" & DSN_Name & ";"
        adoData.CommandType = adCmdText
        adoData.RecordSource = "SELECT LEFT(RTRIM(docid),8) AS [Batch Number], COUNT(docid) AS [Batch Count(s)] from " & Table_Name & " GROUP BY LEFT(RTRIM(docid),8)"
        adoData.Refresh
        .ColWidth(0) = 0
        .Visible = True
    End With
    Call ChangeColumnWidth
    
    With MSHFlexGrid1
        intFormWidth = .ColWidth(1) + .ColWidth(2)
        Me.Move 0, 0, intFormWidth, MSHFlexGrid1.Height
    End With
    
End Sub

Try this

VB Code:

Public Sub Form_Load()
' Hide the MSHFlexgrid, connect to the database, run the select query, fill the grid with the values, and unhide the grid
    Dim intFormWidth As Integer
 
    With MSHFlexGrid1
        .Visible = False
        adoData.ConnectionString = "Provider=MSDASQL.1;Persist Security Info=False;Data Source=" & DSN_Name & ";"
        adoData.CommandType = adCmdText
        adoData.RecordSource = "SELECT LEFT(RTRIM(docid),8) AS [Batch Number], COUNT(docid) AS [Batch Count(s)] from " & Table_Name & " GROUP BY LEFT(RTRIM(docid),8)"
        adoData.Refresh
        .ColWidth(0) = 0
        .Visible = True
    End With
    Call ChangeColumnWidth
    
    With MSHFlexGrid1
        intFormWidth = .ColWidth(1) + .ColWidth(2) + 260
        Me.Move 0, 0, intFormWidth, MSHFlexGrid1.Height
    End With
    
End Sub

I added 260 to the inFormWidth to allow for a scrollbar (220) + borders, grid lines, etc. You may have to adjust this number.

Quote:

---

Originally Posted by John McKernan

The Flexgrid is not directly editable, but it is not difficult to accomplish.

In short, you need a borderless, invisible textbox on the form with your grid. When the user clicks on a cell, the textbox is moved and sized to cover the cell, made visible and given the focus. All user editting is done in the textbox. When user is done, the text is copied to the cell, the textbox is cleared and made invisible, awaiting its next use. This is all transparent to the user of course.

The attached zip file, contains a small app in VB6 which illustrates this procedure

---

I know this posting is kinda old but is there any chance that I can get hold of that zip file?