New Timer problem

I'm tryng to make a timer object but having no luck,

If i add timer1 to form1 and write:

me.text = "yeah"
Timer1.enabled = false

Then after one "tick" it will change the text, but to do the same thing with a timer object i've read that i need to write something like:

Public shared Tim as system.timers.timer

Public shared sub main()
Tim = new timers.timer(1000)
Tim.enabled = True
Addhandler Tim.elapsed, addressof TimTick
End sub

Private shared sub TimTick(sender as object, e as timers.elapsedeventargs)
Form1.text = "yeah"
Tim.enabled = false
End sub

This doesn't seem to work, am i missing something?

I'm lost. If this is a Forms application why are you using sub Main()? It won't work if it's not executed.

I'm lost. If this is a Forms application why are you using sub Main()? It won't work if it's not executed.

I spent an hour or so on the internet trying to find how to create a new timer and after the 1st thirty or so forums i found something that looked like this, and it looked like what i wanted.

If i open a new "windows form application", then what changes would i need to make to this to get it to work?

vb.net Code:

Public Class Form1
    Public Shared T As New System.Timers.Timer
    Delegate Sub SetTextCallBack([text] As String) ' You're going to run into cross threading issues
                                                                    ' This is needed for a solution (see below)
 
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        T.Interval = 2000
        AddHandler T.Elapsed, AddressOf T_Tick
        T.Enabled = True
    End Sub
 
    Private Sub SetText(ByVal [text] As String)
 
        ' InvokeRequired required compares the thread ID of the 
        ' calling thread to the thread ID of the creating thread. 
        ' If these threads are different, it returns true. 
 
        If Me.InvokeRequired Then
            Dim d As New SetTextCallBack(AddressOf SetText)
            Me.Invoke(d, New Object() {[text]})
        Else
            Me.Text = [text]
        End If
    End Sub
 
    Private Sub T_Tick(ByVal sender As Object, ByVal e As Timers.ElapsedEventArgs)
        SetText("Ok")
        T.Enabled = False
    End Sub
End Class

Why are you using a System.Timers.Timer? Nomally, you would drag a timer onto the form. This would be a Forms.Timer, and they are quite a bit easier to use. The other timer is for threading, and you never said you wanted that. You can also create a Forms.Timer in code just like you can create anything else:

Public myTimer As Forms.Timer = New Forms.Timer

However, if you do that, you will also need to use AddHandler to hook the timer up to the method that you want to use to handle the tick. If you just drag the timer onto the form then you can just double click it and you will be taken to the method.

Quote:

---

Originally Posted by Shaggy Hiker

Public myTimer As Forms.Timer = New Forms.Timer

However, if you do that, you will also need to use AddHandler to hook the timer up to the method that you want to use to handle the tick. If you just drag the timer onto the form then you can just double click it and you will be taken to the method.

---

A slightly easier alternative is to use the WithEvents keyword:

Public WithEvents myTimer As New Timer

Then you can code the Timer Tick sub the same way as if you added it in the Designer. It's what the VS Designer itself uses.

BB

Ours is not to reason why ... or so they keep telling me. It was quite fun trying to work it all out with the cross thread and all so I don't feel the time (or should that be 'the timer'?) was wasted, (though I must confess to crushing a cake box in frustration at one point - serves me right for not reading the whole article I was consulting!) :rolleyes:

when I said I was trying to create a timer object I meant that I'd tried "Public Tim as new Timer" but found that I had no seperate "sub" for a "Tim.tick" meaning the timer was useless. So what your saying is that adding "WithEvents" would allow for a "Tim.Tick" Sub?

Thank you very much for the time and effort Dunfiddlin, I'll give that a go later.

Quote:

---

Originally Posted by sico

when I said I was trying to create a timer object I meant that I'd tried "Public Tim as new Timer" but found that I had no seperate "sub" for a "Tim.tick" meaning the timer was useless. So what your saying is that adding "WithEvents" would allow for a "Tim.Tick" Sub?.

---

Yes.
BB

Quote:

---

Originally Posted by sico

when I said I was trying to create a timer object I meant that I'd tried "Public Tim as new Timer" but found that I had no seperate "sub" for a "Tim.tick" meaning the timer was useless. So what your saying is that adding "WithEvents" would allow for a "Tim.Tick" Sub?

Thank you very much for the time and effort Dunfiddlin, I'll give that a go later.

---

As BB noted, yes, WithEvents will allow the timer 'Tick' event (note the difference between a forms timer and a system timer).

However, Adding a handler will do the same thing, similar to what you have done in your first post. However, your sub main() is executing and completing (thus ending the application) before any kind of event can fire.

Code:

---

Module Module1

    Private Tim As System.Timers.Timer

    Public Sub Main()
        Tim = New Timers.Timer(1000)
        Tim.Enabled = True
        AddHandler Tim.Elapsed, AddressOf TimTick
        Console.WriteLine("Find the ANY key")
        Console.ReadKey(True)
    End Sub

    Private Sub TimTick(sender As Object, e As Timers.ElapsedEventArgs)
        Console.WriteLine("Tim is Fired!")
        Tim.Enabled = False
    End Sub

End Module

---

Of course, this is a console application: if you want to play with forms, you'd create a forms application and typically use the Forms timer.

Both AddHandler and WithEvents do the same thing, ultimately. When you have an oject that can raise events, such as controls, timers, custom objects with custom events, and so forth, the object is maintaining a list (one list per event) of methods that it needs to call whenever the event happens. WithEvents tells the object that will raise the event, that the current class wants to handle events. You then have to add the Handles clause to the end of the method that is supposed to handle the event (the designer does this for you for components added in the designer). The compiler will then hook the event to the handler. By comparison, AddHandler is a bit more straightforward. That method is used to tell the object that will raise the event, which method it should add to which list. No magic compiler hookups with AddHandler, it is a strange looking method, but one that works in a clear and understandable fashion once you know how the event raising mechanism works. WithEvents and the Handles clause is easier to use, simply because the designer hooks things up automatically, but how that happens isn't quite as clear.

Thanks for all the help and advice. I've got it all working now so i can carry on with my project.