appdata folder in vb6

need your assistance guys.

what is the correct way to hardcode this path.

In winxp, I need to create subfolder in the current users Documents and Settings folder and extract files there . . .

or in vista or 7, I need to create subfolder in the current users Documents and Settings folder and extract files there . . .

I dont want to hardcode C:\Documents and Settings\CustomFolder or C:\Users\CustomFolder because probably the working drive is D or E.

Can I hardcode like %appdata%/customfolder?

What is the correct code?

Hi,

Try these :

MsgBox Environ$("AppData")
MsgBox Environ$("AllUsersProfile")

Regards
Veena

thank you very much. will this work with vista and 7 too?

Hi,

I dont know.. I have neither of them installed here...

Take a look at this FAQ section http://www.vbforums.com/showthread.php?t=564256
The code there is tested and works on Vista/7.

The FAQ section answers a lot of common questions such as this.

As far as I understand using Environment variables is not 100% reliable.

If you want to know a little more about the API indirectly involved in the solution from the FAQ research...
SHGetKnownFolderPath, SHGetFolderPath, KNOWNFOLDERID, CSIDL

Edit: Baja has pipped me to the post

Microsoft officially recommended using SHGetFolderPath API to retrieve the location of special folders in XP, meaning they have to keep supporting it for a long time going forward.

vb Code:

Public Enum FolderEnum
    feCDBurnArea = 59 ' \Docs & Settings\User\Local Settings\Application Data\Microsoft\CD Burning
    feCommonAppData = 35 ' \Docs & Settings\All Users\Application Data
    feCommonAdminTools = 47 ' \Docs & Settings\All Users\Start Menu\Programs\Administrative Tools
    feCommonDesktop = 25 ' \Docs & Settings\All Users\Desktop
    feCommonDocs = 46 ' \Docs & Settings\All Users\Documents
    feCommonPics = 54 ' \Docs & Settings\All Users\Documents\Pictures
    feCommonMusic = 53 ' \Docs & Settings\All Users\Documents\Music
    feCommonStartMenu = 22 ' \Docs & Settings\All Users\Start Menu
    feCommonStartMenuPrograms = 23 ' \Docs & Settings\All Users\Start Menu\Programs
    feCommonTemplates = 45 ' \Docs & Settings\All Users\Templates
    feCommonVideos = 55 ' \Docs & Settings\All Users\Documents\My Videos
    feLocalAppData = 28 ' \Docs & Settings\User\Local Settings\Application Data
    feLocalCDBurning = 59 ' \Docs & Settings\User\Local Settings\Application Data\Microsoft\CD Burning
    feLocalHistory = 34 ' \Docs & Settings\User\Local Settings\History
    feLocalTempInternetFiles = 32 ' \Docs & Settings\User\Local Settings\Temporary Internet Files
    feProgramFiles = 38 ' \Program Files
    feProgramFilesCommon = 43 ' \Program Files\Common Files
    'feRecycleBin = 10 ' ???
    feUser = 40 ' \Docs & Settings\User
    feUserAdminTools = 48 ' \Docs & Settings\User\Start Menu\Programs\Administrative Tools
    feUserAppData = 26 ' \Docs & Settings\User\Application Data
    feUserCache = 32 ' \Docs & Settings\User\Local Settings\Temporary Internet Files
    feUserCookies = 33 ' \Docs & Settings\User\Cookies
    feUserDesktop = 16 ' \Docs & Settings\User\Desktop
    feUserDocs = 5 ' \Docs & Settings\User\My Documents
    feUserFavorites = 6 ' \Docs & Settings\User\Favorites
    feUserMusic = 13 ' \Docs & Settings\User\My Documents\My Music
    feUserNetHood = 19 ' \Docs & Settings\User\NetHood
    feUserPics = 39 ' \Docs & Settings\User\My Documents\My Pictures
    feUserPrintHood = 27 ' \Docs & Settings\User\PrintHood
    feUserRecent = 8 ' \Docs & Settings\User\Recent
    feUserSendTo = 9 ' \Docs & Settings\User\SendTo
    feUserStartMenu = 11 ' \Docs & Settings\User\Start Menu
    feUserStartMenuPrograms = 2 ' \Docs & Settings\User\Start Menu\Programs
    feUserStartup = 7 ' \Docs & Settings\User\Start Menu\Programs\Startup
    feUserTemplates = 21 ' \Docs & Settings\User\Templates
    feUserVideos = 14  ' \Docs & Settings\User\My Documents\My Videos
    feWindows = 36 ' \Windows
    feWindowFonts = 20 ' \Windows\Fonts
    feWindowsResources = 56 ' \Windows\Resources
    feWindowsSystem = 37 ' \Windows\System32
End Enum
 
Private Declare Function SHGetFolderPath Lib "shfolder" Alias "SHGetFolderPathA" (ByVal hwndOwner As Long, ByVal nFolder As Long, ByVal hToken As Long, ByVal dwFlags As Long, ByVal pszPath As String) As Long
 
Public Function SpecialFolder(pfe As FolderEnum) As String
    Const MAX_PATH = 260
    Dim strPath As String
    Dim strBuffer As String
    
    strBuffer = Space$(MAX_PATH)
    If SHGetFolderPath(0, pfe, 0, 0, strBuffer) = 0 Then strPath = Left$(strBuffer, InStr(strBuffer, vbNullChar) - 1)
    If Right$(strPath, 1) = "\" Then strPath = Left$(strPath, Len(strPath) - 1)
    SpecialFolder = strPath
End Function

Sample usage:

?SpecialFolder(feUserAppData)
C:\Documents and Settings\Ellis\Application Data

?SpecialFolder(feUserDocs)
C:\Documents and Settings\Ellis\My Documents

thanks for all the help here. I am very sorry if I am newbie and cant relate to all programming disciplines.

Quote:

---

Originally Posted by iamresearcher

I am very sorry if I am newbie and cant relate to all programming disciplines.

---

There's no need to apologise for being a newbie - we all were at one time, and like you, totally baffled by the mysteries of Operating Systems. As you gain more experience you'll find that, rather than bumping into constraints and treating them as irritations to be got round, you'll actually make use of them (and be thankful that the're there) !

Happy New Year ! :)