Removing vowels from string

I was wondering if someone could please look at this for me? I am trying to remove vowels from the user input and displaying them in the edited label. This is what I have so far but I really don't know which way to go now.


Public Class Form1

Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
Dim textBox1 As String
Dim searchFor As String = ("aeiou")
Dim newList As String
Dim vowelList As New List(Of String)
vowelList.Add("a")
vowelList.Add("e")
vowelList.Add("i")
vowelList.Add("o")
vowelList.Add("u")

'If searchFor = True Then vowelList.Add()

Dim count As Integer = myString.Length - 1
Dim y As Integer = 0

If vowelList.Contains(vowelList(y)) = True Then
newList = newList.Remove(y, 1)
lblEdited = newList
y -= 1
End If
y += 1


End Sub

'Private Function y() As Integer
' Throw New NotImplementedException
'End Function

End Class

Here's an example using RegEx: Extracting Vowels in Substring.

try this

Code:

---

        Dim theVowels As String = "aeiouAEIOU" 'define what a vowel is

        'test string
        Dim panagram As String = "The quick brown fox jumps over the lazy dog"
        '
        Dim newString As String 'string with vowels removed

        For Each c As Char In panagram 'look at each char
            If Not theVowels.Contains(c) Then 'if it is not a vowel
                newString &= c 'add to new string
            End If
        Next

        Debug.WriteLine(newString)
        Stop

---

Of course fitting in "Y" is always the tough part :D

Dim panagram As String = "The shy pygmy dryly said why when the Crypt was dry."

I am just not seeing it.

Quote:

---

Originally Posted by paule

I am just not seeing it.

---

What does this mean?

And once again, people fail to take into account the complexities of text. What about accented characters? Either they are encoded as a single character, which is different to the plain character (such as U+00E9) so that it doesn't get removed, OR it's encoded as the base letter (U+0065) followed by the combining accent (U+0301), where the base letter will be removed and the accent will combine with the previous character.

It would be quite a stretch to describe either of those as "correct" behaviour.

The way to deal with this, in my opinion, is to firstly break the string down into graphemes with the StringInfo.GetTextElementEnumerator method. This gives you strings that represent each "character" as understood by a person. This means that if you have a base character with several combining characters, they will all be returned in one element of the Enumerator.

Given a string, you can then check whether the base letter is a vowel with the simple method shown above ("aeiouAEIOU".Contains(baseLetter), for example). The trick is in how do you get the base letter? You can simply apply that check to every character in the string that is returned from the enumerator, as long as you can be sure that the base letter exists as its own character (U+00E9 fails this). To decompose U+00E9 into U+0065, U+0301 so that it does get caught, you can use the Normalize(NormalizationForm) method on the string. Which NormalizationForm do you want to pass? Well, you want the canonical decomposition without replacing with primary compositions, so I'd go for FormD personally. (Yes I do have a working version of this code with test cases to prove it works)

here's my method, ignoring 'y' + any accented characters:

Code:

---

Dim theVowels As String = "aeiouAEIOU"
Dim panagram As String = "The quick brown fox jumps over the lazy dog"
Dim chars As List(Of Char) = panagram.ToList
chars.RemoveAll(Function(c) theVowels.Contains(c))
MsgBox(String.Concat(chars.ToArray))

---

Quote:

---

Originally Posted by Evil_Giraffe

And once again, people fail to take into account the complexities of text. What about accented characters? Either they are encoded as a single character, which is different to the plain character (such as U+00E9) so that it doesn't get removed, OR it's encoded as the base letter (U+0065) followed by the combining accent (U+0301), where the base letter will be removed and the accent will combine with the previous character.

It would be quite a stretch to describe either of those as "correct" behaviour.

---

True, here's a solution that seems to work whether the diacritic is built in or following the character.

vb.net Code:

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim input = "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZæøåáâăäĺćçčéęëěíîďđńňóôőöřůúűüýţ"
        Dim output = RemoveVowels(input)
        Dim output2 = RemoveVowels2(input)
    End Sub
 
    Private Function RemoveVowels(inputString As String) As String
        Dim normalized = inputString.Normalize(NormalizationForm.FormD)
        Dim pattern = "[!aeiouAEIOU]"
        Dim sb As New StringBuilder
        Array.ForEach(normalized.ToCharArray(), Sub(c) If c Like pattern Then sb.Append(c))
        Return sb.ToString()
    End Function
 
    Private Function RemoveVowels2(inputString As String) As String
        Dim normalized = inputString.Normalize(NormalizationForm.FormD)
        Dim pattern = "[!aeiouAEIOU]"
        Return String.Join("", normalized.Where(Function(c) c Like pattern))
    End Functions

Hmm, that doesn't work with my test cases MattP.

vbnet Code:

Imports NUnit.Framework
 
<TestFixture>
Public Class TestVowelRemover
    <Test>
    Public Sub Remove_NullString_ReturnNullString()
        Assert.That(Sub() VowelRemover.Remove(Nothing), Throws.ArgumentException)
    End Sub
 
    <Test>
    Public Sub Remove_EmptyString_ReturnEmptyString()
        Assert.That(VowelRemover.Remove(""), [Is].EqualTo(""))
    End Sub
 
    <Test>
    Public Sub Remove_StringWithoutVowels_ReturnsInputStringWithoutChanges()
        Assert.That(VowelRemover.Remove("bcd"), [Is].EqualTo("bcd"))
    End Sub
 
    <Test>
    Public Sub Remove_StringWithSimpleLatinVowels_ReturnsStringWithVowelsRemoved()
        Assert.That(VowelRemover.Remove("abcde"), [Is].EqualTo("bcd"))
    End Sub
 
    <Test>
    Public Sub Remove_StringWithBaseVowelWithCombiningCharacter_RemovesVowelAndAccent()
        Dim input As String = New String({"a"c, "b"c, "c"c, "d"c, "e"c, ChrW(&H301)})
 
        Assert.That(VowelRemover.Remove(input), [Is].EqualTo("bcd"))
    End Sub
 
    <Test>
    Public Sub Remove_StringWithCombinedVowelAndAccentCharacter_RemovesCombinedCharacter()
        Dim input As String = New String({"a"c, "b"c, "c"c, "d"c, ChrW(&HE9)})
 
        Assert.That(VowelRemover.Remove(input), [Is].EqualTo("bcd"))
    End Sub
End Class

Here's one that does work with the above cases:

vbnet Code:

Public Class VowelRemover
    Private Shared ReadOnly _vowels As String = "AEIOUaeiou"
 
    Public Shared Function Remove(vowelified As String) As String
        If vowelified Is Nothing Then Throw New ArgumentException("string to de-vowel must be supplied", "vowelified")
 
        Dim devoweledBuilder As New StringBuilder
        Dim graphemeIterator = StringInfo.GetTextElementEnumerator(vowelified)
 
        While graphemeIterator.MoveNext()
            Dim grapheme As String = graphemeIterator.Current.ToString()
            If Not grapheme.Normalize(NormalizationForm.FormD).Any(Function(c) _vowels.Contains(c)) Then
                devoweledBuilder.Append(grapheme)
            End If
        End While
 
        Return devoweledBuilder.ToString()
    End Function
End Class

However, that still doesn't take into account whether "y" is a vowel in the context... I'm not going to even touch it.

Also, I notice in MattP's input string the two characters 'æ' and 'ø' - are these considered vowels? My code doesn't strip these (but neither does MattP's :p).

Quote:

---

Originally Posted by Evil_Giraffe

Also, I notice in MattP's input string the two characters 'æ' and 'ø' - are these considered vowels?

---

Æ, Ø and Å are all considered vowels (danish language). Usually though Æ is represented as AE, Ø as OE and Å as AA.

Quote:

---

Originally Posted by Evil_Giraffe

Also, I notice in MattP's input string the two characters '�' and '�' - are these considered vowels? My code doesn't strip these (but neither does MattP's :p).

---

+1

Yes those are vowels (Danish and Norwegian I believe). '�' is removed if Option Compare is changed from Binary to Text.

Since Testing doesn't come up too often here are your test methods translated from NUnit to the Microsoft Unit Test Framework. I've tried to break everything out and comment so it's easy to follow.

(Note: Remove is not a shared method in my VowelRemover project, StringDiacritics is the namespace of my VowelRemover class hence the Import statement)

vb.net Code:

Imports System.Text
Imports Microsoft.VisualStudio.TestTools.UnitTesting
Imports StringDiacritics
 
<TestClass()>
Public Class VowelRemoverTests
 
    <TestMethod()>
    <ExpectedException(GetType(System.ArgumentException), "Null Exception Not Thrown")>
    Public Sub Remove_ReturnExceptionOnNullString()
 
        'Arrange
        Dim inputString As Object = Nothing
        Dim outputString As String = Nothing
        Dim vr As New VowelRemover()
 
        'Act
        outputString = vr.Remove(inputString)
 
    End Sub
 
    <TestMethod()>
    Public Sub Remove_EmptyString_ReturnEmptyString()
 
        'Arrange
        Dim inputString = ""
        Dim outputString As String = Nothing
        Dim vr As New VowelRemover()
 
        'Act
        outputString = vr.Remove(inputString)
 
        'Assert
        'Parameters: Expected, Actual, Failure Message
        Assert.AreEqual("", outputString, "Empty String Not Equal")
 
    End Sub
 
    <TestMethod()>
    Public Sub Remove_StringWithoutVowels_ReturnsStringWithoutChanges()
 
        'Arrange
        Dim inputString = "bcd"
        Dim outputString As String = Nothing
        Dim vr As New VowelRemover()
 
        'Act
        outputString = vr.Remove(inputString)
 
        'Assert
        Assert.AreEqual("bcd", outputString, "No Vowel String Not Equal")
 
    End Sub
 
    <TestMethod()>
    Public Sub Remove_StringWithSimpleLatinVowels_ReturnsStringWithVowelsRemoved()
 
        'Arrange
        Dim inputString = "abcde"
        Dim outputString As String = Nothing
        Dim vr As New VowelRemover()
 
        'Act
        outputString = vr.Remove(inputString)
 
        'Assert
        Assert.AreEqual("bcd", outputString, "Latin Vowel String Not Equal")
 
    End Sub
 
    <TestMethod()>
    Public Sub Remove_StringWithBaseVowelWithCombiningCharacter_RemovesVowelAndAccent()
 
        'Arrange
        Dim inputString = New String({"a"c, "b"c, "c"c, "d"c, "e"c, ChrW(&H301)})
        Dim outputString As String = Nothing
        Dim vr As New VowelRemover()
 
        'Act
        outputString = vr.Remove(inputString)
 
        'Assert
        Assert.AreEqual("bcd", outputString, "Vowel With Combining Character Not Equal")
 
    End Sub
 
    <TestMethod()>
    Public Sub Remove_StringWithCombinedVowelAndAccentCharacter_RemovesCombinedCharacter()
 
        'Arrange
        Dim inputString = New String({"a"c, "b"c, "c"c, "d"c, "e"c, ChrW(&HE9)})
        Dim outputString As String = Nothing
        Dim vr As New VowelRemover()
 
        'Act
        outputString = vr.Remove(inputString)
 
        'Assert
        Assert.AreEqual("bcd", outputString, "Combined Vowel Not Equal")
 
    End Sub
 
End Class