right click on windows. [hard]

Project > Add Form

However this form is not shown by itself you'll need to load it (or simply call the Show method).

About the issue with the DLL being in use so you can't overwrite it. The main problem with creating shell extensions in VB is that it's so hard to debug it. The system will load your DLL when you have right clicked on a file in Windows Explorer and will keep it in memory until Windows is restarted (or atleast until you log out). What you must do is to restart your system.

Yea, just for testing purposes I log off and on (and i have disabled most startup programs like MSN, so it loads faster).

Ok, Joa, I tried putting a form in , but it didnt work.

Plus my FTP program (which i downloaded) has a usercontrol file in it.

do you know a simpler one (i have been searching for a couple of days now). I tried making my own using Inet, but like it creates folders and stuff, but for some reason does not send a file to the server.

(and it gives me no error).

This code does not work, (and I took it off the word document you made one day as help for this)

VB Code:

Private Declare Function InternetOpen Lib "wininet.dll" _
 Alias "InternetOpenA" ( _
 ByVal sAgent As String, _
 ByVal nAccessType As Long, _
 ByVal sProxyName As String, _
 ByVal sProxyBypass As String, _
 ByVal nFlags As Long) As Long
 
Private Declare Function InternetConnect _
 Lib "wininet.dll" Alias "InternetConnectA" ( _
 ByVal hInternetSession As Long, _
 ByVal sServerName As String, _
 ByVal nServerPort As Integer, _
 ByVal sUserName As String, _
 ByVal sPassword As String, _
 ByVal nService As Long, _
 ByVal dwFlags As Long, _
 ByVal dwContext As Long) As Long
 
 Private Declare Function FtpPutFile _
 Lib "wininet.dll" Alias "FtpPutFileA" ( _
 ByVal hFtpSession As Long, _
 ByVal lpszLocalFile As String, _
 ByVal lpszRemoteFile As String, _
 ByVal dwFlags As Long, _
 ByVal dwContext As Long) As Boolean
 
 
 
 
Private Sub Form_Load()
hINetSession = InternetOpen("MyFTPClient", 0, vbNullString, _
 vbNullString, 0)
 
 If hINetSession = 0 Then
 
 MsgBox "Could Not Connect", vbOKOnly, "Error"
 Exit Sub
 End If
 
 hSession = InternetConnect(hINetSession, "72.36.250.114", _
    "21", "fenix", "kittycat", INTERNET_SERVICE_FTP, 0, 0)
    
    If FtpPutFile(hSession, "c:\SSInst.txt", _
 "www\shared.txt", 1, 0) = False Then
    MsgBox "The call to FtpPutFile failed."
End If
 
Unload Me
End Sub

Put the following code in a BAS module:

VB Code:

Private Declare Function InternetOpen _
 Lib "wininet.dll" Alias "InternetOpenA" ( _
    ByVal sAgent As String, _
    ByVal nAccessType As Long, _
    ByVal sProxyName As String, _
    ByVal sProxyBypass As String, _
    ByVal nFlags As Long _
) As Long
 
Private Declare Function InternetConnect _
 Lib "wininet.dll" Alias "InternetConnectA" ( _
    ByVal hInternetSession As Long, _
    ByVal sServerName As String, _
    ByVal nServerPort As Integer, _
    ByVal sUserName As String, _
    ByVal sPassWord As String, _
    ByVal nService As Long, _
    ByVal nFlags As Long, _
    ByVal nContext As Long _
) As Long
 
Private Declare Function FtpPutFile _
 Lib "wininet.dll" Alias "FtpPutFileA" ( _
    ByVal hFtpSession As Long, _
    ByVal lpszLocalFile As String, _
    ByVal lpszRemoteFile As String, _
    ByVal dwFlags As Long, _
    ByVal dwContext As Long _
) As Boolean
 
Private Declare Function InternetCloseHandle Lib "wininet.dll" ( _
    ByVal hInet As Long _
) As Integer
 
Public Enum eTransferType
    FTP_TRANSFER_TYPE_ASCII = &H1
    FTP_TRANSFER_TYPE_BINARY = &H2
End Enum
 
Private Const INTERNET_FLAG_EXISTING_CONNECT As Long = &H20000000
Private Const INTERNET_FLAG_PASSIVE As Long = &H8000000
Private Const INTERNET_SERVICE_FTP = 1
Private Const INTERNET_OPEN_TYPE_PRECONFIG As Long = 0
 
Private hSession As Long
Private hINetSession As Long
 
Public Function Connect( _
 ByVal sRemoteHost As String, _
 ByVal sUserName As String, _
 ByVal sPwd As String, _
 Optional ByVal nPort As Long = 21) As Boolean
    
    If (hSession + hINetSession) <> 0 Then
        CloseConnection
    End If
    hINetSession = InternetOpen("MyApplication", _
     INTERNET_OPEN_TYPE_PRECONFIG, _
     vbNullString, vbNullString, 0)
    If hINetSession Then
        hSession = InternetConnect(hINetSession, sRemoteHost, _
         nPort, sUserName, sPwd, INTERNET_SERVICE_FTP, _
         INTERNET_FLAG_EXISTING_CONNECT, 0)
    End If
    Connect = (hSession <> 0)
End Function
 
Public Sub CloseConnection()
    If hSession Then
        Call InternetCloseHandle(hSession)
    End If
    If hINetSession Then
        Call InternetCloseHandle(hINetSession)
    End If
    hSession = 0
    hINetSession = 0
End Sub
 
Public Function UploadFile( _
 ByVal sLocalFile As String, _
 sRemoteFile As String, _
 enTransferType As eTransferType) As Boolean
    
    If hSession Then
        UploadFile = FtpPutFile(hSession, sLocalFile, sRemoteFile, enTransferType, 0)
    End If
End Function

Now you would first call the Connect function followed by UploadFile and finally the CloseConnection.

VB Code:

If Connect("ftp.yourserver.com", "UserName", "SecretPassword") Then
    UploadFile "c:\myfile.dat", "/folderPath/myfile.dat", FTP_TRANSFER_TYPE_BINARY
    CloseConnection
Else
    MsgBox "Unable to connect to the server"
End If

Nope that just hangs it and i have to restart it.

the following is what i use and it works.

its preety big, but its simple I think because half of the stuff isnt being used.

I dont get it.. why does it stop responding?

I even take out the "upload".

If it connects it unloads the form, but still it hangs.