[RESOLVED] Transfer UDT to Class [Nested Classes]

Hello,

I have a pretty huge UDT but I'm now converting it as a Class Structure. However I'm having issues passing from/to the nested class properties.

Example:

Code:

---

Dim testDB() As Class1_Main

Private Sub Form_Load()
    ReDim testDB(0)
    Set testDB(0) = New Class1_Main
    testDB(0).Item(0).xName = "test"    'TEST isn't being passed on?

    MsgBox testDB(0).Item(0).xName      'EMPTY<<<<<<<<<<<<<

    End
End Sub

---

I've attached the Simple Project.
Any help would be appreciated.

[...]

.Item(n) returns a clone, non-permanent class instance.

So, testDB(0).Item(0).xName = "test" is setting xName on the clone

MsgBox testDB(0).Item(0).xName is creating another, different, clone

Neither clone is persisted. I didn't run your test, just reviewed the class files

If this:

Code:

---

Public Property Get Item(ByVal iIndex As Byte) As Class2_Items
  Set Item = xItem(iIndex).Clone
End Property

---

changed to this, then you should get your value

Code:

---

Public Property Get Item(ByVal iIndex As Byte) As Class2_Items
  Set Item = xItem(iIndex)
End Property

---

Edited: too slow, dz32 beat me to it

Have you tried setting break points in the class and stepping through the code to see what gets executed?

Ohh i see.. So no need for the Clone Function.

Yeah, I just thought your code through too, and LaVolpe is right on. The Clone function down in Class2_Items is very confusing.

The following line in your Form1 ...

Code:

---

testDB(0).Item(0).xName = "test"    'TEST isn't being passed on?

---

... the highlighted part is calling the Clone function. Remember that only the last piece of a statement is the Let/Set piece (the .xName piece). All other pieces will be Get pieces. Therefore, Item(0) will be a Get. And then, in your Clone procedure, you've got ...

Code:

---

Set Clone = New Class2_Items

---

... within that procedure. Therefore, this local Clone variable/object is uninstantiated once you're finished using it. Therefore, you've set the .xName property in a temporary (further nested, somewhat recursive) version of Class2_Items. Once the testDB(0).Item(0).xName = "test" statement completes, that Clone is destroyed, along with its .xName property.

If you start your program with F8 and just step through it, you'll see all of this.

I'm not clear on why you just didn't directly return the items in Class2 rather than trying to clone them. Are you trying to make a read-only version of them? That would be accomplished a bit differently.

The easiest way I could see to do this would be to just return the entire Class2 as a property of Class1. Something like the following ...

Code:

---

Friend Property Get Item(ByVal iIndex As Byte) As Class2_Items
    ' The item with iIndex must have been added before fetching with iIndex.
    Set Item = xItem(iIndex)
End Property

Friend Property Set Item(ByVal iIndex As Byte, newItem As Class2_Items)
    ' The item with iIndex must have been added before being set with newItem.
    Set xItem(iIndex) = newItem
End Property

---

... (aircode, I didn't test) that should just directly return the item with no cloning.

Good Luck,
Elroy

EDIT1: Ahhh, sorry, I took a bit to compose my post. Yeah, no need for your clone procedure. :)

[...]

Although this issue has been resolved, I cam across another interesting thing.

I have another property which is a ByteArray [xData]

But I can't seem to access it directly without making a temporary variable to dump the data.
Is that normal?

i.e

Code:

---

Private Sub Form_Load()
    ReDim testDB(0)
    Set testDB(0) = New Class1_Main
    testDB(0).Item(0).xData = StrConv("test", vbFromUnicode)
   
  Debug.Print testDB(0).Item(0).xData(2)    '//Error here <<<<

    End
End Sub

---

To reference it directly... notice the closed parentheses

Code:

---

Debug.Print testDB(0).Item(0).xData()(2)

---

Quote:

---

Originally Posted by LaVolpe

To reference it directly... notice the closed parentheses

Code:

---

Debug.Print testDB(0).Item(0).xData()(2)

---

---

hmm... never seen a reference like this .. good to know :)

Although there is somewhat a speed impact....

[...]