Add another button next to the minimize,maximize, close buttons

is there away to add another button to the left of the minimize butotn in the control bar of my program?? i know theres away, im just tring to figure out how...kinda like how the all api guid program has that lil . that puts it in the tray

I don't believe there is a way.

⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀

smashtheqube: I'd love to see how it's done, but are you saying that you've done it but you don't know how?

Draw your own title bar, and write some code to process mouse events on it. You can add everything .

that sounds like someone by the name of smashthecube is taking credit for somthing he didnt build?

if not then why dont u just open your source up and look?

HI

I had asked this question a while ago and this was the reply I had got. I have been able to make only partial sense out of it so far

Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, lpRect As Rect) As Long
Private Declare Function GetParent Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function SetParent Lib "user32" (ByVal hWndChild As Long, ByVal hWndNewParent As Long) As Long
Private Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" (ByVal idHook&, ByVal lpfn&, ByVal hmod&, ByVal dwThreadId&) As Long
Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook&) As Long
Private Declare Function CreateWindowEx Lib "user32" Alias "CreateWindowExA" (ByVal dwExStyle As Long, ByVal lpClassName As String, ByVal lpWindowName As String, ByVal dwStyle As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hWndParent As Long, ByVal hMenu As Long, ByVal hInstance As Long, lpParam As Any) As Long
Private Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long

Private Type Rect
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type

Private Type CWPSTRUCT
lParam As Long
wParam As Long
Message As Long
hwnd As Long
End Type

Const WM_MOVE = &H3
Const WM_SETCURSOR = &H20
Const WM_NCPAINT = &H85
Const WM_COMMAND = &H111

Const SWP_FRAMECHANGED = &H20
Const GWL_EXSTYLE = -20

Private WHook&
Private ButtonHwnd As Long

Public Sub Init()
'Create the button that is going to be placed in the Titlebar
ButtonHwnd& = CreateWindowEx(0&, "Button", "i", &H40000000, 50, 50, 14, 14, Form1.hwnd, 0&, App.hInstance, 0&)
'Show the button cause it´s invisible
Call ShowWindow(ButtonHwnd&, 1)
'Initialize the window hooking for the button
WHook = SetWindowsHookEx(4, AddressOf HookProc, 0, App.ThreadID)
Call SetWindowLong(ButtonHwnd&, GWL_EXSTYLE, &H80)
Call SetParent(ButtonHwnd&, GetParent(Form1.hwnd))
End Sub

Public Sub Terminate()
'Terminate the window hooking
Call UnhookWindowsHookEx(WHook)
Call SetParent(ButtonHwnd&, Form1.hwnd)
End Sub

Public Function HookProc&(ByVal nCode&, ByVal wParam&, Inf As CWPSTRUCT)
Dim FormRect As Rect
Static LastParam&
If Inf.hwnd = GetParent(ButtonHwnd&) Then
If Inf.Message = WM_COMMAND Then
Select Case LastParam
'If the LastParam is cmdInTitlebar call the Click-Procedure
'of the button
Case ButtonHwnd&: Call Form1.cmdInTitlebar_Click
End Select
ElseIf Inf.Message = WM_SETCURSOR Then
LastParam = Inf.wParam
End If
ElseIf Inf.hwnd = Form1.hwnd Then
If Inf.Message = WM_NCPAINT Or Inf.Message = WM_MOVE Then
'Get the size of the Form
Call GetWindowRect(Form1.hwnd, FormRect)
'Place the button int the Titlebar
Call SetWindowPos(ButtonHwnd&, 0, FormRect.Right - 75, FormRect.Top + 6, 17, 14, SWP_FRAMECHANGED)
End If
End If
End Function
--------------------------------------------------------------------------------


And put this in the Form's module:


code:--------------------------------------------------------------------------------
Public Sub cmdInTitlebar_Click()
Me.WindowState = 1 'minimizes the form
End Sub

Private Sub Form_Load()
Call Init
End Sub

Private Sub Form_Unload(Cancel As Integer)
Call Terminate
End Sub


To minimize the form to the system tray you can use a Systemicon control and on the button's click event set the form;s windowstate to be minimized anf add an icon to the system tray.

Appi

if i wanted to draw my own bar then i would, other wise i wouldnt post a freaking message here.....so instead of telling me others ways to do it, either keep yoru moth shut, or say,, um im not sure....ok huyak?

and btw i know there is away, if u have ever used apiguid u will notice they have one that looks exactly like the other buttons except with a caption of .

thanx, ill try that code out

If the above code doesn't work, (can't tell at a glance and too tired to test it), then this will, at least give you a good starting point:

In a Module:

VB Code:

Private Type RECT
        Left As Long
        Top As Long
        Right As Long
        Bottom As Long
End Type
 
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
 
Private Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hdc As Long) As Long
Private Declare Function DeleteDC Lib "gdi32" (ByVal hdc As Long) As Long
Private Declare Function BitBlt Lib "gdi32" (ByVal hDestDC As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As Long) As Long
Private Declare Function GetDC Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function ReleaseDC Lib "user32" (ByVal hwnd As Long, ByVal hdc As Long) As Long
Private Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT) As Long
Private Declare Function SelectObject Lib "gdi32" (ByVal hdc As Long, ByVal hObject As Long) As Long
Private Declare Function GetWindowDC Lib "user32" (ByVal hwnd As Long) As Long
 
Private Declare Function SetCapture Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function ReleaseCapture Lib "user32" () As Long
 
Private Const SRCCOPY = &HCC0020
 
Private Const GWL_WNDPROC = (-4)
 
Private Const WM_NCACTIVATE = &H86
Private Const WM_NCCALCSIZE = &H83
Private Const WM_NCCREATE = &H81
Private Const WM_NCDESTROY = &H82
Private Const WM_NCHITTEST = &H84
Private Const WM_NCLBUTTONDBLCLK = &HA3
Private Const WM_NCLBUTTONDOWN = &HA1
Private Const WM_NCLBUTTONUP = &HA2
Private Const WM_NCMBUTTONDBLCLK = &HA9
Private Const WM_NCMBUTTONDOWN = &HA7
Private Const WM_NCMBUTTONUP = &HA8
Private Const WM_NCMOUSEMOVE = &HA0
Private Const WM_NCPAINT = &H85
Private Const WM_NCRBUTTONDBLCLK = &HA6
Private Const WM_NCRBUTTONDOWN = &HA4
Private Const WM_NCRBUTTONUP = &HA5
Private Const WM_COMMAND = &H111
 
Private Const HTBORDER = 18
Private Const HTBOTTOM = 15
Private Const HTBOTTOMLEFT = 16
Private Const HTCAPTION = 2
Private Const HTBOTTOMRIGHT = 17
Private Const HTCLIENT = 1
Private Const HTERROR = (-2)
Private Const HTGROWBOX = 4
Private Const HTHSCROLL = 6
Private Const HTLEFT = 10
Private Const HTMAXBUTTON = 9
Private Const HTMENU = 5
Private Const HTMINBUTTON = 8
Private Const HTNOWHERE = 0
Private Const HTREDUCE = HTMINBUTTON
Private Const HTRIGHT = 11
Private Const HTSIZE = HTGROWBOX
Private Const HTSIZEFIRST = HTLEFT
Private Const HTSIZELAST = HTBOTTOMRIGHT
Private Const HTSYSMENU = 3
Private Const HTTOP = 12
Private Const HTTOPLEFT = 13
Private Const HTTOPRIGHT = 14
Private Const HTTRANSPARENT = (-1)
Private Const HTVSCROLL = 7
Private Const HTZOOM = HTMAXBUTTON
 
Private lWindowProc As Long
Private lWindowHandle As Long
Private lButtonDC As Long
Private lButtonDownDC As Long
 
Private tRECT As RECT, lWidth, lHeight
 
Private bDrawnDown As Boolean
 
Public Sub SubclassWindow(ByVal hwnd As Long)
    Dim lDC As Long
    
    ' Get the Forms Device Context (DC)
    lDC = GetDC(hwnd)
    ' Create 2 compatible DC's for the Up and Down button images
    lButtonDC = CreateCompatibleDC(lDC)
    lButtonDownDC = CreateCompatibleDC(lDC)
    ' Load the Up and Down button images into each DC respectively
    ' Images are 16x14 16 colors
    Call SelectObject(lButtonDC, LoadPicture("C:\Media\Images\Happy.bmp"))
    Call SelectObject(lButtonDownDC, LoadPicture("C:\Media\Images\HappyDN.bmp"))
    ' Release the forms DC
    Call ReleaseDC(hwnd, lDC)
    ' Subclass the Form
    lWindowProc = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf SubWindowProc)
    ' Store the forms hWnd for processing later
    lWindowHandle = hwnd
End Sub
 
Public Sub StopSubclass()
    ' Remove the Forms subclassing
    Call SetWindowLong(lWindowHandle, GWL_WNDPROC, lWindowProc)
    ' Delete to 2 button image DC's
    Call DeleteDC(lButtonDC)
    Call DeleteDC(lButtonDownDC)
End Sub
 
Private Function SubWindowProc(ByVal hwnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    ' Capture ALL messages going to the Form before they are processed
    Static bDepressed As Boolean
    
    Dim lDC As Long
        
    ' Call the default behaviour as normally we'll want to adjust it after the fact
    SubWindowProc = CallWindowProc(lWindowProc, hwnd, Msg, wParam, lParam)
    
    ' Get the Forms current dimensions
    Call GetWindowRect(hwnd, tRECT)
    
    ' Calculate the Forms Width and Height
    lWidth = tRECT.Right - tRECT.Left
    lHeight = tRECT.Bottom - tRECT.Top
            
    Select Case Msg
    Case WM_NCHITTEST
        ' See if the cursor is over our custom button
        If IsOverButton(lParam) Then
            ' If it is, set the Capture to this window, allowing us to receive
            ' Input events as they happen instead of "after the fact"
            SetCapture hwnd
            ' Tell the form our button is just the Caption bar (I don't know of a custom button HT Const)
            SubWindowProc = HTCAPTION
        End If
        
    Case WM_NCLBUTTONDOWN
        ' If the left mouse button is pressed over our button, show a sunken image
        If IsOverButton(lParam) Then
            ' Keep a flag so we know it's being pressed, (lets us to the fancy raise and sink
            ' as the mouse moves in and out of the button without letting the mouse button up.)
            bDepressed = True
            ' Draw the sunken image of our button
            PaintButton lButtonDownDC
            ' Tell the default Window handler we've processed this message
            SubWindowProc = 0
        End If
 
    Case WM_NCLBUTTONUP
        ' If the left button is up, our button can no longer be being pressed
        ' so flag it and no longer depressed.
        bDepressed = False
        ' If the mouse is over our button...
        If IsOverButton(lParam) Then
            ' Draw the raised image
            PaintButton lButtonDC
            ' Release sole capture of the Input messages
            ReleaseCapture
            ' Tell the default handler, we've processed this message
            SubWindowProc = 0
            ' Trigger our Click event
            ButtonClickEvent
        End If
        
    Case WM_NCMOUSEMOVE
        ' If the mouse moves over our button and the left button is pressed..
        If IsOverButton(lParam) And bDepressed Then
            ' Draw the sunken button image
            PaintButton lButtonDownDC
        Else
            ' Otherwise, if the image is currently sunken, raise it
            If bDrawnDown Then
                PaintButton lButtonDC
            End If
            ' and release capture
            ReleaseCapture
        End If
        
    Case WM_NCPAINT, WM_NCACTIVATE
        ' Redraw the button on PAINT and ACTIVATE events
        PaintButton lButtonDC
        
    End Select
        
End Function
 
Private Function LoWord(ByVal lValue As Long) As Long
    LoWord = lValue And &HFFFF&
End Function
 
Private Function HiWord(ByVal lValue As Long) As Long
    HiWord = (lValue / &H10000) And &HFFFF&
End Function
 
Private Function IsOverButton(ByVal lPos As Long)
    ' Determine if the specified Coords are within our custom button
    Dim lX As Long, lY As Long
    lX = (LoWord(lPos) - tRECT.Left)
    lY = (HiWord(lPos) - tRECT.Top)
    IsOverButton = (lX >= (lWidth - 75)) And (lX <= (lWidth - 61)) And (lY >= 6 And lY <= 22)
End Function
 
Private Function PaintButton(ByVal lImageDC As Long)
    ' Draw the specified image
    Dim lDC As Long
    ' Track whether the button is currently drawn up or down.
    bDrawnDown = (lImageDC = lButtonDownDC)
    lDC = GetWindowDC(lWindowHandle)
    BitBlt lDC, lWidth - 75, 6, 16, 14, lImageDC, 0, 0, SRCCOPY
    Call ReleaseDC(lWindowHandle, lDC)
End Function
 
Private Sub ButtonClickEvent()
    ' Custom Button Event Code goes Here!
    MsgBox "Smile!!"
End Sub

In a Form:

VB Code:

Private Sub Form_Initialize()
    SubclassWindow hwnd
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    StopSubclass
End Sub

Or if you prefer I've attached my project files.

Aaron, that is the first subclassing example I have seen that works on NT4, nice. Will this also work on win 9x?


FOOBAR:

Quote:

---

if i wanted to draw my own bar then i would, other wise i wouldnt post a freaking message here.....so instead of telling me others ways to do it, either keep yoru moth shut, or say,, um im not sure....ok huyak?

---

Chill out man, it was a valid suggestion and much easier than doing it with API calls. Out of interest, how old are you?

It should, I'm using WinME, there shouldn't be anything O/S speicifc in the code.

Quote:

---

Originally posted by Nucleus
Aaron, that is the first subclassing example I have seen that works on NT4, nice. Will this also work on win 9x?


FOOBAR:



Chill out man, it was a valid suggestion and much easier than doing it with API calls. Out of interest, how old are you?

---

yeah man chill out, he was trying to help you