NumericUpDown for touchscreen

Perhaps someone will find this useful. I'm new to .Net so this is my first CodeBank submission and first UserControl. :) Kudos to circuits2 for his post that provided the main inspiration to tackle this as a UserControl instead of individual components.

The app I'm rewriting uses touchscreens and the controls used in VB6 don't exist anymore. This uses 2 pairs of buttons for coarse or fine "steps" since that was another way it had been done in the past so the operators are familiar with it. You could alter to only one button and have a timer to repeat it if you want. It will resize a bit and may be done better than I did perhaps. Left size (75x215) is the minimum and it will go to 300x1000 (right one is 200x499). Smallest size should allow 5 digit integers (if you don't alter the font).

I'm using this with .Net 4.5 so I don't know if there would be any issues with older versions.

Attachment 123027

Attachment 123029

vb.net Code:

Public Class NUD_Touch
 
    Public Event ValueChanged(ByVal Value As Integer)
 
#Region "Properties"
 
    Private _StepFine As Integer
    Private _StepCoarse As Integer
    Private _minimum As Integer
    Private _maximum As Integer
 
    Public Property Minimum() As Integer
        Get
            Return _minimum
        End Get
        Set(ByVal value As Integer)
            _minimum = value
        End Set
    End Property
    Public Property Maximum() As Integer
        Get
            Return _maximum
        End Get
        Set(ByVal value As Integer)
            _maximum = value
        End Set
    End Property
    Public Property StepCoarse() As Integer
        Get
            Return _StepCoarse
        End Get
        Set(ByVal value As Integer)
            _StepCoarse = value
            UpCoarse.Text = "+ " & CStr(_StepCoarse)
            DownCoarse.Text = "- " & CStr(_StepCoarse)
        End Set
    End Property
    Public Property StepFine() As Integer
        Get
            Return _StepFine
        End Get
        Set(ByVal value As Integer)
            _StepFine = value
            UpFine.Text = "+ " & CStr(_StepFine)
            DownFine.Text = "- " & CStr(_StepFine)
        End Set
    End Property
    Public Property Value() As Integer
        Get
            Return CInt(lblValue.Text)
        End Get
        Set(ByVal value As Integer)
            lblValue.Text = CStr(value)
            RaiseEvent ValueChanged(value)
        End Set
    End Property
#End Region
 
    Private Sub NUD_Touch_Load(sender As Object, e As EventArgs) Handles Me.Load
        'set some defaults if nothing has been set in design
        If Maximum = 0 Then Maximum = 100
        If StepCoarse = 0 Then StepCoarse = 10
        If StepFine = 0 Then StepFine = 1
    End Sub
 
    Private Sub UpFine_Click(sender As Object, e As EventArgs) Handles UpFine.Click
        If CInt(lblValue.Text) + StepFine > Maximum Then
            Value = Maximum
        Else
            Value = CInt(lblValue.Text) + StepFine
        End If
    End Sub
 
    Private Sub UpCoarse_Click(sender As Object, e As EventArgs) Handles UpCoarse.Click
        If CInt(lblValue.Text) + StepCoarse > Maximum Then
            Value = Maximum
        Else
            Value = CInt(lblValue.Text) + StepCoarse
        End If
    End Sub
 
    Private Sub DownCourse_Click(sender As Object, e As EventArgs) Handles DownCoarse.Click
        If CInt(lblValue.Text) - StepCoarse < Minimum Then
            Value = Minimum
        Else
            Value = CInt(lblValue.Text) - StepCoarse
        End If
    End Sub
 
    Private Sub DownFine_Click(sender As Object, e As EventArgs) Handles DownFine.Click
        If CInt(lblValue.Text) - StepFine < Minimum Then
            Value = Minimum
        Else
            Value = CInt(lblValue.Text) - StepFine
        End If
    End Sub
 
    Private Sub NUD_Touch_Resize(sender As Object, e As EventArgs) Handles Me.Resize
        Dim new_h As Integer
        Dim but_h As Integer
 
        'widths are being taken care of by anchor property
        new_h = Me.Height
        but_h = CInt((new_h - lblValue.Height) / 4)
        Me.Height = (but_h * 4) + lblValue.Height
        UpFine.Top = 0
        UpFine.Height = but_h
        UpCoarse.Top = but_h
        UpCoarse.Height = but_h
        lblValue.Top = but_h * 2
        DownCoarse.Top = but_h * 2 + lblValue.Height
        DownCoarse.Height = but_h
        DownFine.Top = DownCoarse.Top + but_h
        DownFine.Height = but_h
 
    End Sub
End Class

vb.net Code:

<Global.Microsoft.VisualBasic.CompilerServices.DesignerGenerated()> _
Partial Class NUD_Touch
    Inherits System.Windows.Forms.UserControl
 
    'UserControl1 overrides dispose to clean up the component list.
    <System.Diagnostics.DebuggerNonUserCode()> _
    Protected Overrides Sub Dispose(ByVal disposing As Boolean)
        Try
            If disposing AndAlso components IsNot Nothing Then
                components.Dispose()
            End If
        Finally
            MyBase.Dispose(disposing)
        End Try
    End Sub
 
    'Required by the Windows Form Designer
    Private components As System.ComponentModel.IContainer
 
    'NOTE: The following procedure is required by the Windows Form Designer
    'It can be modified using the Windows Form Designer.  
    'Do not modify it using the code editor.
    <System.Diagnostics.DebuggerStepThrough()> _
    Private Sub InitializeComponent()
        Me.UpFine = New System.Windows.Forms.Button()
        Me.UpCoarse = New System.Windows.Forms.Button()
        Me.DownFine = New System.Windows.Forms.Button()
        Me.DownCoarse = New System.Windows.Forms.Button()
        Me.lblValue = New System.Windows.Forms.Label()
        Me.SuspendLayout()
        '
        'UpFine
        '
        Me.UpFine.Anchor = CType((System.Windows.Forms.AnchorStyles.Left Or System.Windows.Forms.AnchorStyles.Right), System.Windows.Forms.AnchorStyles)
        Me.UpFine.FlatAppearance.BorderColor = System.Drawing.SystemColors.Highlight
        Me.UpFine.FlatAppearance.MouseDownBackColor = System.Drawing.SystemColors.ActiveCaption
        Me.UpFine.FlatAppearance.MouseOverBackColor = System.Drawing.SystemColors.GradientActiveCaption
        Me.UpFine.FlatStyle = System.Windows.Forms.FlatStyle.Flat
        Me.UpFine.Font = New System.Drawing.Font("Microsoft Sans Serif", 12.0!, System.Drawing.FontStyle.Regular, System.Drawing.GraphicsUnit.Point, CType(0, Byte))
        Me.UpFine.Location = New System.Drawing.Point(0, 0)
        Me.UpFine.Name = "UpFine"
        Me.UpFine.Size = New System.Drawing.Size(75, 45)
        Me.UpFine.TabIndex = 0
        Me.UpFine.Text = "UP"
        Me.UpFine.UseVisualStyleBackColor = True
        '
        'UpCoarse
        '
        Me.UpCoarse.Anchor = CType((System.Windows.Forms.AnchorStyles.Left Or System.Windows.Forms.AnchorStyles.Right), System.Windows.Forms.AnchorStyles)
        Me.UpCoarse.FlatAppearance.BorderColor = System.Drawing.SystemColors.Highlight
        Me.UpCoarse.FlatAppearance.MouseDownBackColor = System.Drawing.SystemColors.ActiveCaption
        Me.UpCoarse.FlatAppearance.MouseOverBackColor = System.Drawing.SystemColors.GradientActiveCaption
        Me.UpCoarse.FlatStyle = System.Windows.Forms.FlatStyle.Flat
        Me.UpCoarse.Font = New System.Drawing.Font("Microsoft Sans Serif", 14.25!, System.Drawing.FontStyle.Regular, System.Drawing.GraphicsUnit.Point, CType(0, Byte))
        Me.UpCoarse.Location = New System.Drawing.Point(0, 45)
        Me.UpCoarse.Name = "UpCoarse"
        Me.UpCoarse.Size = New System.Drawing.Size(75, 45)
        Me.UpCoarse.TabIndex = 1
        Me.UpCoarse.Text = "UP"
        Me.UpCoarse.UseVisualStyleBackColor = True
        '
        'DownFine
        '
        Me.DownFine.Anchor = CType((System.Windows.Forms.AnchorStyles.Left Or System.Windows.Forms.AnchorStyles.Right), System.Windows.Forms.AnchorStyles)
        Me.DownFine.FlatAppearance.BorderColor = System.Drawing.SystemColors.Highlight
        Me.DownFine.FlatAppearance.MouseDownBackColor = System.Drawing.SystemColors.ActiveCaption
        Me.DownFine.FlatAppearance.MouseOverBackColor = System.Drawing.SystemColors.GradientActiveCaption
        Me.DownFine.FlatStyle = System.Windows.Forms.FlatStyle.Flat
        Me.DownFine.Font = New System.Drawing.Font("Microsoft Sans Serif", 12.0!, System.Drawing.FontStyle.Regular, System.Drawing.GraphicsUnit.Point, CType(0, Byte))
        Me.DownFine.Location = New System.Drawing.Point(0, 170)
        Me.DownFine.Name = "DownFine"
        Me.DownFine.Size = New System.Drawing.Size(75, 45)
        Me.DownFine.TabIndex = 2
        Me.DownFine.Text = "DN"
        Me.DownFine.UseVisualStyleBackColor = True
        '
        'DownCoarse
        '
        Me.DownCoarse.Anchor = CType((System.Windows.Forms.AnchorStyles.Left Or System.Windows.Forms.AnchorStyles.Right), System.Windows.Forms.AnchorStyles)
        Me.DownCoarse.FlatAppearance.BorderColor = System.Drawing.SystemColors.Highlight
        Me.DownCoarse.FlatAppearance.MouseDownBackColor = System.Drawing.SystemColors.ActiveCaption
        Me.DownCoarse.FlatAppearance.MouseOverBackColor = System.Drawing.SystemColors.GradientActiveCaption
        Me.DownCoarse.FlatStyle = System.Windows.Forms.FlatStyle.Flat
        Me.DownCoarse.Font = New System.Drawing.Font("Microsoft Sans Serif", 14.25!, System.Drawing.FontStyle.Regular, System.Drawing.GraphicsUnit.Point, CType(0, Byte))
        Me.DownCoarse.Location = New System.Drawing.Point(0, 125)
        Me.DownCoarse.Name = "DownCoarse"
        Me.DownCoarse.Size = New System.Drawing.Size(75, 45)
        Me.DownCoarse.TabIndex = 2
        Me.DownCoarse.Text = "DN"
        Me.DownCoarse.UseVisualStyleBackColor = True
        '
        'lblValue
        '
        Me.lblValue.Anchor = CType((System.Windows.Forms.AnchorStyles.Left Or System.Windows.Forms.AnchorStyles.Right), System.Windows.Forms.AnchorStyles)
        Me.lblValue.BackColor = System.Drawing.SystemColors.Window
        Me.lblValue.BorderStyle = System.Windows.Forms.BorderStyle.FixedSingle
        Me.lblValue.Font = New System.Drawing.Font("Microsoft Sans Serif", 15.75!, System.Drawing.FontStyle.Regular, System.Drawing.GraphicsUnit.Point, CType(0, Byte))
        Me.lblValue.Location = New System.Drawing.Point(0, 90)
        Me.lblValue.MaximumSize = New System.Drawing.Size(300, 35)
        Me.lblValue.Name = "lblValue"
        Me.lblValue.Size = New System.Drawing.Size(75, 35)
        Me.lblValue.TabIndex = 4
        Me.lblValue.Text = "0"
        Me.lblValue.TextAlign = System.Drawing.ContentAlignment.MiddleCenter
        '
        'NUD_Touch
        '
        Me.AutoScaleDimensions = New System.Drawing.SizeF(6.0!, 13.0!)
        Me.AutoScaleMode = System.Windows.Forms.AutoScaleMode.Font
        Me.Controls.Add(Me.lblValue)
        Me.Controls.Add(Me.DownCoarse)
        Me.Controls.Add(Me.DownFine)
        Me.Controls.Add(Me.UpCoarse)
        Me.Controls.Add(Me.UpFine)
        Me.MaximumSize = New System.Drawing.Size(300, 1000)
        Me.MinimumSize = New System.Drawing.Size(75, 215)
        Me.Name = "NUD_Touch"
        Me.Size = New System.Drawing.Size(75, 215)
        Me.ResumeLayout(False)
 
    End Sub
    Friend WithEvents UpFine As System.Windows.Forms.Button
    Friend WithEvents UpCoarse As System.Windows.Forms.Button
    Friend WithEvents DownFine As System.Windows.Forms.Button
    Friend WithEvents DownCoarse As System.Windows.Forms.Button
    Friend WithEvents lblValue As System.Windows.Forms.Label
 
End Class