Splite function not avalable in VB5

Split(StringToSplit[, DelimiterToUse, HowMany])
- Returns a one dimensional array
- StringToSplit is any valid string
- DelimiterToUse is the character that you want the string to be split by.
- HowMany is the number of elements you want to limit the array to.
- DelimiterToUse and HowMany are optional parameters.
- If you leave out the DelimterToUse, the function uses a space to split the string.

Example:

Dim MyString, MyArray
MyString = "apples,oranges,grapes"
MyArray = Split(MyString, ",")


Result:
A one dimensional array called MyArray with 3 elements.

Is there same this function (Split) in the VB5

No, Split() is new with VB 6.0, not found in VB 5.0. There are several functions that were added to VB 6.0 - this is one of the reasons why the forum asks you for your VB version and shows it as part of your profile- so the answers you get match your version of VB.

Try:

Code:

---

'Here's one of a dozen versions of Split()

Sub Split(ByVal arr() As String,ByVal strInput as String, ByVal strDelimit as String)
          Dim i, tmp
          Redim arr(0)
          For i = 1 to len(strInput)
              tmp = mid(strInput,i,1)
              if tmp = strDelimit then
                      Redim Preserve arr(Ubound(arr) + 1)
                      arr(UBound(arr) ) = ""
              else
                      arr(Ubound(arr)) = arr(Ubound(arr)) & tmp
              End If
          Next i
End Sub

---

:D

Here's another one, great code from Aaron Young.

VB Code:

'Author: Aaron Young
'Origin: -
'Purpose: Split function
'Version: VB4+ 
 
 
Private Function Split2(ByVal sString As String, ByVal sSeparator As String) As Variant
    Dim sParts() As String
    Dim lParts As Long
    Dim lPos As Long
    
    lPos = InStr(sString, sSeparator)
    While lPos
        ReDim Preserve sParts(lParts)
        sParts(lParts) = Left(sString, lPos - 1)
        sString = Mid(sString, lPos + Len(sSeparator))
        lPos = InStr(sString, sSeparator)
        lParts = lParts + 1
    Wend
    If Len(sString) Then
        ReDim Preserve sParts(lParts)
        sParts(lParts) = sString
    End If
    Split2 = IIf(lParts, sParts, Array())
End Function

Yes, those of us who don't need the fluff of VB6 (J/K) have it hard sometimes. Most apparent is the absense of Replace and the mentioned Split. Attached is a file I use for VB6 source called VB6Compatibility.bas. Just add it to a project and you have instant Split and Replace!

BTW, I didn't write the code. I came accross Replace here on VB Forums and Split on My Favorite Function 3 from VB World.

Here's the Join function for VB5 if you need it as well.
Or to add to that module above ;).

VB Code:

Public Function Join(SourceArray, Optional Delimiter) As String
    If IsMissing(Delimiter) Then Delimiter = ""
    Dim sTemp As String
    Dim nIndex As Long
    If InStr(LCase(TypeName(SourceArray)), "()") Then
        For nIndex = LBound(SourceArray) To UBound(SourceArray)
            sTemp = sTemp & SourceArray(nIndex) & Delimiter
        Next
    End If
    Join = Left(sTemp, Len(sTemp) - Len(Delimiter))
End Function

And the InstrRev function.

VB Code:

Public Function InStrRev(StringCheck As String, StringMatch As String, Optional Start As Long = -1) As Long
    Dim sTemp As String
    Dim nChar As Long
    Dim nPos As Long
    
    sTemp = Space(Len(StringCheck))
    For nChar = 0 To Len(StringCheck) - 1
        Mid(sTemp, nChar + 1, 1) = Mid(StringCheck, Len(StringCheck) - nChar, 1)
    Next
    If Start <= Len(StringCheck) Then
        nPos = InStr(IIf(Start = -1, 1, Len(StringCheck) + 1 - Start), sTemp, StringMatch)
    End If
    InStrRev = IIf(nPos, (Len(StringCheck) + 1) - nPos, 0)
End Function

Another InstrRev function written by Iain.

VB Code:

'Author: Iain17
'Origin: String Manipulation
'Purpose: InStrRev for VB5
'VB version: VB4/VB5/VB6
'Comments:  Remove the Optional iStart As Long in order for this to work in VB4.
 
 
Private Function InStrRev(strStringToSearch As String, strFind As String, Optional iStart As Long) As Long
    Dim ip1 As Long, ip2 As Long
    Dim iLenStringToSearch As Long
    Dim iLenFind As Long
    
    'get the length of the string
    iLenStringToSearch = Len(strStringToSearch)
    iLenFind = Len(strFind)
    
    'if the start is 0 then set the start to the length
    'of the string
    If iStart = 0 Then
      iStart = iLenStringToSearch
    End If
    iStart = iStart + 1
    
    ip1 = 1
    Do
      ip2 = InStr(ip1, strStringToSearch, strFind)
      If (ip2 > 0) And (ip2 + iLenFind <= iStart) Then
        'if ip2 is not zero and it is less than the
        'place to start searching + the length of the
        'find string then set the function
        'to return that position
        InStrRev = ip2
      ElseIf ip2 = 0 Then
        ip2 = iLenStringToSearch
      End If
      'set the next position to seracf from
      ip1 = ip2 + 1
    Loop Until ip1 >= iStart
    
End Function

And a StrReverse function, written by Iain as well, I believe.

VB Code:

Private Function StrReverse(stString As String) As String
    Dim i As Integer
    For i = Len(stString) To 1 Step -1
      StrReverse = StrReverse & Mid$(stString, i, 1)
    Next i
End Function

I assume the above compatibility code has the same syntax as the true VB6 function, right?

I was looking for this the other day, and found a really good site with optimised code. Definately worth checking out.

http://www.xbeat.net/vbspeed/

Great site!

Here's the new and improved VB6Compatibility.bas file! According to VB Speed, these are (in general) the fastest code segments available. There are only a few reasons why the fastest wouldn't be contained in here:
1) Requires a TLB. Reason: I don't like 'em.
2) Requires an External class. That defeats the purpose of having a drop in file code module.
3) Lenth of code. A 10k function that goes 2x as fast as a 1k module doesn't quite seem like a good trade off to me.

Anyway, here it is. VB6Compatibility.1

Note, both original functions have been replaced with faster code.