Virtual light box. Almost.

Hi folks.

I have a need to write a kind of virtual light box, but in reverse. The need arises because of some drawing software I have that doesn't support layers very well and I need to trace outline drawings on a Wacom tablet.

With a light box you place your picture underneath your media and draw on a clean sheet of paper on top, much the same as having an underlying layer in a graphics program. However I kind of need the opposite. Because this software 'I Need to use' doesn't handle layers well I need an overlay program that will display a graphic with adjustable opacity, that the mouse or stylus can draw through onto the application underneath.

I've been a VB person for decades and have some limited graphical ability, but I wouldn't know where to start with this, or even if it's possible at all. Anyone have any ideas?

Please don't say - use a better drawing app, this isn't an option.

Thanks.

Can you save a copy of the original Image, draw onto the copy of the Image, and then save the Image back? This would only work if your drawing application allows you to save and open images.

Quote:

---

Originally Posted by tclancey

I need an overlay program that will display a graphic with adjustable opacity, that the mouse or stylus can draw through onto the application underneath.

---

Quick idea, toggle the WS_EX_TRANSPARENT window flag, it should let you click thru the form and also set the opacity.,

Note, Testing on Win7, Click-thru only works when form opacity is < 1.0D.

vb.net Code:

Imports System.Runtime.InteropServices
 
Public Class Form1
 
    Private Const hotKey_ClickThruToggle As Integer = 100 ' Our hot key ID
 
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        ' mouse-click-thru is off by default.
        Me.Text = "Click-Thru Off"
 
        ' register a hot key (Control+Q) to toggle mouse-click-thru option. 
        If Not RegisterHotKey(Me.Handle, hotKey_ClickThruToggle, fsModifier.CONTROL Or fsModifier.NOREPEAT, CUInt(Keys.Q)) Then
            MessageBox.Show("RegisterHotKey 'Control+Q' failed!", "Error", MessageBoxButtons.OK, MessageBoxIcon.Asterisk)
        End If
 
        ' set default opacity to 0%, opacity can be set using a trackbar.
        Me.Opacity = 1D
        TrackBar1.Minimum = 0
        TrackBar1.Maximum = 8 ' Limit opacity to 80%.
 
        ' load an image.
        Me.BackgroundImageLayout = ImageLayout.None
        Me.BackgroundImage = New Bitmap("m:\Windows_Vista_Logo.jpg")
    End Sub
 
    Private Sub Form1_FormClosing(sender As Object, e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing
        ' UnRegister our hot key
        UnregisterHotKey(Me.Handle, hotKey_ClickThruToggle)
    End Sub
 
    ' Window messages
    Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
        Static clickThruOn As Boolean
        If m.Msg = WM_HOTKEY Then
            If m.WParam.ToInt32 = hotKey_ClickThruToggle Then  ' Control+Q detected.
                If Not clickThruOn Then ' set click-thru on.
                    clickThruOn = True
                    SetWindowLong(Me.Handle, GWL_EXSTYLE, GetWindowLong(Me.Handle, GWL_EXSTYLE) Or WS_EX_TRANSPARENT)
                    Me.TopMost = True
                    Me.Text = "Click-Thru On"
                Else ' disable click thru
                    clickThruOn = False
                    SetWindowLong(Me.Handle, GWL_EXSTYLE, GetWindowLong(Me.Handle, GWL_EXSTYLE) And Not WS_EX_TRANSPARENT)
                    Me.Text = "Click-Thru Off"
                End If
            End If
        End If
        ' proc all msgs.
        MyBase.WndProc(m)
    End Sub
 
    Private Sub TrackBar1_Scroll(sender As System.Object, e As System.EventArgs) Handles TrackBar1.Scroll
        ' set form opacity
        Me.Opacity = 1D - (TrackBar1.Value / 10)
    End Sub
 
#Region "API"
    Private Const WM_HOTKEY As Int32 = &H312
    Private Enum fsModifier As UInt32
        NONE = &H0
        ALT = &H1
        CONTROL = &H2
        SHIFT = &H4
        WIN = &H8
        NOREPEAT = &H4000
    End Enum
    <DllImport("User32.dll")> _
    Private Shared Function RegisterHotKey(ByVal hwnd As IntPtr, ByVal id As Int32, ByVal fsModifiers As UInt32, ByVal vk As UInt32) As Boolean
    End Function
    <DllImport("User32.dll")> _
    Private Shared Function UnregisterHotKey(ByVal hwnd As IntPtr, ByVal id As Int32) As Boolean
    End Function
 
    Private Const GWL_EXSTYLE As Integer = (-20)
    Private Const WS_EX_TRANSPARENT As Integer = &H20
    Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As IntPtr, ByVal nIndex As Integer, ByVal dwNewLong As Integer) As Integer
    Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As IntPtr, ByVal nIndex As Integer) As Integer
#End Region
 
End Class