checking thread completion before continuing.

I'm having trouble checking the completion of multiple threads before executing more code.

As an example, I started two threads:

**************************
Dim Thread1 As New System.Threading.Thread(AddressOf wordpress_checker_thread)
Thread1.Start()
Dim Thread2 As New System.Threading.Thread(AddressOf wordpress_checker_thread)
Thread2.Start()

(check if Thread1 and Thread2 finish running)

* continue with more code.
*******************

I'd like to check when these threads are completed.

I've used If Thread1.IsAlive in a timer but that didn't work because I can't pass Thread1 to the Timer handler. I've declared Thread1 globally using public, it does work but only once because when I rerun the code, you can't restart the same Thread twice.

Any suggestion on how to implement this.

What I would do is to encapsulate those threading operations inside a class. I'd give this class completion type events which I would raise when the thread has completed. Would you like to see an example of how I'd approach it ?

Niya, I would appreciate an example. Thx.

Sorry I been so long. Was a lil busy cooking. Here is an example of how I implement threading in my components:-

vbnet Code:

Imports System.Threading
 
Public Class Counter
 
    'Incase we need to update anything on the UI
    'we use this control to invoke events
    'on the UI thread
    Private g_objCtl As Control
 
    Private g_thrdInternalBeginCount As Thread
 
    Public Event CountChanged As EventHandler(Of CountChangedEventArgs)
    Public Event CountCompleted As EventHandler
 
    Protected Overridable Sub OnCountChanged(ByVal e As CountChangedEventArgs)
        RaiseEvent CountChanged(Me, e)
    End Sub
    Protected Overridable Sub OnCountCompleted()
        RaiseEvent CountCompleted(Me, New EventArgs)
    End Sub
    
 
    Public Sub BeginCountAsync(ByVal max As Integer, ByVal delay As Integer)
 
        'Only one instance of the asyncronous counting is allowed
        If g_thrdInternalBeginCount IsNot Nothing AndAlso g_thrdInternalBeginCount.IsAlive Then
            Throw New NotSupportedException("BeginCount already running")
        End If
 
        'Create the control on the thread that called this function
        'so we can use the control to invoke on said thread
        InitThreading()
 
        g_thrdInternalBeginCount = New Thread(AddressOf InternalBeginCount)
 
        'Ensures that this thread terminates
        'when the application terminates
        g_thrdInternalBeginCount.IsBackground = True
 
 
        g_thrdInternalBeginCount.Start(New InternalBeginCountArgs With {.Delay = delay, .Max = max})
    End Sub
 
    Public Sub BeginCount(ByVal max As Integer, ByVal delay As Integer)
        InternalBeginCount(max, delay)
    End Sub
 
    'Thread.Start is only able to take 1 parameter so we must
    'package the parameters in an object
    Private Sub InternalBeginCount(ByVal args As InternalBeginCountArgs)
        InternalBeginCount(args.Max, args.Delay)
    End Sub
 
    Private Sub InternalBeginCount(ByVal Max As Integer, ByVal Delay As Integer)
 
        For i = 1 To Max
 
            'If this function was called on a different thread
            'from the thread the control was created on
            'then we need to invoke it on the control's thread
            If g_objCtl.InvokeRequired Then
                g_objCtl.Invoke(New Action(Of CountChangedEventArgs)(AddressOf OnCountChanged), New CountChangedEventArgs(i, Max))
            Else
                OnCountChanged(New CountChangedEventArgs(i, Max))
            End If
 
            thread.sleep(Delay)
        Next
 
        If g_objCtl.InvokeRequired Then
            g_objCtl.Invoke(New Action(AddressOf OnCountCompleted))
        Else
            OnCountCompleted()
        End If
 
    End Sub
 
    Private Sub InitThreading()
        If g_objCtl IsNot Nothing Then g_objCtl.Dispose()
 
        g_objCtl = New Control
 
        'Force creation of handle on current thread
        Dim x As IntPtr = g_objCtl.Handle
 
    End Sub
 
    Private Class InternalBeginCountArgs
        Public Max As Integer
        Public Delay As Integer
    End Class
 
End Class
 
Public Class CountChangedEventArgs
    Inherits EventArgs
 
    Private _iMax As Integer
    Private _iCurCount As Integer
 
 
    Public Sub New(ByVal curCount As Integer, ByVal max As Integer)
        _iMax = max
        _iCurCount = curCount
    End Sub
    Public ReadOnly Property CurCount() As Integer
        Get
            Return _iCurCount
        End Get
    End Property
    Public ReadOnly Property Max() As Integer
        Get
            Return _iMax
        End Get
    End Property
 
End Class

I tried to make this as simple as possible for you. Its simple a class that counts to a specified number and raises two events. One event is raised every time the counter is incremented and another event is raised on completion of the count. To test it, place the above code in a class file and place a Label control and a Button control on a Form and use this code:-

vbnet Code:

Public Class Form1
    Private WithEvents counter As New Counter
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        counter.BeginCountAsync(100, 100)
    End Sub
 
    Private Sub counter_CountChanged(ByVal sender As Object, ByVal e As CountChangedEventArgs) Handles counter.CountChanged
        Label1.Text = CStr(e.CurCount)
    End Sub
 
    Private Sub counter_CountCompleted(ByVal sender As Object, ByVal e As System.EventArgs) Handles counter.CountCompleted
        MsgBox("Count complete")
    End Sub
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
 
    End Sub
End Class

If you have any questions about it let me know.