using 2 arrays

Hi everyone. I'm a newbie at vb and have to write a program using 2 arrays,one with student names and the other with student scores.I have to 1st print them out in original order and then sort them from best score to worst. I'm trying to do this using a list box,with a for/next loop and additem. Below is my current code. I know it is wrong and keep getting invalid qualifier errors.Any help would be greatly appreciated.
Option Explicit
Dim namearray(6) As String
Dim lstnamearray As Integer
Dim i As Integer
Private Sub Command1_Click()
Dim i As Integer
i = lstnamearray
lstnamearray.Clear
lstnamearray(0).AddItem = "Dan Pickett 92"
lstnamearray(1).AddItem = "Betty Knapp 87"
lstnamearray(2).AddItem = "Jackie Denhoff 82"
lstnamearray(3).AddItem = "Mike Diebold 78"
lstnamearray(4).AddItem = "Rob Wardell 73"
lstnamearray(5).AddItem = "Mike Garcia 70"
lstnamearray(6).AddItem = "Paul Martinez 66"
Cls
For i = 0 To UBound(namearray)
Print namearray(i)
Next i
End Sub

Put this in a form and test it....look at the comments I added.

Option Explicit
Dim namearray(6) As String
'Dim lstnamearray As Integer ' same name as listbox....no good
' this explains the "invalid qualifier errors"
Dim i As Integer
Private Sub Command1_Click()
Dim i As Integer
'i = lstnamearray ' see above
lstnamearray.Clear

' with listboxes you don't specify an "array" element until to
' want to access a particular value.
lstnamearray.AddItem "Dan Pickett 92"
lstnamearray.AddItem "Betty Knapp 87"
lstnamearray.AddItem "Jackie Denhoff 82"
lstnamearray.AddItem "Mike Diebold 78"
lstnamearray.AddItem "Rob Wardell 73"
lstnamearray.AddItem "Mike Garcia 70"
lstnamearray.AddItem "Paul Martinez 66"
Cls

' not sure what your doing here....namearray is empty
For i = 0 To UBound(namearray)
Print namearray(i)
Next i
End Sub

Just noticed..you have i as Integer declared 2x. At the top and in the commandbutton click event. Delete one of them.

Hi Pickett
Here is a quick sample. I do hope that you dont just copy it and rather go thru it to understand what each line does. This is just one way of doing it and is based on assumptions such as the score being a whole number. I wanted to keep it simple tho.
Regards
Stuart

VB Code:

Option Explicit
 
Dim fstrNames() As String 'Dynamic declaration is better than fixed if it can change
Dim fintScores() As Integer 'Dynamic declaration is better than fixed if it can change
'You can also use a user defined type to store both values
'in one variable but we will leave that
Dim fintNumberOfStudents As Integer
Dim fintLoopCounter As Integer
Dim fintOrderPosition As Integer
 
Private Sub Form_Load()
'Lets assume that you are not reading your
'data from a file
    ReDim fstrNames(4) 'U dont need to do this if u declare as fixed length above
    fstrNames(0) = "John Smith"
    fstrNames(1) = "Jenny Jones"
    fstrNames(2) = "Dora Dent"
    fstrNames(3) = "Roger Ramjet"
    fstrNames(4) = "Kevin Kev"
    
    'Assume whole numbers. Otherwise
    'use Single or Double variables
    ReDim fintScores(4) 'U dont need to do this if u declare as fixed length above
    fintScores(0) = 75
    fintScores(1) = 60
    fintScores(2) = 80
    fintScores(3) = 95
    fintScores(4) = 20
    
    'Use this if file can change in number of entries
    fintNumberOfStudents = UBound(fintScores)
    'Or just use fintNumberOfStudents = 4
End Sub
 
Private Sub Command1_Click()
    'Stage 1 Display in actual order
    List1.Clear
    For fintLoopCounter = 0 To fintNumberOfStudents
        'NB List 1 is set to SORTED = FALSE in properties
        List1.AddItem fstrNames(fintLoopCounter) & vbTab & fintScores(fintLoopCounter)
    Next
End Sub
 
Private Sub Command2_Click()
    'Stage 2 Display in score order from best to worst
    List1.Clear
    List2.Clear 'Maybe make List2 Visible false to hide what is going on
    For fintLoopCounter = 0 To fintNumberOfStudents
        'NB List 2 is set to SORTED = TRUE in properties
        List2.AddItem fintScores(fintLoopCounter) 'Scores are all u are sorting so leave names out
        List2.ItemData(List2.NewIndex) = fintLoopCounter
    Next
 
    'Note counting backwards here
    For fintLoopCounter = fintNumberOfStudents To 0 Step -1
        'NB List 1 is set to SORTED = FALSE in properties
        fintOrderPosition = List2.ItemData(fintLoopCounter)
        List1.AddItem fstrNames(fintOrderPosition) & vbTab & fintScores(fintOrderPosition)
    Next
End Sub