Writing binary file with progress

I am at present writing binary from a custom resource to a file. However I would like to keep a status bar recording the progress of the writing. Unfortunately this code (has no progress bar):

VB Code:

Dim byteArr() As Byte
 
byteArr = LoadResData(101,"CUSTOM")
 
Open theFile$ For Binary As #1
Put #1, , byteArr
Close #1

is 100 times faster (according to GetTickCount) than this code:

VB Code:

Dim byteArr() As Byte
Dim i as Integer
 
byteArr = LoadResData(101,"CUSTOM")
 
Open theFile$ For Binary As #1
For i = 0 To Ubound(byteArr)
Put #1, , byteArr(i)
UpdateStatus Int((i+1)/(Ubound(byteArr)+1)*100) 'update progressbar
Next
Close #1

I would like to keep a progress bar on the writing, but I cannot have something which is so slow. Any ideas?

did u do the timecompare without the statusbar update?

its just that 100 times seems much :)

Dont refresh the progress bar every change, try maybe every 10 or 100 depends on the max value.

every time - i just had an empty sub for updatestatus - the simple time for looping made it take 2016 milliseconds as opposed to 19 milliseconds for the first example.

:eek: damn.. that was a big diff.

hmmm don't see how u could make the progress bar ... maybe do it the way MS often does, showing a stupid anim. letting the user know that SOMETHING is happening but we don't know how far the process have reached ... (I don't like it but...)

Refreshing anything on screen will slow down your code :(

Try this :

VB Code:

Dim byteArr() As Byte
Dim i As Long, nUbound As Long, nUboundPlusOne As Long
 
byteArr = LoadResData(101,"CUSTOM")
nUbound = Ubound(byteArr)
nUboundPlusOne = nUbound + 1
 
Open theFile$ For Binary As #1
    For i = 0 To nUbound
        Put #1, , byteArr(i)
        UpdateStatus (i + 1) \ (nUboundPlusOne) * 100 
    Next
Close #1

even if you update the progress bar with the same value each time it will still cause the same delay (maybe a *little* shorter)

I cannot see how that can be much faster (other than not always finding the ubound). I tested it without the updatestatus line and it was still 100 times slower. I think the looping and therefore the extra put commands make it slower

Well prestoring constants is a standard way of optimizing/speeding up code.

As is using the Long data type instead of Integer.

You could also try something like this :

VB Code:

Open theFile For Binary As #1
    For i = 0 To nUbound
        Put #1, , byteArr(i)
        If ((i Mod 10) = 0) Then UpdateStatus((i + 1) \ (nUboundPlusOne) * 100)
    Next
Close #1

But I ran just:

VB Code:

Dim byteArr() As Byte
Dim i As Integer
 
byteArr = LoadResData(101,"CUSTOM")
 
Open theFile$ For Binary As #1
     For i = 0 To UBound(byteArr)
          Put #1, , byteArr(i)
     Next i
Close #1

and just that (no status update) was 100 times slower.

Well obviously iterating through the array its going to be slower than just outputting the array as is.

100 times though?

Apparantly ;)

Im getting lots of different answers, but on average this is showing me about 10 times slower....

VB Code:

Option Explicit
 
Private Declare Function GetTickCount Lib "kernel32" () As Long
Private time1 As Long
Private time2 As Long
 
Private Sub Form_Load()
    sub1
    sub2
    Debug.Print time1 & "," & time2
End Sub
 
 
Private Sub sub1()
    Dim byteArr() As Byte, i As Long
    ReDim byteArr(0)
 
    For i = 0 To 50000
        byteArr(i) = CByte(i Mod 255)
        ReDim Preserve byteArr(UBound(byteArr) + 1)
    Next i
    
    time1 = GetTickCount
    Open "c:\myTest.txt" For Binary As #1
        Put #1, , byteArr
    Close #1
    time1 = GetTickCount - time1
    
End Sub
 
Private Sub sub2()
 
    Dim byteArr() As Byte, i As Long
    ReDim byteArr(0)
    
    For i = 0 To 50000
        byteArr(i) = CByte(i Mod 255)
        ReDim Preserve byteArr(UBound(byteArr) + 1)
    Next i
    
    time2 = GetTickCount
    Open "c:\myTest.txt" For Binary As #1
        For i = 0 To UBound(byteArr)
            Put #1, , byteArr(i)
        Next
    Close #1
    time2 = GetTickCount - time2
    
End Sub

I modified the Form_Load price as follows :

VB Code:

Private Sub Form_Load()
    Dim x As Long
    For x = 0 To 10
        sub1
        sub2
        Debug.Print time1 & "," & time2
    Next x
End Sub

and get the following :

Code:

---

    0,285
    0,295
    0,290
    5,290
    0,285
    0,290
    5,290
    0,285
    0,290
    5,285
    0,285

---

I was writing a 440 K file and I got:

19,2124
20,2090
19,2143
19,2119

And then you would have to have the status updating...