Creating 2 player pong, not working!

So I'm trying to create a 2 player pong game, however I have 2 problems.
1. After adding a moving ball, the player1's paddle will now not move. The arrow keys will not make it move, however it was all working before adding the ball
2. I haven't done this in this version yet, but in another version I added 2 players, and only one player could move at a time. As soon as I used the arrow keys (player 1) player 2 could not move using WASD.

Thanks for any help! I'm using VB 2008 Express, Code below:

Code:

---

Public Class Pong

   

    Private Sub Form1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
        Select Case e.KeyCode
            Case Keys.Left
                Me.Player1.Left -= 1
            Case Keys.Up
                Me.Player1.Top -= 1
            Case Keys.Right
                Me.Player1.Left += 1
            Case Keys.Down
                Me.Player1.Top += 1
        End Select
    End Sub
    Private Sub Ball_PreviewKeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.PreviewKeyDownEventArgs) Handles Ball.PreviewKeyDown
        Select Case e.KeyCode
            Case Keys.Left, Keys.Up, Keys.Right, Keys.Down
                e.IsInputKey = True
        End Select
    End Sub

    Private Sub Pong_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

    End Sub

    'Set up ball speeed and movement
    Dim speed As Single = 10
    'Create a random instance to keep the game exciting
    Dim rndInst As New Random()
    'Set the minimum and maximum angle of randomisation
    Dim xVel As Single = Math.Cos(rndInst.Next(8, 12)) * speed
    Dim yVel As Single = Math.Sin(rndInst.Next(4, 14)) * speed
    Private Sub Gametimer_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Gametimer.Tick
        'Move the ball
        Ball.Location = New Point(Ball.Location.X + xVel, Ball.Location.Y + yVel)

        'Now we must make sure the ball never leaves the game area
        If Ball.Location.Y < 0 Then
            Ball.Location = New Point(Ball.Location.X, 0)
            'Set the velocity to the opposite of the velocity when hitting the ball
            yVel = -yVel
        End If

        'Check if the ball hits the bottom of the playing feild
        If Ball.Location.Y > Me.Height - Ball.Size.Height - 45 Then
            Ball.Location = New Point(Ball.Location.X, Me.Height - Ball.Size.Height - 45)
            yVel = -yVel
        End If

        'Check if the ball hits a players paddle
        If Ball.Bounds.IntersectsWith(Player1.Bounds) Then
            Ball.Location = New Point(Player1.Location.X - Ball.Size.Width, Ball.Location.Y)
            xVel = -xVel
        End If

        'Check if the ball hits a players paddle
        If Ball.Bounds.IntersectsWith(player2.Bounds) Then
            Ball.Location = New Point(player2.Location.X + Ball.Size.Width, Ball.Location.Y)
            xVel = -xVel
        End If



    End Sub

    Private Sub Ball_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Ball.Click

    End Sub

    Private Sub play_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles play.Click
        Gametimer.Enabled = True
    End Sub
End Class

---

I don't see exactly whats stopping player 1 from moving but you need better controls. So I'm gonna help you on that. In this simple project, just add a picturebox and a timer. This is just for player 1 though. For player 2, just add more constants but keep going on the binary ones from player one. It is currently at 1 2 4 8, so for player 2 itll be at 16 32 64 128:

vb.net Code:

Option Explicit On
Option Strict On
 
Public Class Form1
 
    Private Const P1_UP As Keys = Keys.Up
    Private Const P1_DOWN As Keys = Keys.Down
    Private Const P1_LEFT As Keys = Keys.Left
    Private Const P1_RIGHT As Keys = Keys.Right
 
    'Key Flags (MUST BE IN BINARY FORMAT THE MORE KEYS YOU USE: ex. 1, 2, 4, 8, 16, 32, 64, 128, etc.
    Private Const P1_UP_FLAG As Integer = 1
    Private Const P1_DOWN_FLAG As Integer = 2
    Private Const P1_LEFT_FLAG As Integer = 4
    Private Const P1_RIGHT_FLAG As Integer = 8
 
    Private Keystate As Integer
 
    Private Function Check_Key(ByVal Keyflag As Integer) As Integer
 
        Check_Key = Keystate And Keyflag
 
    End Function
 
    Private Sub Keyboard_Control()
 
        If Check_Key(P1_LEFT_FLAG) > 0 Then PictureBox1.Left -= 5
        If Check_Key(P1_RIGHT_FLAG) > 0 Then PictureBox1.Left += 5
        If Check_Key(P1_UP_FLAG) > 0 Then PictureBox1.Top -= 5
        If Check_Key(P1_DOWN_FLAG) > 0 Then PictureBox1.Top += 5
 
    End Sub
 
    Private Sub Form1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
 
        Select Case e.KeyCode
            Case P1_UP
                Keystate = Keystate Or P1_UP_FLAG
            Case P1_DOWN
                Keystate = Keystate Or P1_DOWN_FLAG
            Case P1_LEFT
                Keystate = Keystate Or P1_LEFT_FLAG
            Case P1_RIGHT
                Keystate = Keystate Or P1_RIGHT_FLAG
        End Select
 
    End Sub
 
    Private Sub Form1_KeyUp(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyUp
 
        Select Case e.KeyCode
            Case P1_UP
                Keystate = Keystate And (Not P1_UP_FLAG)
            Case P1_DOWN
                Keystate = Keystate And (Not P1_DOWN_FLAG)
            Case P1_LEFT
                Keystate = Keystate And (Not P1_LEFT_FLAG)
            Case P1_RIGHT
                Keystate = Keystate And (Not P1_RIGHT_FLAG)
        End Select
 
    End Sub
 
    Private Sub Timer1_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Gametimer.Tick[B][/B]
          Keyboard_Control
    End Sub
End Class

You'll notice the controls are vastly improved, and you can press more than one key at the same time, which should help when player 2 comes along. Another thing is that it is never wise to use a Timer at all for game programming. Its better to use a realtime Game Loop locked at 60 frames per second, like this example spliced with the above example, this time without a timer:

vb.net Code:

Option Explicit On
Option Strict On
 
Public Class Form1
 
    Private Declare Function QueryPerformanceCounter Lib "Kernel32" (ByRef X As Long) As Integer
    Private Declare Function QueryPerformanceFrequency Lib "Kernel32" (ByRef X As Long) As Integer
 
    Private Structure Sprite_Type
        Public X As Integer
        Public Y As Integer
        Public Width As Integer
        Public Height As Integer
        Public Texture As Image
        Public Texture_Graphics As Graphics
    End Structure
 
    'Key Functions
    Private Const P1_UP As Keys = Keys.Up
    Private Const P1_DOWN As Keys = Keys.Down
    Private Const P1_LEFT As Keys = Keys.Left
    Private Const P1_RIGHT As Keys = Keys.Right
 
    'Key Flags (MUST BE IN BINARY FORMAT THE MORE KEYS YOU USE: ex. 1, 2, 4, 8, 16, 32, 64, 128, etc.
    Private Const P1_UP_FLAG As Integer = 1
    Private Const P1_DOWN_FLAG As Integer = 2
    Private Const P1_LEFT_FLAG As Integer = 4
    Private Const P1_RIGHT_FLAG As Integer = 8
 
    Private Ticks_Per_Second As Long
    Private Start_Time As Long
 
    Private Milliseconds As Integer
    Private Get_Frames_Per_Second As Integer
    Private Frame_Count As Integer
 
    Private Keystate As Integer
    Private Running As Boolean
 
    Dim Backbuffer_Graphics As Graphics
 
    Private Sprite As Sprite_Type
 
    Private Function Hi_Res_Timer_Initialize() As Boolean
        If QueryPerformanceFrequency(Ticks_Per_Second) = 0 Then
            Hi_Res_Timer_Initialize = False
        Else
            QueryPerformanceCounter(Start_Time)
            Hi_Res_Timer_Initialize = True
        End If
    End Function
 
    Private Function Get_Elapsed_Time() As Single
        Dim Last_Time As Long
        Dim Current_Time As Long
 
        QueryPerformanceCounter(Current_Time)
        Get_Elapsed_Time = Convert.ToSingle((Current_Time - Last_Time) / Ticks_Per_Second)
        QueryPerformanceCounter(Last_Time)
    End Function
 
    Private Function Get_Elapsed_Time_Per_Frame() As Single
        Static Last_Time As Long
        Static Current_Time As Long
 
        QueryPerformanceCounter(Current_Time)
        Get_Elapsed_Time_Per_Frame = CSng((Current_Time - Last_Time) / Ticks_Per_Second)
        QueryPerformanceCounter(Last_Time)
    End Function
 
    Private Sub Lock_Framerate(ByVal Target_FPS As Long)
        Static Last_Time As Long
        Dim Current_Time As Long
        Dim FPS As Single
 
        Do
            QueryPerformanceCounter(Current_Time)
            FPS = Convert.ToSingle(Ticks_Per_Second / (Current_Time - Last_Time))
        Loop While (FPS > Target_FPS)
 
        QueryPerformanceCounter(Last_Time)
    End Sub
 
    Private Function Get_FPS() As String
        Frame_Count = Frame_Count + 1
 
        If Get_Elapsed_Time() - Milliseconds >= 1 Then
            Get_Frames_Per_Second = Frame_Count
            Frame_Count = 0
            Milliseconds = Convert.ToInt32(Get_Elapsed_Time)
        End If
 
        Get_FPS = "Frames Per Second: " & Get_Frames_Per_Second
    End Function
 
    Private Function Check_Key(ByVal Keyflag As Integer) As Integer
        Check_Key = Keystate And Keyflag
    End Function
 
    Private Sub Keyboard_Control()
        If Check_Key(P1_LEFT_FLAG) > 0 Then Sprite.X -= 5
        If Check_Key(P1_RIGHT_FLAG) > 0 Then Sprite.X += 5
    End Sub
 
    Private Sub Load_Textures()
        Sprite.Texture_Graphics = Me.CreateGraphics()
        Sprite.Texture = Image.FromFile(Application.StartupPath() & "\Link.png")
    End Sub
 
    Private Sub Unload_Textures()
        Sprite.Texture_Graphics.Dispose()
    End Sub
 
    Private Sub Setup_Sprites()
        With Sprite
            .Width = 54
            .Height = 69
            .X = CInt(Me.Width / 2) - CInt(Sprite.Width / 2)
            .Y = 490
        End With
    End Sub
 
    Private Sub Clear_Screen()
        Backbuffer_Graphics.Clear(Color.FromArgb(255, 0, 0, 0))
    End Sub
 
    Private Sub Render()
        Clear_Screen()
        Sprite.Texture_Graphics.DrawImage(Sprite.Texture, New RectangleF(Sprite.X, Sprite.Y, Sprite.Width, Sprite.Height))
    End Sub
 
    Private Sub Game_Loop()
        Do While Running = True
            Keyboard_Control()
            Render()
            Lock_Framerate(60)
            Me.Text = Get_FPS()
            Application.DoEvents()
        Loop
    End Sub
 
    Private Sub Main()
        With Me
            .Show()
            .Focus()
            .DoubleBuffered = True
            .KeyPreview = True
        End With
 
        Backbuffer_Graphics = Me.CreateGraphics()
        Load_Textures()
        Setup_Sprites()
        Hi_Res_Timer_Initialize()
        Running = True
        Game_Loop()
    End Sub
 
    Private Sub Shutdown()
        Unload_Textures()
        Running = False
        Application.Exit()
    End Sub
 
    Private Sub Form1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
        Select Case e.KeyCode
            Case P1_UP
                Keystate = Keystate Or P1_UP_FLAG
            Case P1_DOWN
                Keystate = Keystate Or P1_DOWN_FLAG
            Case P1_LEFT
                Keystate = Keystate Or P1_LEFT_FLAG
            Case P1_RIGHT
                Keystate = Keystate Or P1_RIGHT_FLAG
        End Select
    End Sub
 
    Private Sub Form1_KeyUp(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyUp
        Select Case e.KeyCode
            Case P1_UP
                Keystate = Keystate And (Not P1_UP_FLAG)
            Case P1_DOWN
                Keystate = Keystate And (Not P1_DOWN_FLAG)
            Case P1_LEFT
                Keystate = Keystate And (Not P1_LEFT_FLAG)
            Case P1_RIGHT
                Keystate = Keystate And (Not P1_RIGHT_FLAG)
        End Select
    End Sub
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Main()
    End Sub
 
    Private Sub Form1_FormClosing(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles MyBase.FormClosing
        Shutdown()
    End Sub
 
End Class

And of course theres collision. You dont need all them if statements for collision. And there are many ways to check for it. This is a function that will check for collision of 2 rectangles:

vb.net Code:

Private Structure Box
    X As Single
    Y As Single
    W As Single
    H As Single
    VX As Single
    VY As Single
End Structure
 
Private Function AABBCheck(B1 As Box, B2 As Box) As Boolean
    'returns true if the boxes are colliding (velocities are not used)
    Return Not (((B1.X + B1.W < B2.X) Or (B1.X > B2.X + B2.W) Or (B1.Y + B1.H < B2.Y) Or (B1.Y > B2.Y + B2.H)))
End Function

Theres a much better way out there called AABB Sweep collision detection, which is designed for fast moving objects, but I'm still figuring that out. I'm also creating Pong, only in 3D using VB.Net 2010, and DirectX9.